Использование MBUnit в TeamCity

Я собираю проект NAnt на Linux с сервером Continuous Integration TeamCity. Я смог создать тестовый отчет, запустив NAnt на монохромном Runner, но не имеет возможности использовать отчет как NAnt Runner. Я также использую MBUnit для платформы тестирования.

Как я могу объединиться в отчете об испытаниях и отобразить "Не удалось выполнить тесты: 1 (1 новый), прошло: 3049" для сборки?

Обновление: взгляните на MBUnitTask на свою задачу NAnt, которая использует отправленные сообщения, которые TeamCity ожидает от NUnit, поэтому позволяет использовать все функции TeamCity для тестов.

MBUnitTask

Обновление: Galio имеет лучшую поддержку, поэтому вам просто нужно ссылаться на DLL Galio MBUnit 3.5 вместо DLL MBUnit 3.5 и переключиться на бегун galio, чтобы он работал.

Ответы

Ответ 2

TeamCity отслеживает вывод командной строки из сборки. Вы можете сообщить ему, как идут ваши тесты, вставляя определенные маркеры в этот вывод. Смотрите http://www.jetbrains.net/confluence/display/TCD3/Build+Script+Interaction+with+TeamCity. Например

##teamcity[testSuiteStarted name='Test1']

сообщит TeamCity, что запущен набор тестов. С MbUnit вы не можете вывести эти маркеры во время выполнения тестов, но вы можете преобразовать полученный XML файл. Вот XSL, который я использую:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/">

        <xsl:apply-templates/>

    </xsl:template>

    <xsl:template match="assemblies/assembly">
##teamcity[testSuiteStarted name='<xsl:value-of select="@name" />']

        <xsl:apply-templates select="//run" />

##teamcity[testSuiteFinished name='<xsl:value-of select="@name" />']
    </xsl:template>

    <xsl:template match="run">

        <xsl:choose>
            <xsl:when test="@result='ignore' or @result='skip'">
        ##teamcity[testIgnored name='<xsl:value-of select="@name" />' message='Test Ignored']
            </xsl:when>
            <xsl:otherwise>
        ##teamcity[testStarted name='<xsl:value-of select="@name" />']
            </xsl:otherwise>
        </xsl:choose>


        <xsl:if test="@result='failure'">
            ##teamcity[testFailed name='<xsl:value-of select="@name" />' message='<xsl:value-of select="child::node()/message"/>' details='<xsl:value-of select="normalize-space(child::node()/stack-trace)"/>']
        </xsl:if>


        <xsl:if test="@result!='ignore' and @result!='skip'">
        ##teamcity[testFinished name='<xsl:value-of select="@name" />']
        </xsl:if>

    </xsl:template>

</xsl:stylesheet>

Ответ 3

Вот что я придумал

Как я могу объединиться в тестовом отчете?

Сначала вам нужно будет создать mbunit для создания отчета XML и HTML. Аргументы командной строки выглядят следующим образом:

/rt:Xml /rt:Html /rnf:mbunit /rf:..\reports

это сгенерирует отчеты в dir, называемые отчетами, и файл будет называться mbunit.xml и mbunit.html

Далее мы хотим добавить эти файлы в качестве артефактов в сборке

build\reports\* => Reports

последним шагом является указание teamcity, чтобы добавить его как вкладку для сборки

найдите .BuildServer\config\main-config.xml и добавьте эту строку (в окнах это находится в c:\Documents and Settings \, в linux это было в каталоге /root )

<report-tab title="Tests" basePath="Reports" startPage="mbunit.html" />

Как я могу отобразить "Не удалось выполнить тесты: 1 (1 новый), прошло: 3049" для сборки?

TeamCity ищет файл с именем teamcity-info.xml, в котором вы можете вставлять сообщения для отображения. Фактическое количество тестов - это просто текст. Я думаю, вы можете просто добавить файл в качестве артефакта, но я также получил его в корневом каталоге сборки.

в NAnt вы захотите использовать эту команду для создания XSLT в XML-отчете MBUnit

<style style="includes\teamcity-info.xsl" in="reports\mbunit.xml" out="..\teamcity-info.xml" />

фактический xsl выглядит следующим образом. (Обратите внимание: что {и} зарезервированы в xsl, поэтому мы должны использовать params)

<?xml version="1.0" encoding="ISO-8859-1"?>

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:param name="cbl" select="'{'"/>
<xsl:param name="cbr" select="'}'"/>
<xsl:template match="/">
<xsl:for-each select="report-result/counter">

<build number="1.0.{concat($cbl,'build.number',$cbr)}">
    <xsl:if test="@failure-count &gt; 0">
        <statusInfo status="FAILURE">    
            <text action="append"> Tests failed: <xsl:value-of select="@failure-count"/>, passed: <xsl:value-of select="@success-count"/></text>
        </statusInfo>
    </xsl:if>
    <xsl:if test="@failure-count = 0">
        <statusInfo status="SUCCESS">
            <text action="append"> Tests passed: <xsl:value-of select="@success-count"/></text>
        </statusInfo>
    </xsl:if>

</build>
</xsl:for-each>

</xsl:template>
</xsl:stylesheet>

Это даст вам файл, похожий на этот

<build number="1.0.{build.number}">
   <statusInfo status="FAILURE">
      <text action="append">Tests failed: 16, passed: 88</text>
   </statusInfo>
</build>