Внедрение концепции ключевых значений в XSLT

Я работаю над XSLT, где мне нужно что-то реализовать следующим образом. Пример исходного XML-кода выглядит следующим образом.

Считайте, что есть список пары ключевых значений.

Мне нужно написать xslt таким образом, что для каждого заполнения ключа "A" необходимо заменить соответствующим значением.

Мне также нужно указать список пар значений ключа в том же XSLT. Выходной сигнал:

Может кто-нибудь помочь мне, как это сделать.

Ответы

Ответ 1

I. Простое решение XSLT 1.0

Это преобразование:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <my:codes>
   <code key="A" value="Algebra"/>
   <code key="B" value="Biology"/>
   <code key="C" value="Chemistry"/>
   <code key="D" value="Data Analysis"/>
 </my:codes>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match=
  "title/text()[. = document('')/*/my:codes/*/@key]">

  <xsl:value-of select=
   "document('')/*/my:codes/*[@key=current()]/@value"/>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному XML-документу:

<catalog>
    <cd>
        <title>A</title>
        <title>B</title>
        <title>C</title>
    </cd>
</catalog>

создает желаемый, правильный результат:

<catalog>
   <cd>
      <title>Algebra</title>
      <title>Biology</title>
      <title>Chemistry</title>
   </cd>
</catalog>

Объяснение

Это стандартный способ включения встроенного XML node в качестве глобального элемента (дочерний элемент xsl:stylesheet), который принадлежит пространству имен (непустое), отличному от пространства имен xsl.

II. Более эффективное решение XSLT 1.0, используя клавиши:

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     xmlns:my="my:my">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>
     <xsl:strip-space elements="*"/>

     <my:codes>
       <code key="A" value="Algebra"/>
       <code key="B" value="Biology"/>
       <code key="C" value="Chemistry"/>
       <code key="D" value="Data Analysis"/>
     </my:codes>

     <xsl:key name="kCodeByName" match="code" use="@key"/>

     <xsl:template match="node()|@*">
      <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
     </xsl:template>

     <xsl:template match=
      "title/text()[. = document('')/*/my:codes/*/@key]">

      <xsl:variable name="vCur" select="."/>

      <xsl:for-each select="document('')">
          <xsl:value-of select=
           "key('kCodeByName', $vCur)/@value"/>
      </xsl:for-each>
     </xsl:template>
</xsl:stylesheet>

, когда это преобразование применяется к одному и тому же XML-документу (см. выше), получается тот же правильный, желаемый результат:

<catalog>
   <cd>
      <title value="Algebra"/>
      <title value="Biology"/>
      <title value="Chemistry"/>
   </cd>
</catalog>

Объяснение

Доступ к данным с помощью функции key() обычно является сублинейным - часто O (1) и чрезвычайно быстрым, чем линейный поиск (что важно, если количество узлов, которые нужно искать, велико).

Доступ к node одного документа с помощью индекса (xsl:key) при обработке node другого документа возможен, если документ, содержащий node для поиска, является текущим документом. Чтобы получить доступ к узлам из другого документа, его корень (или node интерес должен быть сохранен и привязан к переменной).

III. Решение XSLT 2.0:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vCodes">
  <codes>
   <code key="A" value="Algebra"/>
   <code key="B" value="Biology"/>
   <code key="C" value="Chemistry"/>
   <code key="D" value="Data Analysis"/>
  </codes>
 </xsl:variable>

 <xsl:key name="kCodeByName" match="code" use="string(@key)"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match=
  "title/text()[key('kCodeByName', ., $vCodes)]">

  <xsl:sequence select=
   "key('kCodeByName', ., $vCodes)/@value"/>
 </xsl:template>
</xsl:stylesheet>

<catalog>
   <cd>
      <title value="Algebra"/>
      <title value="Biology"/>
      <title value="Chemistry"/>
   </cd>
</catalog>

Объяснение

Почти то же самое, что и эффективное решение XSLT 1.0, но:

В XSLT 2.0 шаблон соответствия шаблонов может содержать ссылку на переменную.
В XSLT 2.0 нет необходимости в акробатических трюках, управляющих текущим и индексированным документами. Третий аргумент функции key() - это указать дерево, индекс которого будет использоваться.