Как выполнять строковые операции с переменными в цикле for?

Это звучит глупо, но я не могу заставить его работать. Я думаю, что просто не понимаю разницу между %%v, %v% and %v

Вот что я пытаюсь сделать:

for %%v in (*.flv) do ffmpeg.exe -i "%%v" -y -f mjpeg -ss 0.001 -vframes 1 -an "%%v.jpg"

Это успешно создает миниатюру для каждого из фильмов, но проблема заключается в следующем:

movie.flv -> movie.flv.jpg

Итак, что бы я хотел сделать, это вывести последние 4 символа с %%v и использовать это для второй переменной.

Я пробовал такие вещи:

%%v:~0,-3%

Но он не работает и не является итерациями того, что я мог придумать.

Любые идеи?

Ответы

Ответ 1

Используйте %% ~ nV, чтобы получить только имя файла.

Ответ 2

Для тех, кто нашел этот поток, который ищет, как выполнять строковые операции для переменных for-loop (использует отложенное расширение):

setlocal enabledelayedexpansion

...

::Replace "12345" with "abcde"
for %%i in (*.txt) do (
    set temp=%%i
    echo !temp:12345=abcde!
)

Ответ 3

for %%v in (*.flv) do ffmpeg.exe -i "%%v" -y -f mjpeg -ss 0.001 -vframes 1 -an "%%~nv.jpg"

От "help for":

%~I         - expands %I removing any surrounding quotes (")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file
%~$PATH:I   - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string

Ответ 4

Я не так хорош в пакете, как указано выше (вместо этого я использую WSH или другие языки script), но я могу попытаться объяснить %% v% v и% v%.

Первые две формы используются в цикле for. help for объясняет разницу, первая форма используется в пакетном файле, а вторая используется при вводе (вставке) команды непосредственно в командной строке.

Последняя форма просто заменяет имя переменной (переменную среды) ее значением:

set FOO=C:\bar\foo
cd %FOO%\gah

Ответ 5

Еще один способ, который я предпочитаю, - создать подпрограмму (: processMpeg), которую я вызываю для каждого элемента цикла For, к которому я передаю переменную %% v.

for %%v in (*.flv) do call :processMpeg "%%v"
goto :eof

:processMpeg
  set fileName=%~n1
  echo P1=%1  fileName=%fileName%  fullpath=%~dpnx1
  ffmpeg.exe -i "%~1" -y -f mjpeg -ss 0.001 -vframes 1 -an "%filename%.jpg"
  goto :eof