Общий lisp: переопределить существующую функцию в пределах области?

Ответ 1

В рамках данной лексической области да. Используйте FLET или LABELS. Любая функция, определенная с помощью FLET, не сможет вызывать функции, определенные в той же лексической области, если вы хотите, чтобы это (например, саморекурсивное из группы взаимно-рекурсивных функций), вам нужно будет использовать LABELS.

Обратите внимание, что и FLET, и LABELS устанавливают только лексическое затенение, не должны использоваться для теневых функций из пакета COMMON- LISP и не будут динамически изменять, какую функцию вызывается из-за пределов лексической области, которую создает форма.

Ответ 2

Локальные функции могут быть введены с помощью FLET и LABELS.

Ответ 3

Если вы хотите переопределить/закрыть существующую функцию с помощью динамической области, это макрос, который я использовал некоторое время.

(defmacro! with-shadow ((fname fun) &body body)
  "Shadow the function named fname with fun
   Any call to fname within body will use fun, instead of the default function for fname.
   This macro is intentionally unhygienic:
   fun-orig is the anaphor, and can be used in body to access the shadowed function"
  `(let ((fun-orig))
     (cond ((fboundp ',fname)
            (setf fun-orig (symbol-function ',fname))
            (setf (symbol-function ',fname) ,fun)
            (unwind-protect (progn ,@body)
              (setf (symbol-function ',fname) fun-orig)))
           (t
            (setf (symbol-function ',fname) ,fun)
            (unwind-protect (progn ,@body)
              (fmakunbound ',fname))))))

Использование:

Clozure Common Lisp Version 1.9-r15759  (DarwinX8664)  Port: 4005  Pid: 4728
; SWANK 2012-03-06
CL-USER>  
(defun print-using-another-fname (x)
  (print x))
PRINT-USING-ANOTHER-FNAME

CL-USER> 
(let ((*warn-if-redefine-kernel* nil))
  (with-shadow (print (lambda (x)
                        (funcall fun-orig (+ x 5))))
    (print-using-another-fname 10)))

15 
15
CL-USER>                
(print 10)

10 
10
CL-USER> 

Обратите внимание, что он полагается на Doug Hoyte defmacro! макрос, доступный в Let Over Lambda.

Также как написано, это анафорично (fun-orig доступно в теле). Если вы хотите, чтобы он был полностью гигиеничным, просто измените fun-orig, g! Fun-orig.

Я чаще всего переопределяю функции при написании модульных тестов. Смехотворные функции в рамках конкретного unit test полезны, и иногда это необходимо делать с динамической (не лексической) областью.

Ответ 4

Вы можете имитировать динамическое связывание для таких забав:

(defmacro setvfun (symbol function)
      `(progn
         (setf ,symbol ,function)
         (setf (symbol-function ',symbol) (lambda (&rest args) (apply (symbol-value ',symbol) args)))))

а затем, например, с

(setvfun some-fun (lambda() (format t "initial-definition~%")))
(defun test-the-fun (&rest args) (apply #'some-fun args))

(defun test ()
   (test-the-fun)
   (flet ((some-fun () (format t "Lexically REDEFINED (if you see this, something is very wrong)~%")))
      (test-the-fun))
   (let ((some-fun (lambda (x) (format t "Dynamically REDEFINED with args: ~a~%" x))))
       (declare (special some-fun))
       (test-the-fun "Hello"))
   (test-the-fun))

вы получаете:

REPL> (test)
==>initial-definition
==>initial-definition
==>Dynamically REDEFINED with args: Hello
==>initial-definition