User Defined Type (UDT) как параметр в открытом модуле Sub in class (VB6)

Ответ 1

Итак, есть ли способ публиковать UDT используется как параметр в общедоступной sub в классе?

Одним словом, нет. Самое близкое, что вы можете использовать только с классическим кодом VB, - это создать класс, который реплицирует UDT и будет использовать его вместо этого. Там определенно есть преимущества, но вы попадаете, если вам нужно передать это, скажем, и API.

Другой вариант - определить UDT в typelib. Если вы это сделаете, его можно использовать как параметр для общедоступного метода.

Ответ 2

Просто укажите sub как область Friend. Это компилируется для меня в классе VB6.

Private Type testtype
  x As String
End Type


Friend Sub testmethod(y As testtype)

End Sub

Из сообщений об ошибках появляется, что ваш класс является приватным. Если вы хотите, чтобы ваш класс был общедоступным, т.е. Вы делали exe или DLL ActiveX, и вы хотите, чтобы клиенты могли получить доступ к югу, тогда просто сделайте как тип, так и суб-публикацию.

Ответ 3

Хорошо, вот как это сделать, если я смогу заставить мою кошку оставить меня в покое, то есть.

В Form1 (с одной кнопкой на нем):

Option Explicit
'
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (ByVal dst As Long, ByVal src As Long, ByVal nBytes As Long)
'

Private Sub Command1_Click()
' Okay, this is what won't work in VB6:
'     Dim MyUdt1 As MyUdtType   ' Declare a variable with a publicly defined UDT (no problem).
'     Form2.Show                ' We could have created some object with a class.  This was just easier for the demo.
'           INSIDE OF FORM2:
'               Public Sub MySub(MyUdt2 As MyUdtType)   ' It won't even let you compile this.
'                   Msgbox MyUdt2.l
'                   MyUdt2.l = 5
'               End Sub
'     Form2.MySub MyUdt1                                ' You'll never get this far.
'     Unload Form2
'     Msgbox MyUdt1.l
'
' The following is a way to get it done:
'
Dim MyUdt1 As MyUdtType         ' Declare a variable with a publicly defined UDT (no problem).
Dim ReturnUdtPtr As Long        ' Declare a variable for a return pointer.
MyUdt1.l = 3                    ' Give the variable of our UDT some value.
Form2.Show                      ' Create our other object.
'
' Now we're ready to call our procedure in the object.
' This is all we really wanted to do all along.
' Notice that the VarPtr of the UDT is passed and not the actual UDT.
' This allows us to circumvent the no passing of UDTs to objects.
ReturnUdtPtr = Form2.MyFunction(VarPtr(MyUdt1))
'
' If we don't want anything back, we could have just used a SUB procedure.
' However, I wanted to give an example of how to go both directions.
' All of this would be exactly the same even if we had started out in a module (BAS).
CopyMemory VarPtr(MyUdt1), ReturnUdtPtr, Len(MyUdt1)
'
' We can now kill our other object (Unload Form2).
' We probably shouldn't kill it until we've copied our UDT data
' because the lifetime of our UDT will be technically ended when we do.
Unload Form2                    ' Kill the other object.  We're done with it.
MsgBox MyUdt1.l                 ' Make sure we got the UDT data back.
End Sub

В form2 (никаких элементов управления не требуется). (Это может быть так же легко, как объект, созданный с помощью класса.):

    Option Explicit
'
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (ByVal dst As Long, ByVal src As Long, ByVal nBytes As Long)
'

Public Function MyFunction(ArgUdtPtr As Long) As Long
' Ok, this is how we get it done.
' There are a couple of things to notice right off the bat.
' First, the POINTER to the UDT is passed (using VarPtr) rather than the actual UDT.
' This way, we can circumvent the restriction of UDT not passed into objects.
' Second, the following MyUdt2 is declared as STATIC.
' This second point is important because the lifetime of MyUdt2 technically ends
' when we return from this function if it is just DIMmed.
' If we want to pass changes back to our caller, we will want to have a slightly longer lifetime.
Static MyUdt2 As MyUdtType
' Ok, we're here, so now we move the argument UDT data into our local UDT.
CopyMemory VarPtr(MyUdt2), ArgUdtPtr, Len(MyUdt2)
' Let see if we got it.
MsgBox MyUdt2.l
' Now we might want to change it, and then pass back our changes.
MyUdt2.l = 5
' Once again, we pass back the pointer, because we can't get the actual UDT back.
' This is where the MyUdt2 being declared as Static becomes important.
MyFunction = VarPtr(MyUdt2)
End Function

И, наконец, это происходит в файле модуля (BAS).

    Option Explicit
'
' This is just the UDT that is used for the example.
Public Type MyUdtType
    l As Long
End Type
'

Ответ 4

Просто передайте UDT как ссылочный параметр, и он будет работать.:)

'method in the class

Public Sub CreateFile(ByRef udt1 As UdtTest)

End Sub

Ответ 5

У меня было такое же сообщение об ошибке, и после проверки приложения я обнаружил, что в окне свойств для класса параметр "Instancing" был установлен в "1 - частный" для объекта, на который ссылается. Я изменил его на "5 - MultiUse" и получил то же сообщение об ошибке. Затем я вернулся к версии модуля проекта до того, как я добавил этот объект, на который ссылался, и добавил его снова в проект - он по умолчанию "1 - частный". Я изменил его на "5 - MultiUse" , прежде чем делать что-либо еще, и закрыл проект, чтобы он обновлялся перед компиляцией. Я повторно открыл проект, подтвердил, что он по-прежнему установлен в "5 - MultiUse" , затем скомпилировал проект и скомпилировал его без сообщения об ошибке.

Когда сообщение об ошибке указывало, что не разрешает ссылаться на частный объект, объект действительно был закрытым. Как только я объявил, что он не является приватным, и модуль проекта принял эту новую настройку, он скомпилирован.

Ответ 6

Определите UDF (открытый тип) в модуле:

Public Type TPVArticulo
    Referencia As String
    Descripcion As String
    PVP As Double
    Dto As Double
End Type

и используйте Friend в классе, модуль o frm:

Friend Function GetArticulo() As TPVArticulo

Ответ 7

UDT должен быть объявлен в общедоступном объекте, например:

Public Class Sample

    Public Strucutre UDT
       Dim Value As Object
    End Structure

End Class