SQL Server - остановить или прервать выполнение SQL script

Ответ 1

метод raiserror

raiserror('Oh no a fatal error', 20, -1) with log

Это приведет к завершению соединения, тем самым остановив оставшуюся часть script.

Обратите внимание, что для того, чтобы он работал таким образом, необходимы как уровень серьезности 20, так и выше и параметр WITH LOG.

Это даже работает с операторами GO, например.

print 'hi'
go
raiserror('Oh no a fatal error', 20, -1) with log
go
print 'ho'

Выдает результат:

hi
Msg 2745, Level 16, State 2, Line 1
Process ID 51 has raised user error 50000, severity 20. SQL Server is terminating this process.
Msg 50000, Level 20, State 1, Line 1
Oh no a fatal error
Msg 0, Level 20, State 0, Line 0
A severe error occurred on the current command.  The results, if any, should be discarded.

Обратите внимание, что 'ho' не печатается.

ПРЕДОСТЕРЕЖЕНИЯ:

• Это работает только в том случае, если вы вошли в систему как администратор (роль sysadmin), а также не получаете соединения с базой данных.
• Если вы НЕ вошли в систему как admin, сам вызов RAISEERROR() завершится неудачно, и script продолжит выполнение.
• При вызове с sqlcmd.exe будет сообщено код выхода 2745.

Ссылка: http://www.mydatabasesupport.com/forums/ms-sqlserver/174037-sql-server-2000-abort-whole-script.html#post761334

Метод noexec

Другим методом, который работает с операторами GO, является set noexec on. Это приведет к пропуску остальной части script. Он не завершает соединение, но вам нужно снова отключить noexec перед выполнением любых команд.

Пример:

print 'hi'
go

print 'Fatal error, script will not continue!'
set noexec on

print 'ho'
go

-- last line of the script
set noexec off -- Turn execution back on; only needed in SSMS, so as to be able 
               -- to run this script again in the same session.

Ответ 2

Просто используйте RETURN (он будет работать как внутри, так и снаружи хранимой процедуры).

Ответ 3

Если вы можете использовать режим SQLCMD, то заклинание

:on error exit

(ВКЛЮЧАЯ двоеточие) приведет к тому, что RAISERROR фактически остановит script. Например.

:on error exit

IF NOT EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N'[dbo].[SOMETABLE]') AND type in (N'U')) 
    RaisError ('This is not a Valid Instance Database', 15, 10)
GO

print 'Keep Working'

выведет:

Msg 50000, Level 15, State 10, Line 3
This is not a Valid Instance Database
** An error was encountered during execution of batch. Exiting.

и партия остановится. Если режим SQLCMD не включен, вы получите ошибку разбора в двоеточие. К несчастью, он не полностью пуленепробиваемый, как будто script запускается без использования в режиме SQLCMD, SQL Managment Studio брезжит прямо мимо даже ошибок времени синтаксического анализа! Тем не менее, если вы используете их из командной строки, это нормально.

Ответ 4

Я бы не использовал RAISERROR-SQL с IF-инструкциями, которые могут быть использованы для этой цели. Сделайте свою проверку и поиск и установите локальные переменные, затем используйте значение переменных в операторах IF, чтобы сделать вставки условными.

Вам не нужно будет проверять результат переменной каждого теста проверки. Обычно вы можете сделать это только с одной переменной флага, чтобы подтвердить все пройденные условия:

declare @valid bit

set @valid = 1

if -- Condition(s)
begin
  print 'Condition(s) failed.'
  set @valid = 0
end

-- Additional validation with similar structure

-- Final check that validation passed
if @valid = 1
begin
  print 'Validation succeeded.'

  -- Do work
end

Даже если ваша проверка более сложна, вам нужно будет только несколько переменных флага для включения в вашу окончательную проверку.

Ответ 5

вы можете обернуть свой оператор SQL в цикле WHILE и использовать BREAK при необходимости

WHILE 1 = 1
BEGIN
   -- Do work here
   -- If you need to stop execution then use a BREAK


    BREAK; --Make sure to have this break at the end to prevent infinite loop
END

Ответ 6

Я успешно удалил решение noexec on/off с транзакцией для запуска script любым способом.

set noexec off

begin transaction
go

<First batch, do something here>
go
if @@error != 0 set noexec on;

<Second batch, do something here>
go
if @@error != 0 set noexec on;

<... etc>

declare @finished bit;
set @finished = 1;

SET noexec off;

IF @finished = 1
BEGIN
    PRINT 'Committing changes'
    COMMIT TRANSACTION
END
ELSE
BEGIN
    PRINT 'Errors occured. Rolling back changes'
    ROLLBACK TRANSACTION
END

По-видимому, компилятор "понимает" @законченную переменную в IF, даже если произошла ошибка, и выполнение было отключено. Однако значение равно 1, только если выполнение не было отключено. Следовательно, я могу красиво совершить или отменить транзакцию соответственно.

Ответ 7

В SQL 2012+ вы можете использовать THROW.

THROW 51000, 'Stopping execution because validation failed.', 0;
PRINT 'Still Executing'; -- This doesn't execute with THROW

Из MSDN:

