В Perl, как я могу узнать, используется ли мой файл в качестве модуля или запускается как script?

Ответ 1

Если файл вызывается как script, не будет caller, чтобы вы могли использовать:

main() unless caller;

Смотрите brian d foy объяснение.

#!/usr/bin/perl

use strict;
use warnings;

main() unless caller;

sub main {
    my $obj = MyClass->new;
    $obj->hello;
}

package MyClass;

use strict;
use warnings;

sub new { bless {} => shift };

sub hello { print "Hello World\n" }

no warnings 'void';
"MyClass"

Вывод:

C:\Temp> perl MyClass.pm
Hello World

Использование из другого script:

C:\Temp\> cat mytest.pl
#!/usr/bin/perl

use strict;
use warnings;

use MyClass;

my $obj = MyClass->new;
$obj->hello;

Вывод:

C:\Temp> mytest.pl
Hello World

Ответ 2

Я называю эти вещи "modulinos" изначально в моей статье Scripts as Modules для журнала Perl (теперь доктор Доббс). Google этот термин, и вы получаете нужные ресурсы. Синан уже связан с моими источниками развития одной из моих книг, где я об этом говорю. Вам также может понравиться Как Script станет модулем.

Ответ 3

Лучше не делать этого и вместо этого использовать структурированный подход, например MooseX::Runnable.

Ваш класс будет выглядеть так:

class Get::Me::Data with (MooseX::Runnable, MooseX::Getopt) {

    has 'dsn' => (
        is            => 'ro',
        isa           => 'Str',
        documentation => 'Database to connect to',
    );

    has 'database' => (
        is         => 'ro',
        traits     => ['NoGetopt'],
        lazy_build => 1,
    );

    method _build_database {
        Database->connect($self->dsn);
    }

    method get_data(Str $for_person){
        return $database->search({ person => $for_person });
    }

    method run(Str $for_person?) {
        if(!$defined $for_person){
            print "Type the person you are looking for: ";
            $for_person = <>;
            chomp $for_person;
        }

        my @data = $self->get_data($for_person);

        if([email protected]){
            say "No data found for $for_person";
            return 1;
        }

        for my $data (@data){
            say $data->format;
        }

        return 0;
    }
}

Теперь у вас есть класс, который можно легко использовать внутри вашей программы:

my $finder = Get::Me::Data->new( database => $dbh );
$finder->get_data('jrockway');

Внутри интерактивного script, который больше, чем только метод "run" выше:

...
my $finder = Get::Me::Data->new( dsn => 'person_database' );
$finder->run('jrockway') and die 'Failure'; # and because "0" is success
say "All done with Get::Me::Data.";
...

Если вы просто хотите сделать это отдельно, вы можете сказать:

$ mx-run Get::Me::Data --help
Usage: mx-run ... [arguments]
    --dsn     Database to connect to

$ mx-run Get::Me::Data --dsn person_database
Type the person you are looking for: jrockway
<data>

$ mx-run Get::Me::Data --dsn person_database jrockway
<data>

Обратите внимание, как мало написано кода, и насколько гибким является результирующий класс. "main if! caller" приятно, но зачем беспокоиться, когда вы можете сделать лучше?

(BTW, MX:: Runnable имеет плагины, поэтому вы можете легко увеличить количество отладочного вывода, которое вы видите, перезапустить приложение при изменении кода, сделать приложение постоянным, запустить его в профилировщике и т.д.)