В CoffeeScript существует ли "официальный" способ интерполяции строки во время выполнения, а не при компиляции?

У меня есть объект options в моем классе CS, и я хотел бы оставить в нем несколько шаблонов:

class MyClass
    options:
        templates:
            list: "<ul class='#{ foo }'></ul>"
            listItem: "<li>#{ foo + bar }</li>"
            # etc...

Затем я хотел бы интерполировать эти строки позже в коде... Но, конечно, они скомпилированы в "<ul class='" + foo +"'></ul>", а foo - undefined.

Есть ли официальный способ CoffeeScript для этого во время выполнения с помощью .replace()?

Изменить: я закончил писать небольшую утилиту, чтобы помочь:

# interpolate a string to replace {{ placeholder }} keys with passed object values
String::interp = (values)->
    @replace /{{ (\w*) }}/g,
        (ph, key)->
            values[key] or ''

Итак, теперь мои параметры выглядят следующим образом:

templates:
    list: '<ul class="{{ foo }}"></ul>'
    listItem: '<li>{{ baz }}</li>'

И далее в коде:

template = @options.templates.listItem.interp
    baz: foo + bar
myList.append $(template)

Ответы

Ответ 1

Я бы сказал, что если вам нужна отсроченная оценка, то они, вероятно, должны быть определены как функции.

Возможно, взяв значения отдельно:

templates:
    list: (foo) -> "<ul class='#{ foo }'></ul>"
    listItem: (foo, bar) -> "<li>#{ foo + bar }</li>"

Или из объекта контекста:

templates:
    list: (context) -> "<ul class='#{ context.foo }'></ul>"
    listItem: (context) -> "<li>#{ context.foo + context.bar }</li>"

Учитывая ваши прежние комментарии, вы можете использовать второй пример выше:

$(options.templates.listItem foo: "foo", bar: "bar").appendTo 'body'