Пролог GNU - Univ-оператор? Объяснение этого

Итак, оператор univ. Я не совсем понимаю это.

Например:

foo(PredList,[H|_]) :- bar(PredList,H).
foo(PredList,[_|T]) :- foo(PredList,T),!.

bar([H|_],Item) :- G =.. [H,Item],G.
bar([_|T],Item) :- bar(T,Item).

Что это делает? Это похоже на то, верно ли другое предикат. Я не понимаю, что делает "..".

Как бы вы переписали это без оператора univ?

Ответы

Ответ 1

Univ (=..) разбивает термин на список составляющих или строит термин из такого списка. Попробуйте:

?- f(x,y) =.. L.
L = [f, x, y].

?- f(x,y,z) =.. [f|Args].
Args = [x, y, z].

?- Term =.. [g,x,y].
Term = g(x, y).

bar, кажется, вызывает каждый предикат в PredList на Item, при этом foo возвращается назад к Item s. (Использование переменной в качестве предиката не переносимо, предикат call должен быть предпочтительным.)

Изменить: Kaarel прав, univ может быть заменен на functor/3 и arg/3 следующим образом:

bar([H|_],Item) :-
    functor(Goal,H,1),   % unifies Goal with H(_)
    arg(1,Goal,Item),    % unifies first argument of Goal with Item
    call(Goal).          % use this for portability

Ответ 2

Самое подходящее переписывание, на мой взгляд, будет:

 bar( [H|_], Item ) :- call(H, Item).

call/n еще не являются частью стандартного стандарта ISO, но они могут стать в ближайшем будущем (*). Многие системы Prolog уже поддерживают их.

Есть одна причина, по которой call/n следует выбирать по простым решениям (=..)/2 и functor/3 + arg/3. Решение call/n способно обрабатывать замыкания (**).

С помощью простого решения (=..)/2 и functor/3 + arg/3 можно вызвать bar/2 только с атомами в первом аргументе списка. Например:

 p1(1).
 p2(2).
 ?- bar( [p1, p2], 1 ).
 Yes
 ?- bar( [p1, p2], 2 ).
 Yes
 ?- bar( [p1, p2], 3 ).
 No

С закрытием мы не ограничены атомами, и мы можем сэкономить некоторое усилие кодирования. Например, мы можем сделать следующее непосредственно:

 ?- bar( [=(1), =(2)], 1 ).
 Yes
 ?- bar( [=(1), =(2)], 2 ).
 Yes
 ?- bar( [=(1), =(2)], 3 ).
 No

С наилучшими пожеланиями

(*)
Проект технического исправления 2
http://www.complang.tuwien.ac.at/ulrich/iso-prolog/dtc2#call

(**)
Кто его изобрел?: call/n Предикаты
http://www.complang.tuwien.ac.at/ulrich/Prolog-inedit/naish.html