Xsl: переменная как значение xpath для другого тега xsl

У меня проблемы с xsl:variable. Я хочу создать переменную со значением, которое зависит от значения другого атрибута XML node. Это работает хорошо. Но когда я пытаюсь создать переменную со строковым значением, представляющим XPath, он просто не работает, когда я пытаюсь использовать его как XPath в более позднем теге XSL.

<xsl:variable name="test">  
  <xsl:choose>
    <xsl:when test="node/@attribute=0">string/represent/xpath/1</xsl:when>
    <xsl:otherwise>string/represent/xpath/2</xsl:otherwise>
  </xsl:choose>       
</xsl:variable>                 
<xsl:for-each select="$test">
  [...]
</xsl:for-each>

Я попробовал:  Как использовать переменную xsl в xsl, если а также  проблема с xsl: для каждого выбора с использованием xsl: variable. Но без результатов.

Ответы

Ответ 1

Если этот путь известен заранее, как этот случай, вы можете использовать:

<xsl:variable name="vCondition" select="node/@attribute = 0"/>
<xsl:variable name="test" select="actual/path[$vCondition] |
                                  other/actual/path[not($vCondition)]"/>

Ответ 2

Динамическая оценка выражения XPath обычно не поддерживается в XSLT (как 1.0, так и 2.0):

Мы можем реализовать довольно общий динамический оценщик XPath, если мы ограничиваем только каждый путь местоположения именем элемента:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:param name="inputId" select="'param/yyy/value'"/>

 <xsl:variable name="vXpathExpression"
  select="concat('root/meta/url_params/', $inputId)"/>

 <xsl:template match="/">
  <xsl:value-of select="$vXpathExpression"/>: <xsl:text/>

  <xsl:call-template name="getNodeValue">
    <xsl:with-param name="pExpression"
         select="$vXpathExpression"/>
  </xsl:call-template>
 </xsl:template>

 <xsl:template name="getNodeValue">
   <xsl:param name="pExpression"/>
   <xsl:param name="pCurrentNode" select="."/>

   <xsl:choose>
    <xsl:when test="not(contains($pExpression, '/'))">
      <xsl:value-of select="$pCurrentNode/*[name()=$pExpression]"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:call-template name="getNodeValue">
        <xsl:with-param name="pExpression"
          select="substring-after($pExpression, '/')"/>
        <xsl:with-param name="pCurrentNode" select=
        "$pCurrentNode/*[name()=substring-before($pExpression, '/')]"/>
      </xsl:call-template>
    </xsl:otherwise>
   </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

, когда это преобразование применяется к этому XML-документу:

<root>
  <meta>
    <url_params>
      <param>
        <xxx>
          <value>5</value>
        </xxx>
      </param>
      <param>
        <yyy>
          <value>8</value>
        </yyy>
      </param>
    </url_params>
  </meta>
</root>

требуется, правильный результат получается:

root/meta/url_params/param/yyy/value: 8

Ответ 3

Это невозможно изначально в XSLT 1.0, но вы можете использовать библиотеку расширений, такую ​​как dyn:

http://www.exslt.org/dyn/functions/evaluate/dyn.evaluate.html

Функция dyn:evaluate оценивает строку как выражение XPath.