Случайные/шумовые функции для GLSL

Ответ 1

Для очень простых псевдослучайных вещей я использую этот oneliner, который я нашел где-то в Интернете:

float rand(vec2 co){
    return fract(sin(dot(co.xy ,vec2(12.9898,78.233))) * 43758.5453);
}

Вы также можете генерировать шумовую текстуру, используя любой PRNG, который вам нравится, затем загружать его обычным способом и выбирать значения в вашем шейдере; Я могу выкопать образец кода позже, если вы хотите.

Кроме того, проверьте этот файл для GLSL-реализаций шума Perlin и Simplex, Stefan Gustavson.

Ответ 2

Реализация Gustavson использует 1D текстуру

Нет, нет, не с 2005 года. Просто люди настаивают на загрузке старой версии. Версия, указанная в приведенной ссылке, использует только 8-битные 2D-текстуры.

Новая версия Ian McEwan из Ashima и меня не использует текстуру, но работает на половине скорости на обычных настольных платформах с большим количеством полосы пропускания текстуры. На мобильных платформах версия без текстур может быть быстрее, потому что текстурирование часто является значительным узким местом.

Наш активно поддерживаемый исходный репозиторий:

https://github.com/ashima/webgl-noise

Здесь собраны как текстурные, так и текстурированные версии шума (используя только 2D-текстуры):

http://www.itn.liu.se/~stegu/simplexnoise/GLSL-noise-vs-noise.zip

Если у вас есть какие-либо конкретные вопросы, не стесняйтесь напрямую отправлять мне по электронной почте (мой адрес электронной почты можно найти в источниках classicnoise*.glsl.)

Ответ 3

Мне кажется, что вы можете использовать простую целочисленную хэш-функцию и вставить результат в поплавок мантиссы. IIRC спецификация GLSL гарантирует 32-разрядные целые числа без знака и представление IEEE binary32 float, поэтому оно должно быть совершенно портативным.

Я попробовал только сейчас. Результаты очень хорошие: он выглядит точно так же, как и статичный, с каждым входом, который я пытался, без видимых шаблонов. Напротив, популярный фрагмент sin/fract имеет довольно выраженные диагональные линии на моем GPU, учитывая те же самые входы.

Одним из недостатков является то, что для этого требуется GLSL v3.30. И хотя это кажется достаточно быстрым, я не эмпирически оценил его производительность. AMD Shader Analyzer утверждает, что 13,33 пикселя за такт для версии vec2 на HD5870. Контрастность с 16 пикселями за такт для фрагмента sin/fract. Так что это, конечно, немного медленнее.

Вот моя реализация. Я оставил его в различных перестановках идеи, чтобы облегчить получение ваших собственных функций.

/*
    static.frag
    by Spatial
    05 July 2013
*/

#version 330 core

uniform float time;
out vec4 fragment;



// A single iteration of Bob Jenkins' One-At-A-Time hashing algorithm.
uint hash( uint x ) {
    x += ( x << 10u );
    x ^= ( x >>  6u );
    x += ( x <<  3u );
    x ^= ( x >> 11u );
    x += ( x << 15u );
    return x;
}



// Compound versions of the hashing algorithm I whipped together.
uint hash( uvec2 v ) { return hash( v.x ^ hash(v.y)                         ); }
uint hash( uvec3 v ) { return hash( v.x ^ hash(v.y) ^ hash(v.z)             ); }
uint hash( uvec4 v ) { return hash( v.x ^ hash(v.y) ^ hash(v.z) ^ hash(v.w) ); }



// Construct a float with half-open range [0:1] using low 23 bits.
// All zeroes yields 0.0, all ones yields the next smallest representable value below 1.0.
float floatConstruct( uint m ) {
    const uint ieeeMantissa = 0x007FFFFFu; // binary32 mantissa bitmask
    const uint ieeeOne      = 0x3F800000u; // 1.0 in IEEE binary32

    m &= ieeeMantissa;                     // Keep only mantissa bits (fractional part)
    m |= ieeeOne;                          // Add fractional part to 1.0

    float  f = uintBitsToFloat( m );       // Range [1:2]
    return f - 1.0;                        // Range [0:1]
}



