Скопировать свойства класса Groovy

Я хочу копировать свойства объекта на другой объект общим способом (если свойство существует в целевом объекте, я копирую его из исходного объекта).

Мой код отлично работает, используя ExpandoMetaClass, но мне не нравится это решение. Есть ли другие способы сделать это?

class User {
    String name = 'Arturo'
    String city = 'Madrid'
    Integer age = 27
}

class AdminUser {
    String name
    String city
    Integer age
}

def copyProperties(source, target) {
    target.properties.each { key, value ->
        if (source.metaClass.hasProperty(source, key) && key != 'class' && key != 'metaClass') {
            target.setProperty(key, source.metaClass.getProperty(source, key))
        }
    }
}

def (user, adminUser) = [new User(), new AdminUser()]
assert adminUser.name == null
assert adminUser.city == null
assert adminUser.age == null

copyProperties(user, adminUser)
assert adminUser.name == 'Arturo'
assert adminUser.city == 'Madrid'
assert adminUser.age == 27

Ответы

Ответ 1

Я думаю, что ваше решение неплохое и находится на правильном пути. По крайней мере, я считаю это вполне понятным.

Более сукцинтная версия этого решения может быть...

def copyProperties(source, target) {
    source.properties.each { key, value ->
        if (target.hasProperty(key) && !(key in ['class', 'metaClass'])) 
            target[key] = value
    }
}

... но это не принципиально иное. Я повторяю свойства источника, поэтому я могу использовать значения для назначения цели:). Он может быть менее надежным, чем исходное решение, хотя, как я думаю, он сломается, если целевой объект определяет метод getAt(String).

Если вы хотите получить фантазию, вы можете сделать что-то вроде этого:

def copyProperties(source, target) {
    def (sProps, tProps) = [source, target]*.properties*.keySet()
    def commonProps = sProps.intersect(tProps) - ['class', 'metaClass']
    commonProps.each { target[it] = source[it] }
}

В основном, он сначала вычисляет общие свойства между двумя объектами, а затем копирует их. Он также работает, но я думаю, что первый из них более прост и понятен:)

Иногда меньше.

Ответ 2

Я думаю, что лучший и понятный способ - использовать метод InvokerHelper.setProperties

Пример:

import groovy.transform.ToString
import org.codehaus.groovy.runtime.InvokerHelper

@ToString
class User {
    String name = 'Arturo'
    String city = 'Madrid'
    Integer age = 27
}

@ToString
class AdminUser {
    String name
    String city
    Integer age
}

def user = new User()
def adminUser = new AdminUser()

println "before: $user $adminUser"
InvokerHelper.setProperties(adminUser, user.properties)
println "after : $user $adminUser"

Вывод:

before: User(Arturo, Madrid, 27) AdminUser(null, null, null)
after : User(Arturo, Madrid, 27) AdminUser(Arturo, Madrid, 27)

Примечание. Если вам нужна более читабельность, вы можете использовать категорию

use(InvokerHelper) {
    adminUser.setProperties(user.properties) 
}

Ответ 3

Другой способ:

def copyProperties( source, target ) {
  [source,target]*.getClass().declaredFields*.grep { !it.synthetic }.name.with { a, b ->
    a.intersect( b ).each {
      target."$it" = source."$it"
    }
  }
}

Что получает общие свойства (которые не являются синтетическими полями), а затем назначает их целевому

Вы также можете (используя этот метод) сделать что-то вроде:

def user = new User()

def propCopy( src, clazz ) {
  [src.getClass(), clazz].declaredFields*.grep { !it.synthetic }.name.with { a, b ->
    clazz.newInstance().with { tgt ->
      a.intersect( b ).each {
        tgt[ it ] = src[ it ]
      }
      tgt
    }
  }
}


def admin = propCopy( user, AdminUser )
assert admin.name == 'Arturo'
assert admin.city == 'Madrid'
assert admin.age == 27

Итак, вы передаете методу объект для копирования свойств из класса и возвращаемого объекта. Затем метод создает новый экземпляр этого класса (предполагая конструктор no-args), устанавливает свойства и возвращает его.

Изменить 2

Предполагая, что это классы Groovy, вы можете вызвать конструктор Map и установить все общие свойства следующим образом:

def propCopy( src, clazz ) {
  [src.getClass(), clazz].declaredFields*.grep { !it.synthetic }.name.with { a, b ->
    clazz.metaClass.invokeConstructor( a.intersect( b ).collectEntries { [ (it):src[ it ] ] } )
  }
}