Как получить несколько столбцов для использования в цикле курсора?
Когда я пытаюсь выполнить следующий фрагмент кода SQL внутри цикла курсора,
set @cmd = N'exec sp_rename ' + @test + N',' +
RIGHT(@test,LEN(@test)-3) + '_Pct' + N',''COLUMN'''
Получаю следующее сообщение:
Msg 15248, уровень 11, состояние 1, процедура sp_rename, строка 213
Либо параметр @objname неоднозначен, либо заявленный @objtype (COLUMN) ошибочен.
Что не так, и как я могу это исправить? Я попытался обернуть имя столбца в скобки [] и двойные кавычки "", как и некоторые из предложенных результатов поиска.
Изменить 1 -
Вот весь script. Как передать имя таблицы в rename sp? Я не уверен, как это сделать, поскольку имена столбцов находятся в одной из многих таблиц.
BEGIN TRANSACTION
declare @cnt int
declare @test nvarchar(128)
declare @cmd nvarchar(500)
declare Tests cursor for
SELECT COLUMN_NAME FROM INFORMATION_SCHEMA.COLUMNS WHERE COLUMN_NAME LIKE 'pct%' AND TABLE_NAME LIKE 'TestData%'
open Tests
fetch next from Tests into @test
while @@fetch_status = 0
BEGIN
set @cmd = N'exec sp_rename ' + @test + N',' + RIGHT(@test,LEN(@test)-3) + '_Pct' + N', column'
print @cmd
EXEC sp_executeSQL @cmd
fetch next from Tests into @test
END
close Tests
deallocate Tests
ROLLBACK TRANSACTION
--COMMIT TRANSACTION
Изменить 2 -
script предназначен для переименования столбцов, имена которых соответствуют шаблону, в данном случае с префиксом "pct". Столбцы встречаются в разных таблицах в базе данных. Все имена таблиц имеют префикс "TestData".
Ответы
Ответ 1
Вот немного измененная версия. Изменения отмечены как комментарии к коду.
BEGIN TRANSACTION
declare @cnt int
declare @test nvarchar(128)
-- variable to hold table name
declare @tableName nvarchar(255)
declare @cmd nvarchar(500)
-- local means the cursor name is private to this code
-- fast_forward enables some speed optimizations
declare Tests cursor local fast_forward for
SELECT COLUMN_NAME, TABLE_NAME
FROM INFORMATION_SCHEMA.COLUMNS
WHERE COLUMN_NAME LIKE 'pct%'
AND TABLE_NAME LIKE 'TestData%'
open Tests
-- Instead of fetching twice, I rather set up no-exit loop
while 1 = 1
BEGIN
-- And then fetch
fetch next from Tests into @test, @tableName
-- And then, if no row is fetched, exit the loop
if @@fetch_status <> 0
begin
break
end
-- Quotename is needed if you ever use special characters
-- in table/column names. Spaces, reserved words etc.
-- Other changes add apostrophes at right places.
set @cmd = N'exec sp_rename '''
+ quotename(@tableName)
+ '.'
+ quotename(@test)
+ N''','''
+ RIGHT(@test,LEN(@test)-3)
+ '_Pct'''
+ N', ''column'''
print @cmd
EXEC sp_executeSQL @cmd
END
close Tests
deallocate Tests
ROLLBACK TRANSACTION
--COMMIT TRANSACTION
Ответ 2
Вы говорите, чтобы переименовать столбец, но он не знает, в какой таблице находится столбец.
sp_rename:
[ @objname = ] 'object_name'
Является текущим квалифицированным или неквалифицированным именем объекта пользователя или типа данных. Если объект, который нужно переименовать, является столбцом в таблице, имя_объекта должно быть в форме table.column или schema.table.column.
(добавлен акцент)
