Ответ 1
Прошло много времени с тех пор, как я задал этот вопрос, и мое решение претерпело все новые и новые улучшения. Мне приходилось иметь дело со всякими особыми случаями, такими как значения, которые поступают непосредственно из книги, разделы, которые должны быть специально созданы на основе списков, и необходимость выполнять замены в верхних и нижних колонтитулах.
Как оказалось, для закладок было недостаточно использовать, так как пользователям было возможно впоследствии редактировать документы для изменения, добавления и удаления значений-заполнителей из документов. Фактически, решение заключалось в использовании ключевых слов, таких как:
Это всего лишь страница из образца документа, в которой используются некоторые из возможных значений, которые могут автоматически добавляться в документ. Более 50 документов существуют с совершенно разными структурами и макетами и с использованием разных параметров. Единственное общее знание, которое разделяют словарные документы и электронная таблица excel, - это знание того, что означают эти значения-заполнители. В excel это сохраняется в списке ключевых слов генерации документа, которые содержат ключевое слово, а затем ссылка на диапазон, который фактически содержит это значение:
Это были ключевые два необходимых ингредиента. Теперь с некоторым умным кодом все, что мне нужно было сделать, это перебрать каждый создаваемый документ, а затем перебрать диапазон всех известных ключевых слов и выполнить поиск и замену для каждого ключевого слова в каждом документе.
Во-первых, у меня есть метод обертки, который заботится о том, чтобы поддерживать экземпляр слова microsoft, итерации по всем документам, выбранным для генерации, нумерации документов и выполнению пользовательского интерфейса (например, ошибки обработки, отображение папки пользователю, и т.д.)
' Purpose: Iterates over and generates all documents in the list of forms to generate
' Improves speed by creating a persistant Word application used for all generated documents
Public Sub GeneratePolicy()
Dim oWrd As New Word.Application
Dim srcPath As String
Dim cel As Range
If ERROR_HANDLING Then On Error GoTo errmsg
If Forms.Cells(2, FormsToGenerateCol) = vbNullString Then _
Err.Raise 1, , "There are no forms selected for document generation."
'Get the path of the document repository where the forms will be found.
srcPath = FindConstant("Document Repository")
'Each form generated will be numbered sequentially by calling a static counter function. This resets it.
GetNextEndorsementNumber reset:=True
'Iterate over each form, calling a function to replace the keywords and save a copy to the output folder
For Each cel In Forms.Range(Forms.Cells(2, FormsToGenerateCol), Forms.Cells(1, FormsToGenerateCol).End(xlDown))
RunReplacements cel.value, CreateDocGenPath(cel.Offset(0, 1).value), oWrd
Next cel
oWrd.Quit
On Error Resume Next
'Display the folder containing the generated documents
Call Shell("explorer.exe " & CreateDocGenPath, vbNormalFocus)
oWrd.Quit False
Application.StatusBar = False
If MsgBox("Policy generation complete. The reserving information will now be recorded.", vbOKCancel, _
"Policy Generated. OK to store reserving info?") = vbOK Then Push_Reserving_Requirements
Exit Sub
errmsg:
MsgBox Err.Description, , "Error generating Policy Documents"
End Sub
Эта процедура вызывает RunReplacements, которая заботится о том, чтобы открыть документ, подготовить среду для быстрой замены, обновить ссылки после завершения, обрабатывать ошибки и т.д.:
' Purpose: Opens up a document and replaces all instances of special keywords with their respective values.
' Creates an instance of Word if an existing one is not passed as a parameter.
' Saves a document to the target path once the template has been filled in.
'
' Replacements are done using two helper functions, one for doing simple keyword replacements,
' and one for the more complex replacements like conditional statements and schedules.
Private Sub RunReplacements(ByVal DocumentPath As String, ByVal SaveAsPath As String, _
Optional ByRef oWrd As Word.Application = Nothing)
Dim oDoc As Word.Document
Dim oWrdGiven As Boolean
If oWrd Is Nothing Then Set oWrd = New Word.Application Else oWrdGiven = True
If ERROR_HANDLING Then On Error GoTo docGenError
oWrd.Visible = False
oWrd.DisplayAlerts = wdAlertsNone
Application.StatusBar = "Opening " & Mid(DocumentPath, InStrRev(DocumentPath, "\") + 1)
Set oDoc = oWrd.Documents.Open(Filename:=DocumentPath, Visible:=False)
RunAdvancedReplacements oDoc
RunSimpleReplacements oDoc
UpdateLinks oDoc 'Routine which will update calculated statements in Word (like current date)
Application.StatusBar = "Saving " & Mid(DocumentPath, InStrRev(DocumentPath, "\") + 1)
oDoc.SaveAs SaveAsPath
GoTo Finally
docGenError:
MsgBox "Un unknown error occurred while generating document: " & DocumentPath & vbNewLine _
& vbNewLine & Err.Description, vbCritical, "Document Generation"
Finally:
If Not oDoc Is Nothing Then oDoc.Close False: Set oDoc = Nothing
If Not oWrdGiven Then oWrd.Quit False
End Sub
Эта процедура затем вызывает RunSimpleReplacements. и RunAdvancedReplacements. В первом мы перебираем набор ключевых слов генерации документов и вызываем WordDocReplace, если документ содержит наше ключевое слово. Обратите внимание, что гораздо быстрее попробовать и Find кучу слов, чтобы выяснить, что их не существует, а затем вызвать замену без разбора, поэтому мы всегда проверяем, существует ли ключевое слово, прежде чем пытаться его заменить.
' Purpose: While short, this short module does most of the work with the help of the generation keywords
' range on the lists sheet. It loops through every simple keyword that might appear in a document
' and calls a function to have it replaced with the corresponding data from pricing.
Private Sub RunSimpleReplacements(ByRef oDoc As Word.Document)
Dim DocGenKeys As Range, valueSrc As Range
Dim value As String
Dim i As Integer
Set DocGenKeys = Lists.Range("DocumentGenerationKeywords")
For i = 1 To DocGenKeys.Rows.Count
If WordDocContains(oDoc, "#" & DocGenKeys.Cells(i, 1).Text & "#") Then
'Find the text that we will be replacing the placeholder keyword with
Set valueSrc = Range(Mid(DocGenKeys.Cells(i, 2).Formula, 2))
If valueSrc.MergeCells Then value = valueSrc.MergeArea.Cells(1, 1).Text Else value = valueSrc.Text
'Perform the replacement
WordDocReplace oDoc, "#" & DocGenKeys.Cells(i, 1).Text & "#", value
End If
Next i
End Sub
Это функция, используемая для определения наличия ключевого слова в документе:
' Purpose: Function called for each replacement to first determine as quickly as possible whether
' the document contains the keyword, and thus whether replacement actions must be taken.
Public Function WordDocContains(ByRef oDoc As Word.Document, ByVal searchFor As String) As Boolean
Application.StatusBar = "Checking for keyword: " & searchFor
WordDocContains = False
Dim storyRange As Word.Range
For Each storyRange In oDoc.StoryRanges
With storyRange.Find
.Text = searchFor
WordDocContains = WordDocContains Or .Execute
End With
If WordDocContains Then Exit For
Next
End Function
И вот здесь резина встречает дорогу - код, который выполняет замену. Эта процедура усложнилась, когда я столкнулся с трудностями. Вот уроки, которые вы сможете извлечь из опыта:
-
Вы можете напрямую установить заменяющий текст, или вы можете использовать буфер обмена. Я обнаружил, что, если вы используете замену VBA в словах длиной более 255 символов, текст будет усечен, если вы попытаетесь поместить его в
Find.Replacement.Text, но вы можете использовать"^c"как ваш замените текст, и он получит его непосредственно из буфера обмена. Это был обходной путь, который мне пришлось использовать. -
Простое замену заменяет пропущенные ключевые слова в некоторых текстовых областях, таких как верхние и нижние колонтитулы. Из-за этого вам действительно нужно выполнить итерацию по
document.StoryRangesи выполнить поиск и замену на каждом из них, чтобы убедиться, что вы улавливаете все экземпляры слова, которое хотите заменить. -
Если вы напрямую устанавливаете
Replacement.Text, вам нужно преобразовать разрывы строк Excel (vbNewLineиChr(10)) с помощью простогоvbCrдля правильного отображения слов. В противном случае в любом месте вашего текста замены есть разрывы строк, исходящие из ячейки excel, в результате чего вставляются странные символы в слово. Однако, если вы используете метод буфера обмена, вам не нужно это делать, так как разрывы строк автоматически преобразуются при вставке в буфер обмена.
Это все объясняет. Комментарии тоже должны быть понятны. Вот золотая рутина, которая выполняет магию:
' Purpose: This function actually performs replacements using the Microsoft Word API
Public Sub WordDocReplace(ByRef oDoc As Word.Document, ByVal replaceMe As String, ByVal replaceWith As String)
Dim clipBoard As New MSForms.DataObject
Dim storyRange As Word.Range
Dim tooLong As Boolean
Application.StatusBar = "Replacing instances of keyword: " & replaceMe
'We want to use regular search and replace if we can. It faster and preserves the formatting that
'the keyword being replaced held (like bold). If the string is longer than 255 chars though, the
'standard replace method doesn't work, and so we must use the clipboard method (^c special character),
'which does not preserve formatting. This is alright for schedules though, which are always plain text.
If Len(replaceWith) > 255 Then tooLong = True
If tooLong Then
clipBoard.SetText IIf(replaceWith = vbNullString, "", replaceWith)
clipBoard.PutInClipboard
Else
'Convert excel in-cell line breaks to word line breaks. (Not necessary if using clipboard)
replaceWith = Replace(replaceWith, vbNewLine, vbCr)
replaceWith = Replace(replaceWith, Chr(10), vbCr)
End If
'Replacement must be done on multiple 'StoryRanges'. Unfortunately, simply calling replace will miss
'keywords in some text areas like headers and footers.
For Each storyRange In oDoc.StoryRanges
Do
With storyRange.Find
.MatchWildcards = True
.Text = replaceMe
.Replacement.Text = IIf(tooLong, "^c", replaceWith)
.Wrap = wdFindContinue
.Execute Replace:=wdReplaceAll
End With
On Error Resume Next
Set storyRange = storyRange.NextStoryRange
On Error GoTo 0
Loop While Not storyRange Is Nothing
Next
If tooLong Then clipBoard.SetText ""
If tooLong Then clipBoard.PutInClipboard
End Sub
Когда пыль оседает, мы оставляем красивую версию исходного документа с производственными значениями вместо тех хеш-отмеченных ключевых слов. Я хотел бы показать пример, но, конечно, каждый заполненный документ содержит всю конфиденциальную информацию.
Остается только упомянуть, что я думаю, что это RunAdvancedReplacements. Он делает что-то очень похожее - он вызывает вызов той же функции WordDocReplace, но что особенно важно в отношении ключевых слов, используемых здесь, заключается в том, что они не ссылаются на одну ячейку в исходной книге, они генерируются в коде с списки в книге. Так, например, одна из расширенных замен будет выглядеть так:
'Generate the schedule of vessels
If WordDocContains(oDoc, "#VESSELSCHEDULE#") Then _
WordDocReplace oDoc, "#VESSELSCHEDULE#", GenerateVesselSchedule()
И тогда будет соответствующая подпрограмма, которая объединяет строку, содержащую всю информацию о судне, как она настроена пользователем:
' Purpose: Generates the list of vessels from the "Vessels" sheet based on the user configuration
' in the booking tab. The user has the option to generate one or both of Owned Vessels
' and Chartered Vessels, as well as what fields to display. Uses a helper function.
Public Function GenerateVesselSchedule() As String
Dim value As String
Application.StatusBar = "Generating Schedule of Vessels."
If Booking.Range("ListVessels").value = "Yes" Then
Dim VesselCount As Long
If Booking.Range("ListVessels").Offset(1).value = "Yes" Then _
value = value & GenerateVesselScheduleHelper("Vessels", VesselCount)
If Booking.Range("ListVessels").Offset(1).value = "Yes" And _
Booking.Range("ListVessels").Offset(2).value = "Yes" Then _
value = value & "(Chartered Vessels)" & vbNewLine
If Booking.Range("ListVessels").Offset(2).value = "Yes" Then _
value = value & GenerateVesselScheduleHelper("CharteredVessels", VesselCount)
If Len(value) > 2 Then value = Left(value, Len(value) - 2) 'Remove the trailing line break
Else
GenerateVesselSchedule = Booking.Range("VesselSchedAlternateText").Text
End If
GenerateVesselSchedule = value
End Function
' Purpose: Helper function for the Vessel Schedule generation routine. Generates either the Owned or
' Chartered vessels based on the schedule parameter passed. The list is numbered and contains
' the information selected by the user on the Booking sheet.
' SENSITIVE: Note that this routine is sensitive to the layout of the Vessel Schedule tab and the
' parameters on the Configure Quotes tab. If either changes, it should be revisited.
Public Function GenerateVesselScheduleHelper(ByVal schedule As String, ByRef VesselCount As Long) As String
Dim value As String, nextline As String
Dim numInfo As Long, iRow As Long, iCol As Long
Dim Inclusions() As Boolean, Columns() As Long
'Gather info about vessel info to display in the schedule
With Booking.Range("VesselInfoToInclude")
numInfo = Booking.Range(.Cells(1, 1), .End(xlToRight)).Columns.Count - 1
ReDim Inclusions(1 To numInfo)
ReDim Columns(1 To numInfo)
On Error Resume Next 'Some columns won't be identified
For iCol = 1 To numInfo
Inclusions(iCol) = .Offset(0, iCol) = "Yes"
Columns(iCol) = sumSchedVessels.Range(schedule).Cells(1).EntireRow.Find(.Offset(-1, iCol)).Column
Next iCol
On Error GoTo 0
End With
'Build the schedule
With sumSchedVessels.Range(schedule)
For iRow = .row + 1 To .row + .Rows.Count - 1
If Len(sumSchedVessels.Cells(iRow, Columns(1)).value) > 0 Then
VesselCount = VesselCount + 1
value = value & VesselCount & "." & vbTab
nextline = vbNullString
'Add each property that was included to the description string
If Inclusions(1) Then nextline = nextline & sumSchedVessels.Cells(iRow, Columns(1)) & vbTab
If Inclusions(2) Then nextline = nextline & "Built: " & sumSchedVessels.Cells(iRow, Columns(2)) & vbTab
If Inclusions(3) Then nextline = nextline & "Length: " & _
Format(sumSchedVessels.Cells(iRow, Columns(3)), "#'") & vbTab
If Inclusions(4) Then nextline = nextline & "" & sumSchedVessels.Cells(iRow, Columns(4)) & vbTab
If Inclusions(5) Then nextline = nextline & "Hull Value: " & _
Format(sumSchedVessels.Cells(iRow, Columns(5)), "$#,##0") & vbTab
If Inclusions(6) Then nextline = nextline & "IV: " & _
Format(sumSchedVessels.Cells(iRow, Columns(6)), "$#,##0") & vbTab
If Inclusions(7) Then nextline = nextline & "TIV: " & _
Format(sumSchedVessels.Cells(iRow, Columns(7)), "$#,##0") & vbTab
If Inclusions(8) And schedule = "CharteredVessels" Then _
nextline = nextline & "Deductible: " & Format(bmCharterers.Range(schedule).Cells( _
iRow - .row, 9), "$#,##0") & vbTab
nextline = Left(nextline, Len(nextline) - 1) 'Remove the trailing tab
'If more than 4 properties were included insert a new line after the 4th one
Dim tabloc As Long: tabloc = 0
Dim counter As Long: counter = 0
Do
tabloc = tabloc + 1
tabloc = InStr(tabloc, nextline, vbTab)
If tabloc > 0 Then counter = counter + 1
Loop While tabloc > 0 And counter < 4
If counter = 4 Then nextline = Left(nextline, tabloc - 1) & vbNewLine & Mid(nextline, tabloc)
value = value & nextline & vbNewLine
End If
Next iRow
End With
GenerateVesselScheduleHelper = value
End Function
результирующая строка может использоваться так же, как содержимое любой ячейки excel, и передается функции замены, которая будет соответствующим образом использовать метод буфера обмена, если он превышает 255 символов.
Итак, этот шаблон:
Кроме того, данные в электронной таблице:
Стать этим документом:
Я искренне надеюсь, что однажды это поможет кому-то. Это было определенно огромная задача и сложное колесо, которое нужно было изобретать. Приложение огромно, с более чем 50 000 строк кода VBA, поэтому, если я упоминал критический метод в моем коде где-то, что кому-то нужно, оставьте комментарий, и я добавлю его здесь.