Разделить разделенные запятой записи на новые строки

Ответ 1

Вам лучше использовать альтернативные массивы, а не клеточные циклы - они намного быстрее кода, когда набор данных имеет смысл. Даже если код длиннее:)

Этот пример ниже дамп в столбцы C и D, чтобы вы могли видеть исходные данные. Измените [c1].Resize(lngCnt, 2).Value2 = Application.Transpose(Y) на [a1].Resize(lngCnt, 2).Value2 = Application.Transpose(Y), чтобы сбрасывать исходные данные

[Обновлено с помощью регулярного выражения для удаления пробелов после ,, т.е. ", band" становится "band" ]

Sub SliceNDice() 
Dim objRegex As Object 
Dim X 
Dim Y 
Dim lngRow As Long 
Dim lngCnt As Long 
Dim tempArr() As String 
Dim strArr 
Set objRegex = CreateObject("vbscript.regexp") 
objRegex.Pattern = "^\s+(.+?)$" 
 'Define the range to be analysed
X = Range([a1], Cells(Rows.Count, "b").End(xlUp)).Value2 
Redim Y(1 To 2, 1 To 1000) 
For lngRow = 1 To UBound(X, 1) 
     'Split each string by ","
    tempArr = Split(X(lngRow, 2), ",") 
    For Each strArr In tempArr 
        lngCnt = lngCnt + 1 
         'Add another 1000 records to resorted array every 1000 records
        If lngCnt Mod 1000 = 0 Then Redim Preserve Y(1 To 2, 1 To lngCnt + 1000) 
        Y(1, lngCnt) = X(lngRow, 1) 
        Y(2, lngCnt) = objRegex.Replace(strArr, "$1") 
    Next 
Next lngRow 
 'Dump the re-ordered range to columns C:D
[c1].Resize(lngCnt, 2).Value2 = Application.Transpose(Y) 
End Sub 

Ответ 2

Принимает ваши данные в столбце A и помещает результаты в столбец C.

Sub SplitAll()
    Dim src As Range
    Dim result As Variant
    For Each src In Range("A:A").SpecialCells(xlCellTypeConstants)
        result = Split(src, ",")
        'last cell in column C
        With Cells(Rows.Count, 3).End(xlUp)
            Range(.Offset(1, 0), .Offset(1 + UBound(result, 1), 0)) = Application.WorksheetFunction.Transpose(result)
        End With
    Next src
End Sub