Несколько операторов IF между диапазонами номеров

Я пытаюсь настроить формулу с несколькими операторами IF между диапазонами номеров, но я вижу ошибку:

Ошибка разбора формулы

Вот форум:

=IF((AND(A2>0,A2<500),"Less than 500",
 If(AND(A2>=500,A2<1000),"Between 500 and 1000"),
 If(AND(A2>=1000,A2<1500),"Between 1000 and 1500"),
 If(AND(A2>=1500,A2<2000),"Between 1500 and 2000")))

Ответы

Ответ 1

Это немного сложно из-за вложенных IF, но вот мой ответ (подтверждено в Google Spreadsheets):

=IF(AND(A2>=0,    A2<500),  "Less than 500", 
 IF(AND(A2>=500,  A2<1000), "Between 500 and 1000", 
 IF(AND(A2>=1000, A2<1500), "Between 1000 and 1500", 
 IF(AND(A2>=1500, A2<2000), "Between 1500 and 2000", "Undefined"))))

Ответ 2

Я предлагаю использовать функцию vlookup, чтобы получить ближайшее совпадение.

Шаг 1

Подготовьте диапазон данных и назовите его: "numberRange":

enter image description here

Выберите диапазон. Перейти в меню: Данные → Именованные диапазоны... → определить новый именованный диапазон.

Шаг 2

Используйте эту простую формулу:

=VLOOKUP(A2,numberRange,2)

enter image description here

Таким образом, вы можете пропустить ошибки и легко исправить результат.

Ответ 3

автономное решение на одну клетку на основе VLOOKUP

Синтаксис США:

=IFERROR(ARRAYFORMULA(IF(LEN(A2:A),
        IF(A2:A>2000, "More than 2000",VLOOKUP(A2:A,
 {{(TRANSPOSE({{{0;   "Less than 500"},
               {500;  "Between 500 and 1000"}},
              {{1000; "Between 1000 and 1500"},
               {1500; "Between 1500 and 2000"}}}))}}, 2)),)), )

Синтаксис ЕС:

=IFERROR(ARRAYFORMULA(IF(LEN(A2:A);
        IF(A2:A>2000; "More than 2000";VLOOKUP(A2:A;
 {{(TRANSPOSE({{{0;   "Less than 500"}\
               {500;  "Between 500 and 1000"}}\
              {{1000; "Between 1000 and 1500"}\
               {1500; "Between 1500 and 2000"}}}))}}; 2));)); )

альтернативы: https://webapps.stackexchange.com/questions/123729/

Ответ 4

Короче, чем принято A, легко расширяется и адреса 0 и ниже:

=if(or(A2<=0,A2>2000),"?",if(A2<500,"Less than 500","Between "&500*int(A2/500)&" and "&500*(int(A2/500)+1)))