Как объединить данные из разных баз данных?

Я столкнулся с необходимостью объединения двух выборок из разных баз данных, а именно парадокса (в bde) и ms sql-сервера.

В настоящее время bde (через TQuery) используется только в этой части программы (т.е. dbgrid). Теперь мне нужно добавить некоторые данные, хранящиеся в базе данных ms sql server (с которой я обычно использую TADOQuery) в той же сетке.

Хотя запросы выполняются по совершенно другим таблицам, набор результатов столбцов называется и вводится аналогично (я имею в виду, если бы у меня были эти таблицы, скажем, в базе данных sq sql ms, я мог бы использовать для этого тривиальный союз).

Есть ли способ объединить записи, выбранные из них в delphi7, чтобы я мог использовать результат в качестве источника данных для dbgrid?

Ответы

Ответ 1

Вы можете использовать clientdataset, созданный с помощью определений, например. набор данных вашего набора данных SQL-Server и добавьте данные вашего набора данных парадокса. TFieldDefArray может быть пустым в вашем случае.

type
  TMyFieldDef = Record
    Name: String;
    Size: Integer;
    DataType: TFieldType;
  end;

  TFieldDefArray = array of TMyFieldDef;


function GetClientDSForDS(ADataSet: TDataSet; AFieldDefArray: TFieldDefArray; AClientDataSet: TClientDataSet = nil; WithRecords: Boolean = true)
  : TClientDataSet;
var
  i: Integer;
  Function NoAutoInc(ft: TFieldType): TFieldType;
  begin
    if ft = ftAutoInc then
      Result := ftInteger
    else
      Result := ft;
  end;

begin

  if Assigned(AClientDataSet) then
    Result := AClientDataSet
  else
    Result := TClientDataSet.Create(nil);
  Result.Close;
  Result.FieldDefs.Clear;

  for i := 0 to ADataSet.FieldCount - 1 do
  begin
    Result.FieldDefs.Add(ADataSet.Fields[i].FieldName, NoAutoInc(ADataSet.Fields[i].DataType), ADataSet.Fields[i].Size);
  end;

  for i := 0 to High(AFieldDefArray) do
    Result.FieldDefs.Add(AFieldDefArray[i].Name, AFieldDefArray[i].DataType, AFieldDefArray[i].Size);

  Result.CreateDataSet;
  for i := 0 to ADataSet.FieldCount - 1 do
  begin
    Result.FieldByName(ADataSet.Fields[i].FieldName).DisplayLabel := ADataSet.Fields[i].DisplayLabel;
    Result.FieldByName(ADataSet.Fields[i].FieldName).Visible := ADataSet.Fields[i].Visible;
  end;

  if WithRecords then
  begin
    ADataSet.First;
    while not ADataSet.Eof do
    begin
      Result.Append;
      for i := 0 to ADataSet.FieldCount - 1 do
      begin
        Result.FieldByName(ADataSet.Fields[i].FieldName).Assign(ADataSet.Fields[i]);
      end;
      Result.Post;
      ADataSet.Next;
    end;
  end;
end;

Другая попытка может создать связанный сервер для парадокса, я не пробовал это...

http://www.experts-exchange.com/Microsoft/Development/MS-SQL-Server/SQL_Server_2008/Q_24067488.html

Ответ 2

Нет проблем с AnyDAC LocalSQL. Вы можете выполнить SQL с любым DataSet, не только выбрать SQL, вставить, обновить, удалить SQL тоже.

Ответ 3

Вы можете использовать встроенную функцию TClientDataSet для объединения данных путем добавления данных из второго набора данных к данным первого.

Существуют разные способы сделать это, мой предпочтительный, потому что простой код должен был добавить два DataSetProviders и связать их с каждым из ваших наборов данных, например

dspBDE.DataSet := MyTQuery;
dspADO.DataSet := MyAdoQuery;

Затем, чтобы открыть свои DataSets, вы можете просто сделать:

MyClientDataSet.Data := dspBDE.Data;
MyClientDataSet.AppendData(dspADO.Data, True);

Чтобы это работало, оба набора данных должны соответствовать номеру поля и типам данных. Так как ваши структуры схожи, вы можете работать при типизации в вашем SQL, если это не происходит автоматически.

Ответ 4

BDE поддерживает (или поддерживается) разнородные запросы Это позволяет запросам охватывать более одного набора данных, но с ограниченным синтаксисом SQL.

IIRC Я использовал несколько десятков лет назад для некоторых быстрых "грязных" данных, но я не помню специфику - я не коснулся BDE в течение многих лет.

Ответ 5

Несколько лет назад (Delphi 7) я использовал TxQuery, но я не знаю, если он все еще находится в разработке

Я нашел ссылку