// Pseudo-random value in half-open range [0:1].
float random( float x ) { return floatConstruct(hash(floatBitsToUint(x))); }
float random( vec2  v ) { return floatConstruct(hash(floatBitsToUint(v))); }
float random( vec3  v ) { return floatConstruct(hash(floatBitsToUint(v))); }
float random( vec4  v ) { return floatConstruct(hash(floatBitsToUint(v))); }





void main()
{
    vec3  inputs = vec3( gl_FragCoord.xy, time ); // Spatial and temporal inputs
    float rand   = random( inputs );              // Random per-pixel value
    vec3  luma   = vec3( rand );                  // Expand to RGB

    fragment = vec4( luma, 1.0 );
}

Скриншот:

Я просмотрел скриншот в программе редактирования изображений. Есть 256 цветов, а среднее значение - 127, что означает, что распределение равномерно и охватывает ожидаемый диапазон.

Ответ 4

Золотой шум

// Gold Noise ©2015 [email protected] 
//  - based on the Golden Ratio, PI and Square Root of Two
//  - superior distribution
//  - fastest noise generator function
//  - works with all chipsets (including low precision)

float PHI = 1.61803398874989484820459 * 00000.1; // Golden Ratio   
float PI  = 3.14159265358979323846264 * 00000.1; // PI
float SQ2 = 1.41421356237309504880169 * 10000.0; // Square Root of Two

float gold_noise(in vec2 coordinate, in float seed){
    return fract(tan(distance(coordinate*(seed+PHI), vec2(PHI, PI)))*SQ2);
}

Смотрите Золотой шум в вашем браузере прямо сейчас!

Эта функция улучшила случайное распределение по текущей функции в ответе @appas от 9 сентября 2017 года:

Функция @appas также неполная, учитывая, что начальное число не поставляется (уф не является начальным значением - одинаково для каждого кадра) и не работает с чипсетами низкой точности. Gold Noise по умолчанию работает с низкой точностью (намного быстрее).

Ответ 5

Существует также хорошая реализация, описанная здесь от McEwan и @StefanGustavson, которая выглядит как шум Perlin, но "не требует никакой настройки, т.е. не текстуры и равномерные массивы. Просто добавьте его в исходный код шейдера и вызовите его везде, где хотите".

Это очень удобно, особенно учитывая, что ранее реализация Gustavson, связанная с @dep, использует 1D-текстуру, которая не поддерживается в GLSL ES (шейдерный язык WebGL).

Ответ 6

Только что нашел эту версию 3d-шума для GPU, он стал самым быстрым из доступных:

#ifndef __noise_hlsl_
#define __noise_hlsl_

// hash based 3d value noise
// function taken from https://www.shadertoy.com/view/XslGRr
// Created by inigo quilez - iq/2013
// License Creative Commons Attribution-NonCommercial-ShareAlike 3.0 Unported License.

// ported from GLSL to HLSL

float hash( float n )
{
    return frac(sin(n)*43758.5453);
}

float noise( float3 x )
{
    // The noise function returns a value in the range -1.0f -> 1.0f

    float3 p = floor(x);
    float3 f = frac(x);

    f       = f*f*(3.0-2.0*f);
    float n = p.x + p.y*57.0 + 113.0*p.z;

    return lerp(lerp(lerp( hash(n+0.0), hash(n+1.0),f.x),
                   lerp( hash(n+57.0), hash(n+58.0),f.x),f.y),
               lerp(lerp( hash(n+113.0), hash(n+114.0),f.x),
                   lerp( hash(n+170.0), hash(n+171.0),f.x),f.y),f.z);
}

#endif

Ответ 7

Прямая, зубчатая версия 1d Perlin, по существу, случайная зигзаг.

half  rn(float xx){         
    half x0=floor(xx);
    half x1=x0+1;
    half v0 = frac(sin (x0*.014686)*31718.927+x0);
    half v1 = frac(sin (x1*.014686)*31718.927+x1);          

    return (v0*(1-frac(xx))+v1*(frac(xx)))*2-1*sin(xx);
}

