Ответ 1
declare @dt datetime
set @dt = '09-22-2007 15:07:38.850'
select dateadd(mi, datediff(mi, 0, @dt), 0)
select dateadd(hour, datediff(hour, 0, @dt), 0)
вернет
2007-09-22 15:07:00.000
2007-09-22 15:00:00.000
Вышеуказанное просто обрезает секунды и минуты, создавая результаты, заданные в вопросе. Как заметил @OMG Ponies, если вы хотите округлить вверх/вниз, то вы можете добавить полминуты или полчаса соответственно, а затем усечь:
select dateadd(mi, datediff(mi, 0, dateadd(s, 30, @dt)), 0)
select dateadd(hour, datediff(hour, 0, dateadd(mi, 30, @dt)), 0)
и вы получите:
2007-09-22 15:08:00.000
2007-09-22 15:00:00.000
До того, как в SQL Server 2008 был добавлен тип данных date, я бы использовал вышеуказанный метод, чтобы урезать временную часть из даты и времени, чтобы получить только дату. Идея состоит в том, чтобы определить количество дней между рассматриваемым временем и фиксированной точкой во времени (0, которое неявно переходит к 1900-01-01 00:00:00.000):
declare @days int
set @days = datediff(day, 0, @dt)
а затем добавьте это количество дней в фиксированную точку во времени, что дает вам исходную дату со временем, установленным на 00:00:00.000:
select dateadd(day, @days, 0)
или более лаконично:
select dateadd(day, datediff(day, 0, @dt), 0)
Использование другой datepart (например, hour, mi) будет работать соответственно.