Как и когда переменные, на которые ссылаются анонимные методы Delphi?

Ответ 1

Когда у вас есть функция, подобная той, которая находится в вопросе, где у вас есть анонимный метод, который обращается к локальной переменной, Delphi, похоже, создает один потомок TInterfacedObject, который захватывает все переменные на основе стека, поскольку он принадлежит общедоступным переменным. Используя трюк Барри, чтобы добраться до реализующего TObject и немного RTTI, мы можем видеть все это в действии.

Магический код реализации, вероятно, выглядит следующим образом:

// Magic object that holds what would normally be Stack variables and implements
// anonymous methods.
type ProcedureThatUsesAnonymousMethods$ActRec = class(TInterfacedObject)
public
  V: string;
  function AnonMethodImp: string;
end;

// The procedure with all the magic brought to light
procedure ProcedureThatUsesAnonymousMethods;
var MagicInterface: IUnknown;
    F1: TFunc<string>;
    F2: TFunc<string>;
begin
  MagicInterface := ProcedureThatUsesAnonymousMethods$ActRec.Create;
  try
    F1 := MagicInterface.AnonMethod;
    MagicInterface.V := '1';
    F2 := MagicInterface.SomeOtherAnonMethod;
    MagicInterface.V := '2';
    ShowMessage(F1);
    ShowMessage(F2);
  finally MagicInterface := nil;
  end;
end;

Конечно, этот код не компилируется. Я без магии:-) Но идея здесь в том, что объект "Magic" создается за кулисами, а локальные переменные, на которые ссылаются анонимный метод, преобразуются в общедоступные поля магического объекта. Этот объект используется как интерфейс (IUnkown), поэтому он получает подсчет ссылок. По-видимому, тот же объект фиксирует все используемые переменные И определяет все анонимные методы.

Это должно отвечать как "Когда", так и "Как".

Вот код, который я использовал для исследования. Поместите TButton в пустой форме, это должен быть весь блок. Когда вы нажмете кнопку, на экране вы увидите следующее:

• 000000 (фиктивный номер)
• 000000 (тот же номер): Это доказывает, что оба анонимных метода фактически реализованы как методы одного и того же объекта!
• TForm25.Button1Click$ActRec: TInterfacedObject: Это показывает объект за реализацией, полученный из TInterfacedObject
• OnStack:string: RTTI обнаруживает это поле на этом объекте.
• Self: TForm25: RTTI обнаруживает это поле на этом объекте. Он использовал для получения значения ClasVar
• FRefCount:Integer - это происходит от TInterfacedObject
• Class Var - результат ShowMessage.
• On Stack - результат ShowMessage.

Здесь код:

unit Unit25;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Rtti;

type
  TForm25 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    ClassVar: string;
  public
  end;

var
  Form25: TForm25;

implementation

{$R *.dfm}

procedure TForm25.Button1Click(Sender: TObject);
var F1: TFunc<string>;
    F2: TFunc<string>;

    OnStack: string;

    i: IInterface;
    o: TObject;

    RC: TRttiContext;
    R: TRttiType;
    RF: TRttiField;

begin
  // This anonymous method references a member field of the TForm class
  F1 := function :string
        begin
          Result := ClassVar;
        end;

  i := PUnknown(@F1)^;
  o := i as TObject;
  ShowMessage(IntToStr(Integer(o))); // I'm looking at the pointer to see if it the same instance as the one for the other Anonymous method

  // This anonymous method references a stack variable
  F2 := function :string
        begin
          Result := OnStack;
        end;

  i := PUnknown(@F2)^;
  o := i as TObject;
  ShowMessage(IntToStr(Integer(o)));

  ShowMessage(o.ClassName + ': ' + o.ClassType.ClassParent.ClassName);

  RC.Create;
  try
    R := RC.GetType(o.ClassType);
    for RF in R.GetFields do
      ShowMessage(RF.Name + ':' + RF.FieldType.Name);
  finally RC.Free;
  end;

  ClassVar := 'Class Var';
  OnStack := 'On Stack';

  ShowMessage(F1);
  ShowMessage(F2);
end;

end.