Пакет для удаления символа из строки

это может показаться простым, но есть ли способ создать пакет для удаления char из строки из txt файла.

так есть способ создания командного файла, который в конце будет удалять .png, чтобы показать это только в новом .txt файле

Ответы

Ответ 1

Вы можете сделать это в соответствии со следующей командой script:

@setlocal enableextensions enabledelayedexpansion
@echo off
set variable=2005060.png
echo !variable!
if "x!variable:~-4!"=="x.png" (
    set variable=!variable:~0,-4!
)
echo !variable!
endlocal

Выводится:

2005060.png
2005060

Магическая линия, конечно же, такова:

set variable=!variable:~0,-4!

который удаляет последние четыре символа.

Если у вас есть файл testprog.in с строками, это:

2005060.png
1 2 3 4 5      leave this line alone.
2005070.png
2005080.png
2005090.png

вы можете использовать небольшую модификацию:

@setlocal enableextensions enabledelayedexpansion
@echo off
for /f "delims=" %%a in (testprog.in) do (
    set variable=%%a
    if "x!variable:~-4!"=="x.png" (
        set variable=!variable:~0,-4!
    )
    echo.!variable!
)
endlocal

который выводит:

2005060
1 2 3 4 5      leave this line alone.
2005070
2005080
2005090

Просто имейте в виду, что он не будет выводить пустые строки (хотя он будет делать строки с пробелами на них).

Это может быть не проблема, зависящая от того, что разрешено в вашем исходном файле. Если это проблема, я советую вам воспользоваться CygWin или GnuWin32 (или Powershell, если у вас есть это на вашей платформе) и использовать некоторые реальные языки сценариев.

Ответ 2

Это сработало лучше для меня:

@echo off
for %%x in (*.png) do  echo %%~nx

кредит

Ответ 3

Если вы пытаетесь прочитать каталог .png файлов и вывести список без расширений? Попробуйте следующее:

    @echo off

    echo. > testprog.txt

    for /R "C:\Users\%USERNAME%\Documents" %%f in (*.png) do (
        echo %%~nf >> testprog.txt
        )

    start testprog.txt