Вызывает исключение и передает выполнение блоку CATCH конструкции TRY... CATCH... Если конструкцию TRY... CATCH недоступна, сеанс завершается. Установлены номер строки и процедура, в которой возникает исключение. Уровень серьезности равен 16.

Ответ 8

Является ли это хранимой процедурой? Если это так, я думаю, вы могли бы просто сделать Return, например "Return NULL";

Ответ 9

Дальнейший метод refinig Sglasses, приведенные выше строки заставляют использовать режим SQLCMD и либо вызывают опрокидывание, если не используют режим SQLCMD, либо используют :on error exit для выхода из любой ошибки
CONTEXT_INFO используется для отслеживания состояния.

SET CONTEXT_INFO  0x1 --Just to make sure everything ok
GO 
--treminate the script on any error. (Requires SQLCMD mode)
:on error exit 
--If not in SQLCMD mode the above line will generate an error, so the next line won't hit
SET CONTEXT_INFO 0x2
GO
--make sure to use SQLCMD mode ( :on error needs that)
IF CONTEXT_INFO()<>0x2 
BEGIN
    SELECT CONTEXT_INFO()
    SELECT 'This script must be run in SQLCMD mode! (To enable it go to (Management Studio) Query->SQLCMD mode)\nPlease abort the script!'
    RAISERROR('This script must be run in SQLCMD mode! (To enable it go to (Management Studio) Query->SQLCMD mode)\nPlease abort the script!',16,1) WITH NOWAIT 
    WAITFOR DELAY '02:00'; --wait for the user to read the message, and terminate the script manually
END
GO

----------------------------------------------------------------------------------
----THE ACTUAL SCRIPT BEGINS HERE-------------

Ответ 10

Я бы предположил, что вы уложите соответствующий блок кода в блок catch try. Затем вы можете использовать событие Raiserror с серьезностью 11 для того, чтобы сломать блок catch, если хотите. Если вы просто хотите raiserrors, но продолжайте выполнение в блоке try, используйте меньшую степень серьезности.

Имеют смысл?

Cheers, Джон

[Отредактировано, чтобы включить ссылку BOL]

http://msdn.microsoft.com/en-us/library/ms175976(SQL.90).aspx

Ответ 11

вы можете использовать RAISERROR.

Ответ 12

Ни одно из них не работает с операторами GO. В этом коде, независимо от того, является ли степень тяжести 10 или 11, вы получаете окончательный оператор PRINT.

Тест Script:

-- =================================
PRINT 'Start Test 1 - RAISERROR'

IF 1 = 1 BEGIN
    RAISERROR('Error 1, level 11', 11, 1)
    RETURN
END

IF 1 = 1 BEGIN
    RAISERROR('Error 2, level 11', 11, 1)
    RETURN
END
GO

PRINT 'Test 1 - After GO'
GO

-- =================================
PRINT 'Start Test 2 - Try/Catch'

BEGIN TRY
    SELECT (1 / 0) AS CauseError
END TRY
BEGIN CATCH
    SELECT ERROR_MESSAGE() AS ErrorMessage
    RAISERROR('Error in TRY, level 11', 11, 1)
    RETURN
END CATCH
GO

PRINT 'Test 2 - After GO'
GO

Результаты:

Start Test 1 - RAISERROR
Msg 50000, Level 11, State 1, Line 5
Error 1, level 11
Test 1 - After GO
Start Test 2 - Try/Catch
 CauseError
-----------

ErrorMessage
--------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
Divide by zero error encountered.

Msg 50000, Level 11, State 1, Line 10
Error in TRY, level 11
Test 2 - After GO

Единственный способ сделать эту работу - написать инструкции script без GO. Иногда это легко. Иногда это довольно сложно. (Используйте что-то вроде IF @error <> 0 BEGIN ....)

Ответ 13

Это было мое решение:

...

BEGIN
    raiserror('Invalid database', 15, 10)
    rollback transaction
    return
END

Ответ 14

Вы можете изменить поток выполнения с помощью GOTO:

IF @ValidationResult = 0
BEGIN
    PRINT 'Validation fault.'
    GOTO EndScript
END

/* our code */

EndScript:

Ответ 15

Вы можете использовать инструкцию GOTO. Попробуй это. Это полезно для вас.

WHILE(@N <= @Count)
BEGIN
    GOTO FinalStateMent;
END

FinalStatement:
     Select @CoumnName from TableName

Ответ 16

Я использую RETURN здесь все время, работает в script или SP

Убедитесь, что вы выполнили транзакцию ROLLBACK, если вы находитесь в одном, иначе RETURN немедленно приведет к открытой незафиксированной транзакции.

Ответ 17

спасибо для ответа!

raiserror() работает нормально, но вы не должны забывать инструкцию return, иначе script продолжается без ошибок! (hense raiserror не является "броском";) и, конечно же, делает откат, если это необходимо!

raiserror() приятно сообщить человеку, который выполняет script, что что-то пошло не так.

Ответ 18

Если вы просто выполняете script в Studio Management и хотите прекратить выполнение или откат транзакции (если используется) при первой ошибке, то лучшим способом, который я считаю, является использование блока catch try (SQL 2005). Это хорошо работает в студии управления, если вы выполняете файл script. Сохраненный proc всегда может использовать это также.