Как изменить имя файла сопоставления proguard в gradle для Android-проекта

У меня есть проект андроида на основе gradle, и я хочу изменить имя файла map.txt после его создания для моей сборки. Как это можно сделать?

обн

Как это можно сделать в build.gradle? Поскольку у меня есть доступ к моим вкусам и другим жестким требованиям, я хотел бы создать имя файла сопоставления на основе версии варианта flavor/build.

Ответы

Ответ 1

Много thanx to Сергий Печеницкий, который помог мне найти это хорошее решение.

Чтобы реализовать копирование файлов сопоставления proguard для каждого аромата, мы можем создать "корневую" задачу copyProguardMappingTask и количество динамических задач для каждого аромата

def copyProguardMappingTask = project.tasks.create("copyProguardMapping")
applicationVariants.all { variant ->
    variant.outputs.each { output ->
        ...
        if (variant.getBuildType().isMinifyEnabled()) {
            def copyProguardMappingVariantTask = project.tasks.create("copyProguardMapping${variant.name.capitalize()}", Copy)

            def fromPath = variant.mappingFile;
            def intoPath = output.outputFile.parent;

            copyProguardMappingVariantTask.from(fromPath)
            copyProguardMappingVariantTask.into(intoPath)
            copyProguardMappingVariantTask.rename('mapping.txt', "mapping-${variant.name}.txt")

            copyProguardMappingVariantTask.mustRunAfter variant.assemble
            copyProguardMappingTask.dependsOn copyProguardMappingVariantTask
        }
    }
}

после этого мы должны запустить эту задачу после сборки нашего проекта. Я использую jenkins, и мой вариант задач выглядит как

gradle clean assembleProjectName copyProguardMapping

Он работает как шарм.

Ответ 2

Упрощенное решение.

applicationVariants.all { variant ->
        if (variant.getBuildType().isMinifyEnabled()) {
            variant.assemble.doLast {
                copy {
                    from variant.mappingFile
                    into "${rootDir}/proguardTools"
                    rename { String fileName ->
                        "mapping-${variant.name}.txt"
                    }
                }
            }
        }
    }

Ответ 3

Используйте эту команду в файле proguard-rules.pro:

-printmapping path/to/your/file/file_name.txt

файл будет записан в части {root}/path/to/your/file с именем file_name.txt.

Если вы хотите иметь разные настройки для разных вкусов, вы можете определить для них множество правил proguard

Я нашел еще одну идею, но я не уверен, что это правильный путь.

Вы можете определить свой путь в ароматах:

productFlavors {
    test1 {
        applicationId "com.android.application.test"
        project.ext."${name}Path" = 'path/one/mapp.txt'
    }
    test2 {
        project.ext."${name}Path" = 'path/two/mapp.txt'
    }
}

И как только вы можете определить новую задачу перед задачей $asseble{variant.name.capitalize()}, как показано ниже:

android.applicationVariants.all { variant ->
    def envFlavor = variant.productFlavors.get(0).name

    def modifyProguardPath = tasks.create(name: "modifyProguardFor${variant.name.capitalize()}", type: Exec) {
        def pathToMap = project."${envFlavor}Test1"
        doFirst {
            println "==== Edit start: $pathToMap ===="
        }
        doLast {
            println "==== Edit end: $pathToMap ===="
        }
        executable "${rootDir}/utils/test.bash"
        args pathToMap
    }

    project.tasks["assemble${variant.name.capitalize()}"].dependsOn(modifyProguardPath);
}

и в script ${root}/utils/test.bash - вы можете изменить proguard-rules.pro.

Но я думаю, что существует лучшее решение.

Ответ 4

Поскольку последний вариант update.mappingFile больше не доступен. (Я использую ProGuard версии 4.7, AndroidStudio 2.0)

Это (часть) моего файла build.gradle:

import java.util.regex.Matcher
import java.util.regex.Pattern

def getCurrentFlavor() {
    Gradle gradle = getGradle()
    String  tskReqStr = gradle.getStartParameter().getTaskRequests().toString()

    Pattern pattern;

    if( tskReqStr.contains( "assemble" ) )
        pattern = Pattern.compile("assemble(\\w+)(Release|Debug)")
    else
        pattern = Pattern.compile("generate(\\w+)(Release|Debug)")

    Matcher matcher = pattern.matcher( tskReqStr )

    if( matcher.find() )
        return matcher.group(1).toLowerCase()
    else
    {
        println "NO MATCH FOUND"
        return "";
    }
}