Я также нашел 1-2-3-4d perlin noise на shadertoy owner inigo quilez perlin tutorial website, и voronoi и т.д., У него есть полные быстрые реализации и коды для них.

Ответ 8

hash: В настоящее время существует webGL2.0, поэтому целые числа доступны в (w) GLSL. → для качественного переносимого хеша (при той же цене, что и уродливые хеш-значения) теперь мы можем использовать "серьезные" методы хеширования IQ реализовал некоторые в https://www.shadertoy.com/view/XlXcW4 (и больше)

Например:

  const uint k = 1103515245U;  // GLIB C
//const uint k = 134775813U;   // Delphi and Turbo Pascal
//const uint k = 20170906U;    // Today date (use three days ago dateif you want a prime)
//const uint k = 1664525U;     // Numerical Recipes

vec3 hash( uvec3 x )
{
    x = ((x>>8U)^x.yzx)*k;
    x = ((x>>8U)^x.yzx)*k;
    x = ((x>>8U)^x.yzx)*k;

    return vec3(x)*(1.0/float(0xffffffffU));
}

Ответ 9

Используйте это:

highp float rand(vec2 co)
{
    highp float a = 12.9898;
    highp float b = 78.233;
    highp float c = 43758.5453;
    highp float dt= dot(co.xy ,vec2(a,b));
    highp float sn= mod(dt,3.14);
    return fract(sin(sn) * c);
}

Не используйте это:

float rand(vec2 co){
    return fract(sin(dot(co.xy ,vec2(12.9898,78.233))) * 43758.5453);
}

Вы можете найти объяснение в Усовершенствованиях канонического однострочного GLSL rand() для OpenGL ES 2.0

Ответ 10

Ниже приведен пример того, как добавить белый шум к визуализированной текстуре. Решение состоит в том, чтобы использовать две текстуры: оригинальный и чистый белый шум, например этот: wiki white noise

private static final String VERTEX_SHADER =
    "uniform mat4 uMVPMatrix;\n" +
    "uniform mat4 uMVMatrix;\n" +
    "uniform mat4 uSTMatrix;\n" +
    "attribute vec4 aPosition;\n" +
    "attribute vec4 aTextureCoord;\n" +
    "varying vec2 vTextureCoord;\n" +
    "varying vec4 vInCamPosition;\n" +
    "void main() {\n" +
    "    vTextureCoord = (uSTMatrix * aTextureCoord).xy;\n" +
    "    gl_Position = uMVPMatrix * aPosition;\n" +
    "}\n";

private static final String FRAGMENT_SHADER =
        "precision mediump float;\n" +
        "uniform sampler2D sTextureUnit;\n" +
        "uniform sampler2D sNoiseTextureUnit;\n" +
        "uniform float uNoseFactor;\n" +
        "varying vec2 vTextureCoord;\n" +
        "varying vec4 vInCamPosition;\n" +
        "void main() {\n" +
                "    gl_FragColor = texture2D(sTextureUnit, vTextureCoord);\n" +
                "    vec4 vRandChosenColor = texture2D(sNoiseTextureUnit, fract(vTextureCoord + uNoseFactor));\n" +
                "    gl_FragColor.r += (0.05 * vRandChosenColor.r);\n" +
                "    gl_FragColor.g += (0.05 * vRandChosenColor.g);\n" +
                "    gl_FragColor.b += (0.05 * vRandChosenColor.b);\n" +
        "}\n";

Общий фрагмент содержит параметр uNoiseFactor, который обновляется при каждом рендеринге по основному приложению:

float noiseValue = (float)(mRand.nextInt() % 1000)/1000;
int noiseFactorUniformHandle = GLES20.glGetUniformLocation( mProgram, "sNoiseTextureUnit");
GLES20.glUniform1f(noiseFactorUniformHandle, noiseFactor);

Ответ 11

