Использование нескольких GPU

Как я могу использовать два устройства для улучшения, например, производительность следующего кода (сумма векторов)? Можно ли одновременно использовать больше устройств? Если да, как я могу управлять распределениями векторов в глобальной памяти разных устройств?

#include <stdio.h>
#include <stdlib.h>
#include <math.h>
#include <time.h>
#include <cuda.h>

#define NB 32
#define NT 500
#define N NB*NT

__global__ void add( double *a, double *b, double *c);

//===========================================
__global__ void add( double *a, double *b, double *c){

    int tid = threadIdx.x + blockIdx.x * blockDim.x; 

    while(tid < N){
        c[tid] = a[tid] + b[tid];
        tid += blockDim.x * gridDim.x;
    }

}

//============================================
//BEGIN
//===========================================
int main( void ) {

    double *a, *b, *c;
    double *dev_a, *dev_b, *dev_c;

    // allocate the memory on the CPU
    a=(double *)malloc(N*sizeof(double));
    b=(double *)malloc(N*sizeof(double));
    c=(double *)malloc(N*sizeof(double));

    // allocate the memory on the GPU
    cudaMalloc( (void**)&dev_a, N * sizeof(double) );
    cudaMalloc( (void**)&dev_b, N * sizeof(double) );
    cudaMalloc( (void**)&dev_c, N * sizeof(double) );

    // fill the arrays 'a' and 'b' on the CPU
    for (int i=0; i<N; i++) {
        a[i] = (double)i;
        b[i] = (double)i*2;
    }

    // copy the arrays 'a' and 'b' to the GPU
    cudaMemcpy( dev_a, a, N * sizeof(double), cudaMemcpyHostToDevice);
    cudaMemcpy( dev_b, b, N * sizeof(double), cudaMemcpyHostToDevice);

    for(int i=0;i<10000;++i)
        add<<<NB,NT>>>( dev_a, dev_b, dev_c );

    // copy the array 'c' back from the GPU to the CPU
    cudaMemcpy( c, dev_c, N * sizeof(double), cudaMemcpyDeviceToHost);

    // display the results
    // for (int i=0; i<N; i++) {
    //      printf( "%g + %g = %g\n", a[i], b[i], c[i] );
    //  }
    printf("\nGPU done\n");

    // free the memory allocated on the GPU
    cudaFree( dev_a );
    cudaFree( dev_b );
    cudaFree( dev_c );
    // free the memory allocated on the CPU
    free( a );
    free( b );
    free( c );

    return 0;
}

Спасибо заранее. Мишель

Ответы

Ответ 1

Поскольку CUDA 4.0 был выпущен, вычисления с несколькими GPU типа, о котором вы просите, относительно просты. До этого вам нужно будет использовать многопоточное хост-приложение с одним потоком хоста для каждого графического процессора и какую-то систему межпоточных коммуникаций, чтобы использовать mutliple GPU внутри одного и того же хост-приложения.

Теперь для части выделения памяти вашего хост-кода можно сделать что-то вроде этого:

double *dev_a[2], *dev_b[2], *dev_c[2];
const int Ns[2] = {N/2, N-(N/2)};

// allocate the memory on the GPUs
for(int dev=0; dev<2; dev++) {
    cudaSetDevice(dev);
    cudaMalloc( (void**)&dev_a[dev], Ns[dev] * sizeof(double) );
    cudaMalloc( (void**)&dev_b[dev], Ns[dev] * sizeof(double) );
    cudaMalloc( (void**)&dev_c[dev], Ns[dev] * sizeof(double) );
}

(отказ от ответственности: написан в браузере, никогда не компилируется, никогда не тестируется, используется на свой страх и риск).

Основная идея здесь заключается в том, что вы используете cudaSetDevice для выбора между устройствами, когда выполняете операции предварительного форматирования на устройстве. Поэтому в приведенном выше фрагменте я предположил два графических процессора и выделил память на каждом [(N/2) удвоении на первом устройстве и N- (N/2) на втором].

Передача данных с хоста на устройство может быть простой:

// copy the arrays 'a' and 'b' to the GPUs
for(int dev=0,pos=0; dev<2; pos+=Ns[dev], dev++) {
    cudaSetDevice(dev);
    cudaMemcpy( dev_a[dev], a+pos, Ns[dev] * sizeof(double), cudaMemcpyHostToDevice);
    cudaMemcpy( dev_b[dev], b+pos, Ns[dev] * sizeof(double), cudaMemcpyHostToDevice);
}

(отказ от ответственности: написан в браузере, никогда не компилируется, никогда не тестируется, используется на свой страх и риск).

Раздел запуска ядра вашего кода может выглядеть примерно так:

for(int i=0;i<10000;++i) {
    for(int dev=0; dev<2; dev++) {
        cudaSetDevice(dev);
        add<<<NB,NT>>>( dev_a[dev], dev_b[dev], dev_c[dev], Ns[dev] );
    }
}

(отказ от ответственности: написан в браузере, никогда не скомпилирован, никогда не тестировался, используйте на свой страх и риск).

Обратите внимание, что я добавил дополнительный аргумент для вашего вызова ядра, потому что каждый экземпляр ядра может быть вызван с другим количеством элементов массива для обработки. Я оставлю это вам для разработки необходимых изменений. Но, опять же, основная идея одна и та же: используйте cudaSetDevice для выбора данного графического процессора, а затем запускайте ядра на нем обычным способом, причем каждое ядро ​​получает свои собственные уникальные аргументы.

Вы можете объединить эти части для создания простого приложения с несколькими GPU. Существует множество других функций, которые можно использовать в последних версиях и оборудовании CUDA для поддержки нескольких приложений GPU (например, для унифицированной адресации, для одноранговых узлов больше), но этого должно быть достаточно, чтобы вы начали. Существует также приложение muLti-GPU в SDK CUDA, на которое вы можете посмотреть больше идей.