Git замедляет Emacs до смерти - как это исправить?

Открытие файла (либо путем ввода Ctrl-x f, AKA Find File), либо путем ввода f в этом файле в режиме Dired), в рабочих каталогах, имеющих подкаталог .git, очень медленно работает.

Даже самый простой файл (50 строк с комментариями) может занять до 8 секунд.

Тот же файл в другом каталоге, который не управляется Git, сразу открывается в jiffy.

Почему это происходит и как я могу исправить этот без отключения vc-mode? (поскольку одной из основных причин, по которым я использую Emacs, является его M-x ediff-revision)

ОБНОВЛЕНИЕ 1:. Благодаря ответу @sanityinc ниже я запустил профилирование ELP, и это то, что я получил (для очень маленького файла 69 строк, из которых 59 - простые комментарии):

Это отличная информация, но я не эксперт Emacs/elisp, так как, куда я могу перейти отсюда?

ОБНОВЛЕНИЕ 2: После того, как я поставил эту проблему на задний план какое-то время, я наткнулся на это замечательное сообщение в блоге: Cygwin slow start up: виновник обнаружен!, который, по существу, предполагает начало bash завершения в фоновом режиме. Я быстро внедрил его и повторно выполнил тест профилирования ELP:

Замечательно видеть, что vc-call-backend снижается с 23 до 14 секунд, но это все еще неприемлемо (поиск файла с контролем CVS занимает менее секунды)!

ОБНОВЛЕНИЕ 3: Невозможно решить тайну, я попробовал свою удачу, обновив ее до последней версии cygwin (1.7.9-1). Это не помогло.

Итак, я решил попробовать переместить песочницу (вместе с ее подкаталогом .git) из общего ресурса Samba в локальное хранилище (C:\Users\WinWin\Documents). Затем я повторил тест профилирования ELP:

Ничего себе! Это снизилось vc-call-backend с 14 секунд до 2 секунд. Это замечательно, но не замечательно, потому что с Emacs/ CVS я могу посетить файл в менее 35 мс - на том же Samba-ресурсе, где первоначально находится песочница:

Git в Emacs теперь быстрее, но он все еще намного медленнее CVS под Emacs. Поэтому я понятия не имею, почему git называется "Система управления быстрой версией". Это может быть лучше CVS, но быстрее?

Ответы

Ответ 1

Есть встроенный профайлер под названием ELP. Вы можете попробовать что-то вроде M-x elp-instrument-package, ввести "vc", а затем попробовать найти файл. Затем M-x elp-results покажет вам отчет о профиле.

(Обратите внимание, что если время вместо этого тратится на функции, не связанные с vc, этот метод не отображает его, но вы можете создавать дополнительные пакеты, если хотите.)

Ответ 2

Вы можете попробовать profile открыть файл, чтобы точно видеть, что занимает так много времени.

Ответ 3

Вы можете отключить vc-mode, установив vc-handled-backends в nil в .emacs.

Ответ 4

У меня была та же проблема с использованием окон git 2.10 из mingw emacs 25.1.1.

Для проверки выполните следующее:

(progn
  ;; make sure the buffer is not already open
  (elp-instrument-function 'find-file-other-window)
  (elp-instrument-function 'vc-git-registered)
  (elp-instrument-function 'vc-git-mode-line-string)
  (elp-instrument-function 'vc-git-find-file-hook)
  (find-file-other-window "my-file-in-a-git-repo")
  (elp-results)
  (elp-restore-all))

Предоставьте следующий профиль:

find-file-other-window   1           1.1076142     1.1076142
vc-git-mode-line-string  1           0.6396082     0.6396082
vc-git-find-file-hook    1           0.2652034     0.2652034
vc-git-registered        1           0.1872024     0.1872024

Функция vc-git-mode-line-string занимает некоторое время. Это показывает что-то вроде Git:mybranch в строке режима вашего окна. Мне все равно, что ждать его каждый раз, поэтому я перезаписываю реализацию, чтобы просто вернуть "Git":

(defun vc-git-mode-line-string (file)
  "Overwritten default vc-git-el implementation. Return a string
for `vc-mode-line' to put in the mode line for FILE."
  "Git")

Функция vc-git-find-file-hook откроет режим редактирования довольно конфликтных ситуаций, если вы откроете конфликтный файл. Реализация сначала вызывала vc-git-conflicted-files, которая занимает некоторое время, а затем делает довольно тривиальную проверку, начинаются ли какие-либо строки с <<<<<<<. Я просто поменял местами два, и теперь реализация занимает около 0,0 секунд в большинстве случаев.

(defun vc-git-find-file-hook ()
  "Overwritten default vc-git-el implementation. Activate
`smerge-mode' if there is a conflict."
  (when (and buffer-file-name
             ;; FIRST check whether this file looks like a conflicted file
             (save-excursion
               (goto-char (point-min))
               (re-search-forward "^<<<<<<< " nil 'noerror))
             ;; THEN ask git if it really is a conflict
             (vc-git-conflicted-files buffer-file-name))
    (vc-file-setprop buffer-file-name 'vc-state 'conflict)
    (smerge-start-session)
    (when vc-git-resolve-conflicts
      (add-hook 'after-save-hook 'vc-git-resolve-when-done nil 'local))
    (vc-message-unresolved-conflicts buffer-file-name)))

Результаты:

find-file-other-window   1           0.2838039     0.2838039
vc-git-registered        1           0.2682037     0.2682037
vc-git-find-file-hook    1           0.0           0.0
vc-git-mode-line-string  1           0.0           0.0