Получить текущего зарегистрированного пользователя ОС в Adobe Air

Ответ 1

Также я бы постарался:

File.userDirectory.name

Но у меня нет Air, поэтому я не могу это проверить...

Ответ 2

Есть несколько небольших очищений, которые вы можете сделать...

package
{
    import flash.filesystem.File;

    public class UserUtil
    {
        public static function get currentOSUser():String
        {
            var userDir:String = File.userDirectory.nativePath;
            var userName:String = userDir.substr(userDir.lastIndexOf(File.separator) + 1);
            return userName;
        }
    }
}

Как предложил Кевин, используйте File.separator, чтобы сделать расщепление каталога кросс-платформой (только что протестировано в Windows и Mac OS X).

Вам не нужно использовать resolvePath(""), если вы не ищете ребенка.

Кроме того, при создании функции правильный getter позволяет связывать без дальнейшей работы.

В приведенном выше примере я помещал его в класс UserUtil, теперь я могу привязываться к UserUtil.currentOSUser, например:

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
    <mx:Label text="{UserUtil.currentOSUser}"/> 
</mx:WindowedApplication>

Ответ 3

Это не самый красивый подход, но если вы знаете, что ваше приложение AIR будет запущено только в среде Windows, он будет работать достаточно хорошо:

public var username:String;

public function getCurrentOSUser():void
{       
   var nativeProcessStartupInfo:NativeProcessStartupInfo = new NativeProcessStartupInfo();  
   var file:File = new File("C:/WINDOWS/system32/whoami.exe");
   nativeProcessStartupInfo.executable = file;

   process = new NativeProcess();       
   process.addEventListener(ProgressEvent.STANDARD_OUTPUT_DATA, onOutputData);
   process.start(nativeProcessStartupInfo);
}

public function onOutputData(event:ProgressEvent):void
{           
   var output:String = process.standardOutput.readUTFBytes(process.standardOutput.bytesAvailable);
   this.username = output.split('\\')[1];
   trace("Got username: ", this.username);
}

Ответ 4

Вот решение, которое работает в XP/Vista, но определенно расширяемое для OSX, Linux, меня все равно будет интересовать другим способом.

public static function GetCurrentOSUser():String{
    // XP & Vista only.
    var userDirectory:String = File.userDirectory.resolvePath("").nativePath;
    var startIndex:Number = userDirectory.lastIndexOf("\\") + 1
    var stopIndex:Number = userDirectory.length;
    var user = userDirectory.substring(startIndex, stopIndex);

    return user;
}

Ответ 5

Обновить путь позже: на самом деле есть встроенная функция для получения текущего пользователя. Я думаю, что это в nativeApplication.