buildTypes {
    release {
        proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt'
        minifyEnabled true

        applicationVariants.all { variant ->
            variant.outputs.each { output ->
                output.outputFile = new File(output.outputFile.parent, "${variant.name}_v${variant.versionName}.apk")
            }
            def mappingFile = "${rootDir}\\app\\build\\outputs\\mapping\\${getCurrentFlavor()}\\release\\mapping.txt"
            println("mappingFile:  ${mappingFile}")
            if (variant.getBuildType().isMinifyEnabled()) {
                variant.assemble.doLast {
                    copy {
                        from "${mappingFile}"
                        into "${rootDir}"
                        rename { String fileName ->
                            "mapping-${variant.name}.txt"
                        }
                    }
                }
            }
        }

    }

    debug {
        minifyEnabled false
        useProguard false

        applicationVariants.all { variant ->
            variant.outputs.each { output ->
                output.outputFile = new File(output.outputFile.parent, "${variant.name}_v${variant.versionName}.apk")
            }
        }
    }

}

Ответ 5

Это вариант ответа igorpst, но переименовывает map.txt в соответствии с именем apk, включая имя версии приложения. Я объединил это с кодом, чтобы назвать APK с номером версии, как описано в этом ответе. Мне пришлось проскользнуть через исходный код gradle, чтобы найти $variant.baseName

apply plugin: 'com.android.application'

android {
    compileSdkVersion 21
    buildToolsVersion "21.1.2"
    defaultConfig {
        applicationId "com.company.app"
        minSdkVersion 13
        targetSdkVersion 21
        versionCode 14       // increment with every release
        versionName '1.4.8'   // change with every release
        archivesBaseName = "MyCompany-MyAppName-$versionName"
    }
    applicationVariants.all { variant ->
        if (variant.getBuildType().isMinifyEnabled()) {
            variant.assemble.doLast {
                (new File(variant.mappingFile.parent, "$archivesBaseName-$variant.baseName-mapping.txt")).delete();
                variant.mappingFile.renameTo(variant.mappingFile.parent +
                        "/$archivesBaseName-$variant.baseName-mapping.txt")
            }
        }
    }
}

Ответ 6

Все эти ответы использовались для переименования файла. Однако я не хотел перемещать файл, я просто хотел изменить его имя, имея в виду тип сборки и вкус.

Я основывался на коде с других плакатов и немного изменил его. Поскольку Minify может быть ложным, но при использовании proguard я просто проверяю, присутствует ли файл.

Следующий код выполняет именно это.

android {
    applicationVariants.all { variant ->
        variant.assemble.doLast {
            def mappingFolderUrl = "${project.buildDir.path}/outputs/mapping/"

            if (variant.buildType.name) {
                mappingFolderUrl += variant.buildType.name + "/"
            }

            if (variant.flavorName) {
                mappingFolderUrl += variant.flavorName + "/"
            }

            def mappingFileUrl = mappingFolderUrl + "mapping.txt"
            logger.lifecycle("mappingFile path: ${mappingFileUrl}")

            File mappingFile = file(mappingFileUrl)
            if (mappingFile.exists()) {
                def newFileName = mappingFolderUrl + "mapping-${variant.name}.txt"
                mappingFile.renameTo(newFileName)
            }
        }
    }
}

Примечание

Возможно, вы также можете использовать этот код для перемещения файла.

метод .renameTo() ожидает полный путь. Если вы измените путь, я бы предположил, что вы эффективно перемещаете файл в другое место.

Ответ 7

Более ранний ответ работал отлично для меня, пока Android 3.0/Android Gradle плагин 3.0 не устарел BuildType.isMinifyEnabled().

Я разработал следующее решение, которое не использует устаревший метод:

applicationVariants.all { variant ->
    variant.assemble.doLast {
        if (variant.mappingFile != null && variant.mappingFile.exists()) {
            def mappingFilename = "$archivesBaseName-$variant.baseName-mapping.txt"
            (new File(variant.mappingFile.parent, mappingFilename)).delete()
            variant.mappingFile.renameTo(variant.mappingFile.parent +
                    "/" + mappingFilename)
        }
    }
}

Ответ 8

variant.assemble теперь устарел, предлагаемое решение, включающее предыдущие модификации:

