Как перенести данные столбцов в строки (с awk)?

У меня есть файл вроде этого:

n A B C D 
1 01 02 01 01
2 02 02 01 01

и я хочу передать столбцы по строкам, поэтому вывод должен выглядеть следующим образом:

Я написал эту команду:

awk '{ for (i=1;i<=NF;i++ ) printf $i " " }' file.txt > out-file.txt

проблема в том, что эта команда помещает все в одну строку! поэтому вывод выглядит следующим образом:

n 1 2 A 01 02 B 02 02 C 01 01 D 01 01

Ответы

Ответ 1

Это может сработать:

awk '{
       for (f = 1; f <= NF; f++) { a[NR, f] = $f } 
     }
     NF > nf { nf = NF }
     END {
       for (f = 1; f <= nf; f++) {
           for (r = 1; r <= NR; r++) {
               printf a[r, f] (r==NR ? RS : FS)
           }
       }
    }' YOURINPUT

Смотрите в действии @Идеал.

Ответ 2

Сохраните этот script как transpose.awk и chmod u+x transpose.awk. Это модификация Тим Шервуд transpose.

#!/usr/bin/gawk -f

BEGIN {
    max_x =0;
    max_y =0;
}

{
    max_y++;
    for( i=1; i<=NF; i++ )
    {
        if (i>max_x) max_x=i;
        A[i,max_y] = $i;
    }
}

END {
    for ( x=1; x<=max_x; x++ )
    {
        for ( y=1; y<=max_y; y++ )
        {
            if ( (x,y) in A ) printf "%s",A[x,y];
            if ( y!=max_y ) printf " ";
        }
        printf "\n";
    }
}

Пример:

$ ./transpose.awk example
n 1 2
A 01 02
B 02 02
C 01 01
D 01 01

Ответ 3

Было бы проще использовать rs:

$ cat /tmp/a
n A B C D
1 01 02 01 01
2 02 02 01 01
$ rs -c' ' -C' ' -T</tmp/a
n 1 2
A 01 02
B 02 02
C 01 01
D 01 01

-c изменяет разделитель входных столбцов, -c изменяет разделитель выходных столбцов, а -T переносит строки и столбцы.

Ответ 4

Ну, без awk мы можем сделать это с помощью cat:

for x in `cat filename`
do
echo $x
done

При этом script результат появится в cols.

Ответ 5

Вот другое решение, которое включает в себя только один для цикла в конце:

{ for (i=1; i<=NF; i++) col[i] = col[i] " " $i }
END { 
    for (i=1; i<=NF; i++) { 
        sub(/^ /, "", col[i]); 
        print col[i] 
    } 
}

Обсуждение

В этом решении используется одномерный массив col, который сохраняет значение для всего столбца. col [1] - это первый столбец.
Для каждой строки мы добавляем столбец в col [i]. Поскольку мы слепо добавим, значение col [i] будет содержать ведущее пространство.
В конце функция sub() удаляет ведущее белое пространство перед печатью столбца (теперь строка)