Последовательные подмножества списка

С учетом списка

{"a", "b", "c", "d"}

Есть ли более простой способ генерации списка последовательных подмножеств, подобных этому (порядок результата не важен)

{
 {"a"},
 {"a b"},
 {"a b c"},
 {"a b c d"},
 {"b"},
 {"b c"},
 {"b c d"},
 {"c"},
 {"c d"},
 {"d"}
}

Ответы

Ответ 1

Мне кажется, мне это больше всего нравится:

set = {"a", "b", "c", "d"};

ReplaceList[set, {___, x__, ___} :> {x}]

С соединением строки:

ReplaceList[set, {___, x__, ___} :> "" <> Riffle[{x}, " "]]

В аналогичном ключе, специфичном для строк:

StringCases["abcd", __, Overlaps -> All]

Поскольку Насер говорит, что я обманываю, вот более ручной подход, который также имеет большую эффективность для больших наборов:

ClearAll[f, f2]
f[i_][x_] := NestList[i, x, [email protected] - 1]
f2[set_]  := Join @@ ( f[Most] /@ f[Rest][set] )

f2[{"a", "b", "c", "d"}]

Ответ 2

Flatten[Partition[{a, b, c, d}, #, 1] & /@ {1, 2, 3, 4}, 1]

дает

{{a}, {b}, {c}, {d}, {a, b}, {b, c}, {c, d}, {a, b, c}, {b, c, d}, {a, b, c, d}}

Ответ 3

Как насчет этого:

origset = {"a", "b", "c", "d"};

bdidxset = Subsets[Range[4], {1, 2}]

origset[[#[[1]] ;; #[[-1]]]] & /@ bdidxset

который дает

{{"a"}, {"b"}, {"c"}, {"d"}, {"a", "b"}, {"a", "b", "c"}, {"a", "b", 
  "c", "d"}, {"b", "c"}, {"b", "c", "d"}, {"c", "d"}}

Ответ 4

Мне нравится метод TomD лучше, но это то, что мне пришло в голову, без строковой обработки:

set = {"a", "b", "c", "d"};

n = [email protected];

Join @@ Table[set~Take~{s, f}, {s, n}, {f, s, n}] // Column

Ответ 5

Вы можете сделать это следующим образом:

a = {"a", "b", "c", "d"};
b = List[StringJoin[Riffle[#, " "]]] & /@
  Flatten[Table[c = Drop[a, n];
    Table[Take[c, i], {i, Length[c]}],
    {n, 0, Length[a]}], 1]

вывод будет выглядеть следующим образом:

{{"a"}, {"a b"}, {"a b c"}, {"a b c d"}, {"b"}, {"b c"}, {"b c d"}, {"c"}, {"c d"}, {"d"}}

Ответ 6

Вот одно возможное решение

a={"a","b","c","d"};
[email protected][#, " "] & /@ 
  DeleteDuplicates[
   LongestCommonSubsequence[a, #] & /@ 
    DeleteCases[[email protected], {}]] // Column

Результат

a
b
c
d
a b
b c
c d
a b c
b c d
a b c d

Ответ 7

в одну сторону:

makeList[lst_] := Map[ Union[lst[[1 ;; #]]] &, [email protected][lst]]
r = Map[makeList[lst[[# ;; -1]]] &, [email protected][lst]];
Flatten[r, 1]

дает

{{"a"}, 
 {"a", "b"}, 
 {"a", "b", "c"}, 
 {"a", "b", "c", "d"}, 
 {"b"},
 {"b", "c"},
 {"b", "c", "d"},
 {"c"}, 
 {"c", "d"}, 
 {"d"}}