Как создать пакетный файл для переименования большого количества файлов в папке?

Ответ 1

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
SET old=Vacation2010
SET new=December
for /f "tokens=*" %%f in ('dir /b *.jpg') do (
  SET newname=%%f
  SET newname=!newname:%old%=%new%!
  move "%%f" "!newname!"
)

Что это делает, он перебирает все файлы .jpg в папке, где находится командный файл, и заменяет Vacation2010 на декабрь внутри имен файлов.

Ответ 2

dir /b *.jpg >file.bat

Это даст вам строки, такие как:

Vacation2010 001.jpg
Vacation2010 002.jpg
Vacation2010 003.jpg

Отредактируйте file.bat в любимом Windows текстовый редактор, выполняя эквивалент:

s/Vacation2010(.+)/rename "&" "December \1"/

Это regex; многие редакторы поддерживают их, но ни один из них не работает по умолчанию с Windows (насколько я знаю). Вы также можете получить инструмент командной строки, такой как sed или perl, который может получить точный синтаксис, который у меня выше, после выхода из командной строки.

Результирующие строки будут выглядеть так:

переименовать "Vacation2010 001.jpg" "December 001.jpg"
переименовать "Vacation2010 002.jpg" "December 002.jpg"
переименовать "Vacation2010 003.jpg" "Декабрь 003.jpg"

Вы можете распознать эти строки как команды переименования, по одному на файл из исходного списка.;) Запустите этот пакетный файл в cmd.exe.

Ответ 3

вы можете сделать это легко без ручного редактирования или с помощью графических редакторов. Здесь vbscript.

Set objFS = CreateObject("Scripting.FileSystemObject")
strFolder="c:\test"
Set objFolder = objFS.GetFolder(strFolder)
For Each strFile In objFolder.Files
    If objFS.GetExtensionName(strFile) = "jpg" Then    
        strFileName = strFile.Name
        If InStr(strFileName,"Vacation2010") > 0 Then           
            strNewFileName = Replace(strFileName,"Vacation2010","December")
            strFile.Name = strNewFileName
        End If 
    End If  
Next 

сохранить как myscript.vbs и

C:\test> cscript //nologo myscript.vbs 

Ответ 4

@ECHO off & SETLOCAL EnableDelayedExpansion

SET "_dir=" REM Must finish with '\'
SET "_ext=jpg"
SET "_toEdit=Vacation2010"
SET "_with=December"
FOR %%f IN ("%_dir%*.%_ext%") DO (
    CALL :modifyString "%_toEdit%" "%_with%" "%%~Nf" fileName 
    RENAME "%%f" "!fileName!%%~Xf"
)
GOTO end

:modifyString what with in toReturn
    SET "__in=%~3"
    SET "__in=!__in:%~1=%~2!"
    IF NOT "%~4" == "" (
        SET %~4=%__in%
    ) ELSE (
        ECHO %__in%
    )
    EXIT /B

:end

Этот script позволяет вам изменить имя всех файлов, содержащих Vacation2010 с тем же именем, но с December вместо Vacation2010.

Если вы скопируете и вставьте код, вы должны сохранить .bat в той же папке с фотографиями. Если вы хотите сохранить script в другом каталоге [E.G. у вас есть любимая папка для утилит], вам нужно изменить значение _dir с помощью пути к фотографиям.

Если вам нужно сделать ту же работу для других фотографий [или других файлов changig _ext], вам нужно изменить значение _toEdit на строку, которую вы хотите изменить [или стереть], и значение _with с строкой, которую вы хотите поместить вместо _toEdit [SET "_with=", если вы просто хотите удалить строку, указанную в _toEdit].

Ответ 5

Вам не нужен командный файл, просто сделайте это из powershell:

powershell -C "gci | % {rni $_.Name ($_.Name -replace 'Vacation2010', 'December')}"