Я перевел одну из Java-реализаций Кена Перлина на GLSL и использовал ее в нескольких проектах на ShaderToy.

Ниже приводится интерпретация GLSL, которую я сделал:

int b(int N, int B) { return N>>B & 1; }
int T[] = int[](0x15,0x38,0x32,0x2c,0x0d,0x13,0x07,0x2a);
int A[] = int[](0,0,0);

int b(int i, int j, int k, int B) { return T[b(i,B)<<2 | b(j,B)<<1 | b(k,B)]; }

int shuffle(int i, int j, int k) {
    return b(i,j,k,0) + b(j,k,i,1) + b(k,i,j,2) + b(i,j,k,3) +
        b(j,k,i,4) + b(k,i,j,5) + b(i,j,k,6) + b(j,k,i,7) ;
}

float K(int a, vec3 uvw, vec3 ijk)
{
    float s = float(A[0]+A[1]+A[2])/6.0;
    float x = uvw.x - float(A[0]) + s,
        y = uvw.y - float(A[1]) + s,
        z = uvw.z - float(A[2]) + s,
        t = 0.6 - x * x - y * y - z * z;
    int h = shuffle(int(ijk.x) + A[0], int(ijk.y) + A[1], int(ijk.z) + A[2]);
    A[a]++;
    if (t < 0.0)
        return 0.0;
    int b5 = h>>5 & 1, b4 = h>>4 & 1, b3 = h>>3 & 1, b2= h>>2 & 1, b = h & 3;
    float p = b==1?x:b==2?y:z, q = b==1?y:b==2?z:x, r = b==1?z:b==2?x:y;
    p = (b5==b3 ? -p : p); q = (b5==b4 ? -q : q); r = (b5!=(b4^b3) ? -r : r);
    t *= t;
    return 8.0 * t * t * (p + (b==0 ? q+r : b2==0 ? q : r));
}

float noise(float x, float y, float z)
{
    float s = (x + y + z) / 3.0;  
    vec3 ijk = vec3(int(floor(x+s)), int(floor(y+s)), int(floor(z+s)));
    s = float(ijk.x + ijk.y + ijk.z) / 6.0;
    vec3 uvw = vec3(x - float(ijk.x) + s, y - float(ijk.y) + s, z - float(ijk.z) + s);
    A[0] = A[1] = A[2] = 0;
    int hi = uvw.x >= uvw.z ? uvw.x >= uvw.y ? 0 : 1 : uvw.y >= uvw.z ? 1 : 2;
    int lo = uvw.x <  uvw.z ? uvw.x <  uvw.y ? 0 : 1 : uvw.y <  uvw.z ? 1 : 2;
    return K(hi, uvw, ijk) + K(3 - hi - lo, uvw, ijk) + K(lo, uvw, ijk) + K(0, uvw, ijk);
}

Я перевел это из Приложения B из Главы 2 оборудования Ken Perlin Noise Hardware в этом источнике:

https://www.csee.umbc.edu/~olano/s2002c36/ch02.pdf

Вот публичный оттенок, который я сделал для Shader Toy, который использует опубликованную функцию шума:

https://www.shadertoy.com/view/3slXzM

Некоторые другие хорошие источники, которые я нашел по теме шума во время моего исследования, включают:

https://thebookofshaders.com/11/

https://mzucker.github.io/html/perlin-noise-math-faq.html

https://rmarcus.info/blog/2018/03/04/perlin-noise.html

http://flafla2.github.io/2014/08/09/perlinnoise.html

https://mrl.nyu.edu/~perlin/noise/

https://rmarcus.info/blog/assets/perlin/perlin_paper.pdf

https://developer.nvidia.com/gpugems/GPUGems/gpugems_ch05.html

Я настоятельно рекомендую книгу шейдеров, поскольку она не только дает отличное интерактивное объяснение шума, но и другие концепции шейдеров.

EDIT:

Может быть в состоянии оптимизировать переведенный код с помощью некоторых аппаратно-ускоренных функций, доступных в GLSL. Обновлю этот пост, если я в конечном итоге сделаю это.