Удалять все файлы и папки рекурсивно с помощью Delphi

Я пытаюсь удалить папку и все ее подпапки рекурсивно, но она не работает вообще, так может кто-то, пожалуйста, проверьте код и скажите мне, что я делаю неправильно здесь?

Я запускаю этот код через D7 под Windows XP

if FindFirst (FolderPath + '\*', faAnyFile, f) = 0 then
      try             
         repeat

            if (f.Attr and faDirectory) <> 0 then
              begin
                    if (f.Name <> '.') and (f.Name <> '..') then
                      begin                            
                        RemoveDir(FolderPath +'\'+ f.Name);
                      end
                    else
                      begin
                        //Call function recursively...
                        ClearFolder(FolderPath +'\'+ f.Name, mask, recursive);
                      end;
              end;

         until (FindNext (f) <> 0);
      finally
        SysUtils.FindClose (f)
      end;
end;

Ответы

Ответ 1

Вместо того, чтобы выполнять всю эту тяжелую работу, я просто использую SHFileOperation:

uses
  ShellAPI;

procedure DeleteDirectory(const DirName: string);
var
  FileOp: TSHFileOpStruct;
begin
  FillChar(FileOp, SizeOf(FileOp), 0);
  FileOp.wFunc := FO_DELETE;
  FileOp.pFrom := PChar(DirName+#0);//double zero-terminated
  FileOp.fFlags := FOF_SILENT or FOF_NOERRORUI or FOF_NOCONFIRMATION;
  SHFileOperation(FileOp);
end;

Для чего стоит, проблема с вашим кодом заключается в том, что он никогда не звонит DeleteFile. И поэтому каталоги никогда не теряются, вызовы RemoveDir терпят неудачу и так далее. Отсутствие проверки ошибок в вашем коде не очень помогает, но добавление кода для удаления файлов приведет к получению кода в полупристойной форме. Вам также необходимо позаботиться о рекурсии. Вы должны убедиться, что все дети удалены сначала, а затем родительский контейнер. Это требует определенной квалификации, чтобы получить право. Основной подход таков:

procedure DeleteDirectory(const Name: string);
var
  F: TSearchRec;
begin
  if FindFirst(Name + '\*', faAnyFile, F) = 0 then begin
    try
      repeat
        if (F.Attr and faDirectory <> 0) then begin
          if (F.Name <> '.') and (F.Name <> '..') then begin
            DeleteDirectory(Name + '\' + F.Name);
          end;
        end else begin
          DeleteFile(Name + '\' + F.Name);
        end;
      until FindNext(F) <> 0;
    finally
      FindClose(F);
    end;
    RemoveDir(Name);
  end;
end;

Я пропустил проверку ошибок для ясности, но вы должны проверить возвращаемые значения DeleteFile и RemoveDir.

Ответ 2

procedure DeleteDir(const DirName: string);
var
  Path: string;
  F: TSearchRec;

begin
  Path:= DirName + '\*.*';
  if FindFirst(Path, faAnyFile, F) = 0 then begin
    try
      repeat
        if (F.Attr and faDirectory <> 0) then begin
          if (F.Name <> '.') and (F.Name <> '..') then begin
            DeleteDir(DirName + '\' + F.Name);
          end;
        end
        else
          DeleteFile(DirName + '\' + F.Name);
      until FindNext(F) <> 0;
    finally
      FindClose(F);
    end;
  end;
  RemoveDir(DirName);
end;