Рабочее решение для последних файлов FZF в Vim?

У меня возникла проблема с поиском правильного решения для самых последних файлов в плагине FZF vim.

Этот плагин должен иметь такие функции, как:

  • показать файлы, открытые в текущей сессии vim (например, буферы)
  • фильтровать файлы, такие как NERD_tree, fugitive

Я попробовал два решения

command! FZFMru call fzf#run({
\ 'source':  reverse(s:all_files()),
\ 'sink':    'edit',
\ 'options': '-m --no-sort -x',
\ 'down':    '40%' })

function! s:all_files()
  return extend(
  \ filter(copy(v:oldfiles),
  \        "v:val !~ 'fugitive:\\|\\.svg|NERD_tree\\|^/tmp/\\|.git/'"),
  \ map(filter(range(1, bufnr('$')), 'buflisted(v:val)'), 'bufname(v:val)'))
endfunction

Это работает во время открытого сеанса, но когда я перезапускаю vim, я не вижу всех последних открытых файлов.

command! FZFMru call s:fzf_wrap({
    \'source':  'bash -c "'.
    \               'echo -e \"'.s:old_files().'\";'.
    \               'ag -l -g \"\"'.
    \           '"',
    \})

function! s:fzf_wrap(dict)
    let defaults = {
    \'sink' : 'edit',
    \'options' : '+s -e -m',
    \'tmux_height': '40%',
    \}
    call extend(a:dict, defaults, 'keep')
    call fzf#run(a:dict)
endfunction

function! s:old_files()
    let oldfiles = copy(v:oldfiles)
    call filter(oldfiles, 'v:val !~ "fugitive"')
    call filter(oldfiles, 'v:val !~ "NERD_tree"')
    call filter(oldfiles, 'v:val !~ "^/tmp/"')
    call filter(oldfiles, 'v:val !~ ".git/"')
    call filter(oldfiles, 'v:val !~ ".svg"')
    return join(oldfiles, '\n')
endfunction

Это решение фильтрует правильные файлы, но работает только для файлов, открытых в предыдущем сеансе. Поэтому мне нужно перезапустить vim, чтобы получить текущий буфер.

Вы нашли рабочее решение для FZFMru в VIM?

Ответы

Ответ 1

Я нашел последний плагин Junegunn.

Plug 'junegunn/fzf.vim'

Он охватывает случай.

Просто добавьте

nmap <silent> <leader>m :History<CR>

Спасибо Junegunn:)

Ответ 2

Одним из возможных решений является использование плагина neomru, который сохранит ваши последние visted файлы в кеше, расположенном в ~/.cache/neomru/file.

После установки плагина neomru с вашим предпочтительным менеджером плагинов вы можете определить сопоставление для поиска файла кеша, например:

nnoremap <silent> <Leader>m :call fzf#run({
\   'source': 'sed "1d" $HOME/.cache/neomru/file',
\   'sink': 'e '
\ })<CR>

Ответ 3

Отъезд https://github.com/junegunn/fzf/wiki/Examples-(vim). Там много классных вещей, включая MRU, поиск тегов и многое другое. Junegunn реализовал MRU просто как:

command! FZFMru call fzf#run({
\  'source':  v:oldfiles,
\  'sink':    'e',
\  'options': '-m -x +s',
\  'down':    '40%'})