Каков наилучший способ создания атрибута класса в Moose?

Мне нужен атрибут класса в Moose. Сейчас я говорю:

#!/usr/bin/perl

use 5.010;
use strict;
use warnings;
use MooseX::Declare;

class User {
    has id      => (isa => "Str", is => 'ro', builder => '_get_id');
    has name    => (isa => "Str", is => 'ro');
    has balance => (isa => "Num", is => 'rw', default => 0);

    #FIXME: this should use a database  
    method _get_id {
        state $id = 0; #I would like this to be a class attribute
        return $id++;
    }
}

my @users;
for my $name (qw/alice bob charlie/) {
    push @users, User->new(name => $name);
};

for my $user (@users) {
    print $user->name, " has an id of ", $user->id, "\n";
}

Ответы

Ответ 1

Я нашел MooseX:: ClassAttribute, но выглядит уродливо. Это самый чистый способ?

#!/usr/bin/perl

use 5.010;
use strict;
use warnings;
use MooseX::Declare;

class User {
    use MooseX::ClassAttribute;

    class_has id_pool => (isa => "Int", is => 'rw', default => 0);

    has id      => (isa => "Str", is => 'ro', builder => '_get_id');
    has name    => (isa => "Str", is => 'ro');
    has balance => (isa => "Num", is => 'rw', default => 0);

    #FIXME: this should use a database  
    method _get_id {
        return __PACKAGE__->id_pool(__PACKAGE__->id_pool+1);
    }
}

my @users;
for my $name (qw/alice bob charlie/) {
    push @users, User->new(name => $name);
};

for my $user (@users) {
    print $user->name, " has an id of ", $user->id, "\n";
}

Ответ 2

Честно говоря, я не считаю нужным всю эту проблему для атрибутов класса. Для атрибутов класса только для чтения я просто использую sub, который возвращает константу. Для атрибутов чтения и записи простая переменная состояния в пакете обычно выполняет трюк (я еще не сталкивался с какими-либо сценариями, где мне было нужно что-то более сложное.)

state $count = 0;
method _get_id { 
    return ++$count;
}

Частный блок с лексическим может использоваться, если вам нужна совместимость до 5.10.