archivesBaseName = "MyCompany-MyAppName-$versionName"
...
applicationVariants.all { variant ->
    variant.assembleProvider.get().doLast {
        if (variant.mappingFile != null && variant.mappingFile.exists()) {
            def mappingFilename = "$archivesBaseName-$variant.baseName-mapping.txt"
        (new File(variant.mappingFile.parent, mappingFilename)).delete()
        variant.mappingFile.renameTo(variant.mappingFile.parent +
                "/" + mappingFilename)
        }
    }
}

Если вы используете пакет приложений (aab) вместо apk, добавьте это после раздела Android:

afterEvaluate {
    bundleRelease.doLast {
        android.applicationVariants.all { variant ->
            if (variant.buildType.name == 'release') {
                tasks.create(name: "renameMappingFile") {
                    if (variant.mappingFile != null && variant.mappingFile.exists()) {
                        variant.mappingFile.renameTo(variant.mappingFile.parent + "/$variant.baseName-$versionName-${new Date().format('yyyy-MM-dd_HHmm')}-mapping.txt")
                    }
                }
            }
        }
    }
}

Поменяйте bundleRelease для assembleRelease для APK, в последнем примере тоже.

Обновление: Однако последнее не сработает, если вы попытаетесь построить нормальную отладку прямо на вашем телефоне. Ошибка:

Не удалось получить неизвестное свойство "bundleRelease" для проекта ": приложение" типа org.gradle.api.Project.

Ответ 9

Решение Pinhassi выше отлично работает и соответствует последним изменениям Gradle. Есть пара вещей, хотя мне пришлось изменить:

Имя модуля жестко запрограммировано ( "приложение" ), что не является идеальным, поскольку во многих случаях (включая мой) это не будет правдой. Лучше всего динамически определить имя модуля.
Файл сопоставления также соответствует только файловой системе Windows с помощью обратного сбрасывания косой черты ( "\" ). Если вы находитесь в системе * NIX, такой как Linux или Mac, вам нужно заменить те, у которых есть несжатые косые черты ( "/" )
Немного изменилось переименование файла .apk, чтобы включить имя проекта и добавить дату/время в конце.

Вот готовый код:

import java.util.regex.Matcher
import java.util.regex.Pattern

buildTypes {
        release {
        debuggable false
        minifyEnabled true
        proguardFiles 'proguard.cfg'

        // Rename the apk file and copy the ProGuard mapping file to the root of the project
        applicationVariants.all { variant ->
            if (variant.getBuildType().name.equals("release")) {
                def formattedDate = new Date().format('yyyyMMddHHmmss')
                def projectName = ""
                variant.outputs.each { output ->
                    def fullName = output.outputFile.name
                    projectName = fullName.substring(0, fullName.indexOf('-'))
                    // ${variant.name} has the value of "paidRelease"
                    output.outputFile = new File((String) output.outputFile.parent, (String) output.outputFile.name.replace(".apk", "-v${variant.versionName}-${formattedDate}.apk"))
                }
                def mappingFile = "${rootDir}/${projectName}/build/outputs/mapping/${getCurrentFlavor()}/release/mapping.txt"
                println("mappingFile:  ${mappingFile}")
                if (variant.getBuildType().isMinifyEnabled()) {
                    variant.assemble.doLast {
                        copy {
                            from "${mappingFile}"
                            into "${rootDir}"
                            rename { String fileName ->
                                "mapping-${variant.name}.txt"
                            }
                        }
                    }
                }
            }
        }
    }

        debug {
            debuggable true
        }
    }

def getCurrentFlavor() {
    Gradle gradle = getGradle()
    String  tskReqStr = gradle.getStartParameter().getTaskRequests().toString()
    Pattern pattern;

    if( tskReqStr.contains( "assemble" ) )
        pattern = Pattern.compile("assemble(\\w+)(Release|Debug)")
    else
        pattern = Pattern.compile("generate(\\w+)(Release|Debug)")

    Matcher matcher = pattern.matcher( tskReqStr )

    if( matcher.find() )
        return matcher.group(1).toLowerCase()
    else {
        println "NO MATCH FOUND"
        return "";
    }
}

Ответ 10

applicationVariants.all { variant ->
    variant.outputs.each { output ->
        if (variant.getBuildType().isMinifyEnabled()) {
            variant.assemble.doLast{
                copy {
                    from variant.mappingFile
                    into "${rootDir}/mapping"
                    rename { String fileName ->
                        "mapping-${variant.name}-${new Date().format('yyyy_MM_dd')}.txt"
                    }
                }
            }
        }
    }
}