Временная метка имени файла в пакете ОС Windows CMD script

У меня есть пакет script, который выводит файл, и я пытаюсь гарантировать, что каждый раз, когда выполняется script, никакие существующие файлы не перезаписываются, поэтому я пытаюсь установить на него временную метку.

В настоящее время у меня есть это:

set  stamp=%DATE:/=-%_%TIME::=-%

Но если время 1-9 & AM, оно дает что-то вроде:

13-06-2012_ instead of a full 13-06-2012_12-39-37.28

Как я могу это исправить?

Я использую Windows 7, а вывод echo %date% %time% в окне командной строки (мой формат часов для "короткой даты" установлен для отображения трехмесячных месяцев):

03-Sep-12 9:06:21.54

Изменить: Я использую следующую временную метку для хорошего времени, хорошо работает.

set timestamp=%DATE:/=-%_%TIME::=-%
set timestamp=%timestamp: =%

Он создал временную метку типа: 18-03-2013_13-37-43.26, заменив / и : на %TIME% и %DATE%, затем удалив пустое пространство. На самом деле проблема была в моем первоначальном вопросе.

Ответы

Ответ 1

Первые четыре строки этого кода предоставят вам надежные переменные YY DD MM YYYY HH Min Sec в XP Pro и выше, используя WMIC.

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%"
set "fullstamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
echo fullstamp: "%fullstamp%"
pause

Ответ 2

См. Stack Вопрос о переполнении Как получить текущее время и время в командной строке Windows в подходящем формате для использования в имени файла?.

Создайте файл date.bat:

@echo off
For /f "tokens=2-4 delims=/ " %%a in ('date /t') do (set mydate=%%c-%%a-%%b)
For /f "tokens=1-3 delims=/:/ " %%a in ('time /t') do (set mytime=%%a-%%b-%%c)
set mytime=%mytime: =% 
echo %mydate%_%mytime%

Выполнить date.bat:

C:\>date.bat
2012-06-14_12-47-PM

UPDATE:

Вы также можете сделать это с помощью одной строки:

for /f "tokens=2-8 delims=.:/ " %%a in ("%date% %time%") do set DateNtime=%%c-%%a-%%b_%%d-%%e-%%f.%%g

Ответ 3

Вот пакет script, который я сделал, чтобы вернуть отметку времени. Необязательный первый аргумент может быть предоставлен для использования в качестве разделителя полей. Например:

C:\SYS\TMP > timestamp.bat
20160404_144741
c:\sys\tmp > timestamp.bat -
2016-04-04_14-45-25
c:\sys\tmp > timestamp.bat:
2016: 04: 04_14: 45: 29

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
:: put your desired field delimiter here.
:: for example, setting DELIMITER to a hyphen will separate fields like so:
:: yyyy-MM-dd_hh-mm-ss
::
:: setting DELIMITER to nothing will output like so:
:: yyyyMMdd_hhmmss
::
SET DELIMITER=%1

SET DATESTRING=%date:~-4,4%%DELIMITER%%date:~-7,2%%DELIMITER%%date:~-10,2%
SET TIMESTRING=%TIME%
::TRIM OFF the LAST 3 characters of TIMESTRING, which is the decimal point and hundredths of a second
set TIMESTRING=%TIMESTRING:~0,-3%

:: Replace colons from TIMESTRING with DELIMITER
SET TIMESTRING=%TIMESTRING::=!DELIMITER!%

:: if there is a preceeding space substitute with a zero
echo %DATESTRING%_%TIMESTRING: =0%

Ответ 4

Он хочет, чтобы все время в DD-MM-YYYY_HH-MM-SS.TT, где TT - это тики. Исключение составляет все.

Ответ 5

Отвечать на вопрос "Очередность переполнения" Создание имени файла в качестве метки времени в пакетном задании, я обнаружил, что это пространство, заканчивающееся именем файла.

Ответ 6

for /f "tokens=2-8 delims=.:/ " %%a in ("%date% %time: =0%") do set DateNtime=%%c-%%a-%%b_%%d-%%e-%%f.%%g
echo %DateNtime%

Или из командной строки:

for /f "tokens=2-8 delims=.:/ " %a in ("%date% %time: =0%") do echo %c-%a-%b_%d-%e-%f.%g

РЕДАКТИРОВАТЬ: В соответствии со спецификациями времени/даты bryce нестандартного. (03-Sep-12 9:06:21.54)

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1-7 delims=.:/- " %%a in ("%date% %time%") do (
  if "%%b"=="Jan" set MM=01
  if "%%b"=="Feb" set MM=02
  if "%%b"=="Mar" set MM=03
  if "%%b"=="Apr" set MM=04
  if "%%b"=="May" set MM=05
  if "%%b"=="Jun" set MM=06
  if "%%b"=="Jul" set MM=07
  if "%%b"=="Aug" set MM=08
  if "%%b"=="Sep" set MM=09
  if "%%b"=="Oct" set MM=10
  if "%%b"=="Nov" set MM=11
  if "%%b"=="Dec" set MM=12
  set HH=0%%d
  set HH=!HH:~-2!
  echo 20%%c-!MM!-%%a_!HH!-%%e-%%f.%%g
)
endlocal

Ответ 7

В прошлом я использовал .cmd script, который я нашел в Интернете. Я ненавижу то, как локализация обычно путается с датами. Каждый раз, когда у вас есть даты в именах файлов (или где-либо еще, если я могу быть таким смелым), я полагаю, что вы хотите, чтобы они были в формате ISO 8601:

2015-02-19T14: 54: 51Z

или что-то еще, у которого есть Y M D H M в этом порядке, например

2015-02-19 14:54

потому что он исправляет неоднозначность MDY/DMY и потому что он сортируется как текст.

Я не знаю, где я получил этот .cmd script, но он, возможно, был http://ss64.com/nt/syntax-getdate.html, который прекрасно работает на мой YYYY-MM-DD Windows 8.1 и установку M/D/YYYY ванили Windows 7. Оба дают тот же формат:

2015-02-09 04:43

Ответ 8

Имя файла журнала журнала Windows в формате 2018-02-08_14.32.06.34.log:

setlocal
set d=%DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%
set t=%time::=.% 
set t=%t: =%
set logfile="%d%_%t%.log"

ping localhost -n 11>%1/%logfile%
endlocal