QML Listview выделенный элемент выделить на клик

Привет, я хочу поместить этот код:

highlight: Rectangle {
    color: "black"
    radius: 5 
    opacity: 0.7
    focus: true
}

в mouseArea в обработчике onclick:

MouseArea {
    id: mouse_area1
    z: 1
    hoverEnabled: false
    anchors.fill: parent
    onClicked: {
    }

Это все listView:

ListView {
         id: listview1
         x: 0
         y: 82
        // width: 574
        // height: 967
         width: window.width
         height: window.height
         visible: true
         keyNavigationWraps: false
         boundsBehavior: Flickable.DragAndOvershootBounds
         opacity: 1
         maximumFlickVelocity: 2500
         anchors.leftMargin: 0
         highlightMoveSpeed: 489
         contentWidth: 0
         preferredHighlightEnd: 2
         spacing: 5
         highlightRangeMode: ListView.NoHighlightRange
         snapMode: ListView.SnapToItem
         anchors.bottomMargin: 0
         anchors.rightMargin: 0
         anchors.topMargin: 82
              anchors.fill: parent
              model: myModel
              delegate:Component {
                  //id: contactDelegate
                  Item {
                      property variant myData: model
                      width: 574; height: 90
                      Column {
                          x: 12
                          y: 0
                          width: 562
                          height: 90
                          anchors.rightMargin: 0
                          anchors.bottomMargin: 0
                          anchors.leftMargin: 12
                          anchors.topMargin: 0
                          anchors.fill: parent
                          spacing: 2
                          Text { text: '<b>ID: </b> ' + id_user ; verticalAlignment: Text.AlignTop; wrapMode: Text.NoWrap; horizontalAlignment: Text.AlignHCenter; color:"steelblue"; font.family: "Helvetica"; font.pointSize: 10 }
                          Text { text: '<b>Name: </b> ' + user_name; horizontalAlignment: Text.AlignHCenter; color:"steelblue"; font.family: "Helvetica"; font.pointSize: 10 }
                          Text { text: '<b>Lastname: </b> ' + user_lastname; horizontalAlignment: Text.AlignHCenter; color:"steelblue"; font.family: "Helvetica"; font.pointSize: 10 }
                          Text { height: 16; text: '<b>Tel number: </b> ' + user_number; verticalAlignment: Text.AlignVCenter; horizontalAlignment: Text.AlignHCenter; color:"steelblue"; font.family: "Helvetica"; font.pointSize: 10 }
                          Text { text: '<b>Address: </b> ' + user address; horizontalAlignment: Text.AlignHCenter; color:"steelblue"; font.family: "Helvetica"; font.pointSize: 10 }

                          MouseArea {
                              id: mouse_area1
                              z: 1
                              hoverEnabled: false
                              anchors.fill: parent
                              onClicked: 
                                  Item
                              {

                                }

                          }
                      }
                      }
              }

              //delegate: contactDelegate
              highlight: Rectangle
              {
                   color:"black"
                   radius: 5
                   opacity: 0.7
                   focus: true
              }
}

Теперь подсветка работает только при использовании стрелок, но это будет приложение для андроида, поэтому мне нужно на ощупь тот же эффект, а ВТОРОЙ вопрос - как читать определенные данные из выбранного элемента в списке? Внутри у меня есть идентификатор, имя, фамилия, номер и адрес. Я хочу поместить эти значения в поля text_input.

Спасибо

Ответы

Ответ 1

Ответ предоставлен denoth: вам нужно добавить эту строку:

listview1.currentIndex = index

Ответ 2

Кажется, вам нужно два решения вашего вопроса:

Вы хотите иметь возможность устанавливать текущий элемент ListView при нажатии
Вы хотите знать, когда изменяется текущий выбор.

Документация Qt5 говорит об этом ListView управление мышью и касанием:

Обработчики просмотров перетаскивают и перемещают их содержимое, однако они не обрабатывают сенсорное взаимодействие с отдельными делегатами. Для того чтобы делегаты могли реагировать на сенсорный ввод, например, для установки currentIndex, делегат должен предоставить MouseArea с соответствующей логикой обработки касания.

Ввод ключа будет работать из коробки, но вам нужно явно поймать событие mouse/touch на делетете и изменить значение ListView.currentIndex на основе значения index выбранного элемента делегирования.

Вот полный пример:

import QtQuick 2.4
import QtQuick.Window 2.2

Window {
    width: 640
    height: 480
    visible: true

    ListModel {
        id: model
        ListElement {
            name:'abc'
            number:'123'
        }
        ListElement {
            name:'efg'
            number:'456'
        }
        ListElement {
            name:'xyz'
            number:'789'
        }
    }

    ListView {
        id: list
        anchors.fill: parent
        model: model
        delegate: Component {
            Item {
                width: parent.width
                height: 40
                Column {
                    Text { text: 'Name:' + name }
                    Text { text: 'Number:' + number }
                }
                MouseArea {
                    anchors.fill: parent
                    onClicked: list.currentIndex = index
                }
            }
        }
        highlight: Rectangle {
            color: 'grey'
            Text {
                anchors.centerIn: parent
                text: 'Hello ' + model.get(list.currentIndex).name
                color: 'white'
            }
        }
        focus: true
        onCurrentItemChanged: console.log(model.get(list.currentIndex).name + ' selected')
    }
}

Он выполняет следующие действия:

создает простой список и модель
использует элемент MouseArea в делегате элемента для обновления, установите list.currentIndex = index, который является локальным var и уникальным для выбранного элемента
прослушивает событие onCurrentItemChanged для ListView, чтобы показать, как получить доступ к текущим значениям элементов модели
привязывает текстовое значение текущего выбранного элемента к выделенному элементу для отображения с использованием текущих выбранных значений в другом месте

Ответ 3

ListView предоставляет так называемые прикрепленные свойства", то есть свойства, доступные в списке delegate для списка. Среди них Listview.view есть ссылка на сам список. Его можно использовать для доступа к свойству currentIndex и его обновлению. Следовательно, для решения вашей проблемы просто:

Uncomment //id: contactDelegate.
Установите contactDelegate.ListView.view.currentIndex = index в OnClick даже обработчик.

Ответ 4

Проще чем когда-либо, вы можете использовать: onCurrentItemChanged

ListView{
    id: listViewMainMenu
    signal Myselect(int playmode)
    onCurrentItemChanged: Myselect(listViewMainMenu.currentIndex)
    // ...
}

Ответ 5

Для тех, кто использует подсветку в ListView с определенной высотой (будучи не заполненной на 100%):

Обязательно включите свойство clip свойства ListView, так как иначе подсветка будет видна вне границ ListView при прокрутке,

ListView 
{
    clip: true    
}

Как обсуждалось здесь: Скрыть выделение ListView при прокрутке