Как преобразовать int в строку на Arduino?

Как преобразовать int, n в строку, чтобы при отправке ее по серийному номеру она отправлялась как строка?

Это то, что у меня есть до сих пор:

int ledPin=13;
int testerPin=8;
int n=1;

char buf[10];

void setup()
{
    pinMode(ledPin, OUTPUT);
    pinMode(testerPin, OUTPUT);
    Serial.begin(115200);
}

void loop()
{
    digitalWrite(ledPin, HIGH);
    sprintf(buf, "Hello!%d", n);
    Serial.println(buf);
    delay(500);
    digitalWrite(ledPin, LOW);
    delay(500);

    n++;
}

Ответы

Ответ 1

Используйте это:

String myString = String(n);

Ниже вы можете найти примеры .

Ответ 3

используйте функцию itoa(), включенную в stdlib.h

char buffer[7];         //the ASCII of the integer will be stored in this char array
itoa(-31596,buffer,10); //(integer, yourBuffer, base)

Ответ 4

Это оптимизированное по скорости решение для преобразования int (16-разрядное целое число) в строку.

Эта реализация избегает использования деления, поскольку 8-битный AVR, используемый для Arduino, не имеет аппаратной команды DIV, компилятор переводит деление на длительные повторяющиеся вычитания. Таким образом, самое быстрое решение использует условные ветки для построения строки.

Исправлен буфер с 7 байтами, полученный с начала в ОЗУ, чтобы избежать динамического распределения. Поскольку это всего 7 байт, стоимость использования фиксированной памяти считается минимальной. Чтобы помочь компилятору, мы добавляем модификатор регистра в объявление переменной для ускорения выполнения. 

char _int2str[7];
char* int2str( register int i ) {
  register unsigned char L = 1;
  register char c;
  register boolean m = false;
  register char b;  // lower-byte of i
  // negative
  if ( i < 0 ) {
    _int2str[ 0 ] = '-';
    i = -i;
  }
  else L = 0;
  // ten-thousands
  if( i > 9999 ) {
    c = i < 20000 ? 1
      : i < 30000 ? 2
      : 3;
    _int2str[ L++ ] = c + 48;
    i -= c * 10000;
    m = true;
  }
  // thousands
  if( i > 999 ) {
    c = i < 5000
      ? ( i < 3000
          ? ( i < 2000 ? 1 : 2 )
          :   i < 4000 ? 3 : 4
        )
      : i < 8000
        ? ( i < 6000
            ? 5
            : i < 7000 ? 6 : 7
          )
        : i < 9000 ? 8 : 9;
    _int2str[ L++ ] = c + 48;
    i -= c * 1000;
    m = true;
  }
  else if( m ) _int2str[ L++ ] = '0';
  // hundreds
  if( i > 99 ) {
    c = i < 500
      ? ( i < 300
          ? ( i < 200 ? 1 : 2 )
          :   i < 400 ? 3 : 4
        )
      : i < 800
        ? ( i < 600
            ? 5
            : i < 700 ? 6 : 7
          )
        : i < 900 ? 8 : 9;
    _int2str[ L++ ] = c + 48;
    i -= c * 100;
    m = true;
  }
  else if( m ) _int2str[ L++ ] = '0';
  // decades (check on lower byte to optimize code)
  b = char( i );
  if( b > 9 ) {
    c = b < 50
      ? ( b < 30
          ? ( b < 20 ? 1 : 2 )
          :   b < 40 ? 3 : 4
        )
      : b < 80
        ? ( i < 60
            ? 5
            : i < 70 ? 6 : 7
          )
        : i < 90 ? 8 : 9;
    _int2str[ L++ ] = c + 48;
    b -= c * 10;
    m = true;
  }
  else if( m ) _int2str[ L++ ] = '0';
  // last digit
  _int2str[ L++ ] = b + 48;
  // null terminator
  _int2str[ L ] = 0;  
  return _int2str;
}

// Usage example:
int i = -12345;
char* s;
void setup() {
  s = int2str( i );
}
void loop() {}

Этот эскиз скомпилирован в 1 082 байта кода с использованием avr-gcc, который в комплекте с Arduino v1.0.5 (размер самой функции int2str составляет 594 байта). По сравнению с решением, использующим объект String, который скомпилирован в 2,398 байт, эта реализация может уменьшить ваш размер кода на 1,2 Кб (предполагается, что вам не нужен другой метод объекта String, а ваш номер строго соответствует типу подписанного типа).

Эта функция может быть оптимизирована далее, написав ее соответствующим кодом ассемблера.

Ответ 5

Вам просто нужно обернуть его вокруг объекта String следующим образом:

String numberString = String(n);

Вы также можете сделать:

String stringOne = "Hello String";                     // using a constant String
String stringOne =  String('a');                       // converting a constant char into a String
String stringTwo =  String("This is a string");        // converting a constant string into a String object
String stringOne =  String(stringTwo + " with more");  // concatenating two strings
String stringOne =  String(13);                        // using a constant integer
String stringOne =  String(analogRead(0), DEC);        // using an int and a base
String stringOne =  String(45, HEX);                   // using an int and a base (hexadecimal)
String stringOne =  String(255, BIN);                  // using an int and a base (binary)
String stringOne =  String(millis(), DEC);             // using a long and a base

Ответ 6

Решение слишком велико. Попробуйте этот простой. Пожалуйста, предоставьте 7+-символьный буфер, никаких проверок.

char *i2str(int i, char *buf){
  byte l=0;
  if(i<0) buf[l++]='-';
  boolean leadingZ=true;
  for(int div=10000, mod=0; div>0; div/=10){
    mod=i%div;
    i/=div;
    if(!leadingZ || i!=0){
       leadingZ=false;
       buf[l++]=i+'0';
    }
    i=mod;
  }
  buf[l]=0;
  return buf;
}

Может быть легко изменен, чтобы вернуть конец буфера, если вы отбросите индекс "l" и сразу увеличите буфер.

Ответ 7

в первом примере используется классическая строка C: это всего лишь массив символов, заканчивающийся нулем (символ NUL). в других примерах используется класс String, класс С++, который я бы отдал далеко, кроме примеров игрушек и крошечных демоверсий. Он просачивает память способами, которые не так легко предсказать, и приводит к таинственным блокировкам платы.