Невозможно понять результат для многострочного регулярного выражения qr/(. $. +)/Xms

Для строки "aa\nbb\ncc" я хочу совместить последнюю букву слева с первой новой строкой ( "a" ) до конца многострочной строки и ожидал, что

"aa\nbb\ncc" =~ qr/( . $ .+ )/xms соответствует a\nbb\ncc

и что

"aa\nbb\ncc\n" =~ qr/( . $ .+ )/xms соответствует a\nbb\ncc\n.

Но у меня нет соответствия для "aa\nbb\ncc" =~ qr/( . $ .+ )/xms и сопоставьте c\n для "aa\nbb\ncc" =~ qr/( . $ .+ )/xms.

Используя qr/( . $ ..+ )/xms, я получил ожидаемые результаты (см. примерный код).

Версия Perl 5.14.2.

Кто-нибудь может дать объяснение этому поведению?

perldoc perlre:

   m   Treat string as multiple lines.  That is, change "^" and "$" 
       from matching the start or end of the string to matching the start 
       or end of any line anywhere within the string.

   s   Treat string as single line. That is, change "." to match any character 
       whatsoever, even a newline, which normally it would not match.

       Used together, as "/ms", they let the "." match any character whatsoever, 
       while still allowing "^" and "$" to match, respectively, just after and 
       just before ewlines within the string.

   \z  Match only at end of string

Запуск следующего примера кода:

#!/usr/bin/env perl

use strict;
use warnings;

print "Multiline string : ", '"aa\nbb\ncc"', "\n\n";
my $str = "aa\nbb\ncc";

print_match($str, qr/( . $ )/xms);       # matches "a"
print_match($str, qr/( . $ . )/xms);     # matches "a\n"
print_match($str, qr/( . $ .. )/xms);    # matches "a\nb"
print_match($str, qr/( . $ ..+ )/xms);   # matches "a\nbb\ncc"
print_match($str, qr/( . $ .+ )/xms);    # NO MATCH ! Why ???
print_match($str, qr/( . $ .+ \z )/xms); # NO MATCH ! Why ???

print "\nMultiline string now with terminating newline : ", '"aa\nbb\ncc\n"', "\n\n";
$str = "aa\nbb\ncc\n";

print_match($str, qr/( . $ )/xms);       # matches "a"
print_match($str, qr/( . $ . )/xms);     # matches "a\n"
print_match($str, qr/( . $ .. )/xms);    # matches "a\nb"
print_match($str, qr/( . $ ..+ )/xms);   # matches "a\nbb\ncc\n"
print_match($str, qr/( . $ .+ )/xms);    # MATCHES "c\n" ! Why ???
print_match($str, qr/( . $ .+ \z)/xms);  # MATCHES "c\n" ! Why ???

sub print_match {
    my ($str, $regex) = @_;
    $str =~ $regex;
    if ( $1 ) {
        printf "--> %-20s matched : >%s< \n", $regex, $1;
    }
    else {
        printf "--> %-20s : no match !\n", $regex;
    }
}

вывод:

Multiline string : "aa\nbb\ncc"

--> (?^msx:( . $ ))      matched : >a<
--> (?^msx:( . $ . ))    matched : >a
<
--> (?^msx:( . $ .. ))   matched : >a
b<
--> (?^msx:( . $ ..+ ))  matched : >a
bb
cc<
--> (?^msx:( . $ .+ ))   : no match !

Multiline string now with terminating newline : "aa\nbb\ncc\n"

--> (?^msx:( . $ ))      matched : >a<
--> (?^msx:( . $ . ))    matched : >a
<
--> (?^msx:( . $ .. ))   matched : >a
b<
--> (?^msx:( . $ ..+ ))  matched : >a
bb
cc
<
--> (?^msx:( . $ .+ ))   matched : >c
<

Ответы

Ответ 1

Это ошибка. Сообщайте об этом, запустив также командную строку perlbug.

$ perl -E'say "aa\nbb\ncc" =~ qr/( . $ .+ )/xms ? ">$1<" : 0'
0

$ perl -E'say "aa\nbb\ncc\n" =~ qr/( . $ .+ )/xms ? ">$1<" : 0'
>c
<

$ perl -v
...
This is perl 5, version 16, subversion 0 (v5.16.0) built for x86_64-linux
...

Как вы сказали, они должны соответствовать "a\nbb\ncc" и "a\nbb\ncc\n" соответственно. Есть оптимизация, связанная с $. Один из них, похоже, не принял во внимание /ms.

PS — Вас может заинтересовать use re 'debug';.

$ perl -Mre=debug -E'say "aa\nbb\ncc" =~ qr/( . $ .+ )/xms ? ">$1<" : 0'
Compiling REx "( . $ .+ )"
Final program:
   1: OPEN1 (3)
   3:   SANY (4)
   4:   MEOL (5)
   5:   PLUS (7)
   6:     SANY (0)
   7: CLOSE1 (9)
   9: END (0)
anchored ""$ at 2 minlen 2 
Matching REx "( . $ .+ )" against "aa%nbb%ncc"
   0 <> <aa%nbb%ncc>         |  1:OPEN1(3)
   0 <> <aa%nbb%ncc>         |  3:SANY(4)
   1 <a> <a%nbb%ncc>         |  4:MEOL(5)
                                  failed...
   3 <aa%n> <bb%ncc>         |  1:OPEN1(3)
   3 <aa%n> <bb%ncc>         |  3:SANY(4)
   4 <aa%nb> <b%ncc>         |  4:MEOL(5)
                                  failed...
   6 <aa%nbb%n> <cc>         |  1:OPEN1(3)
   6 <aa%nbb%n> <cc>         |  3:SANY(4)
   7 <aa%nbb%nc> <c>         |  4:MEOL(5)
                                  failed...
Match failed
0
Freeing REx: "( . $ .+ )"