Вычитание церковных цифр в haskell

Я пытаюсь внедрить церковные цифры в Haskell, но я столкнулся с небольшой проблемой. Haskell жалуется на бесконечный тип с помощью

Происходит проверка: невозможно построить бесконечный тип: t = (t → t1) → (t1 → t2) → t2

когда я пытаюсь сделать вычитание. Я на 99% уверен, что мое исчисление лямбда действительно (хотя, если это не так, пожалуйста, скажите мне). Я хочу знать, есть ли что-нибудь, что я могу сделать, чтобы заставить haskell работать с моими функциями.

module Church where

type (Church a) = ((a -> a) -> (a -> a))

makeChurch :: Int -> (Church a)
makeChurch 0 = \f -> \x -> x
makeChurch n = \f -> \x -> f (makeChurch (n-1) f x)

numChurch x = (x succ) 0

showChurch x = show $ numChurch x

succChurch = \n -> \f -> \x -> f (n f x)

multChurch = \f2 -> \x2 -> \f1 -> \x1 -> f2 (x2 f1) x1

powerChurch = \exp -> \n -> exp (multChurch n) (makeChurch 1)

predChurch = \n -> \f -> \x -> n (\g -> \h -> h (g f)) (\u -> x) (\u -> u)

subChurch = \m -> \n -> (n predChurch) m

Ответы

Ответ 1

Проблема в том, что predChurch слишком полиморфна, чтобы правильно вывести вывод типа Хиндли-Милнера. Например, соблазнительно написать:

predChurch :: Church a -> Church a
predChurch = \n -> \f -> \x -> n (\g -> \h -> h (g f)) (\u -> x) (\u -> u)

но этот тип неверен. A Church a принимает в качестве своего первого аргумента a a -> a, но вы передаете n функцию с двумя аргументами, явно ошибку типа.

Проблема состоит в том, что Church a неправильно характеризует цифру Церкви. Церковная цифра просто представляет собой число - что может означать этот параметр типа? Например:

foo :: Church Int
foo f x = f x `mod` 42

Это typechecks, но foo, безусловно, не является церковной цифрой. Нам нужно ограничить тип. Церковные цифры должны работать для любого a, а не только для конкретного a. Правильное определение:

type Church = forall a. (a -> a) -> (a -> a)

Вам нужно иметь {-# LANGUAGE RankNTypes #-} в верхней части файла, чтобы включить такие типы.

Теперь мы можем дать подпись типа, которую мы ожидаем:

predChurch :: Church -> Church
-- same as before

Здесь вы должны указать подпись типа, потому что более высокие классы не выводятся Hindley-Milner.

Однако, когда мы переходим к реализации subChurch, возникает другая проблема:

Couldn't match expected type `Church'
       against inferred type `(a -> a) -> a -> a'

Я не уверен на 100%, почему это происходит, я думаю, что forall слишком либерально разворачивается программой typechecker. Меня это не удивляет; более высокие типы рангов могут быть немного хрупкими из-за трудностей, которые они представляют компилятору. Кроме того, мы не должны использовать type для абстракции, мы должны использовать newtype (что дает нам большую гибкость в определении, помогает компилятору с проверкой меток и отмечает места, где мы используем реализацию абстракции):

newtype Church = Church { unChurch :: forall a. (a -> a) -> (a -> a) }

И мы должны изменить predChurch для рулона и разворачивания по мере необходимости:

predChurch = \n -> Church $ 
    \f -> \x -> unChurch n (\g -> \h -> h (g f)) (\u -> x) (\u -> u)

То же самое с subChurch:

subChurch = \m -> \n -> unChurch n predChurch m

Но нам больше не нужны сигнатуры типов - в списке roll/unroll достаточно информации для повторного ввода типов.

Я всегда рекомендую newtype при создании новой абстракции. Регулярные синонимы type довольно редко встречаются в моем коде.

Ответ 3

Я столкнулся с той же проблемой. И я решил это без добавления сигнатуры типа.

Здесь решение с cons car скопировано из SICP.

cons x y = \m -> m x y
car z = z (\p q -> p)
cdr z = z (\p q -> q)

next z = cons (cdr z) (succ (cdr z))
pred n = car $ n next (cons undefined zero)

sub m n = n pred m

Здесь вы можете найти полный источник .

Я действительно поражен после написания sub m n = n pred m и загружаю его в ghci без ошибки типа!

Код Haskell настолько краток!: -)