Изменение поведения Emacs Forward-Word

Как говорится в названии, как изменить поведение функции forward-word emacs? Например, предположим, что [] - это курсор. Тогда:

my $abs_target_path[]= abs_path($target);
<M-f>
my $abs_target_path = abs[_]path($target);

Я знаю, что могу просто использовать M-f M-b, но, насколько мне известно, это не обязательно, и я бы хотел его изменить. В частности, я хочу две вещи:

Когда я нажимаю M-f, я хочу перейти к первому символу следующего слова независимо от того, находится ли точка внутри слова, внутри группы пробелов или где-то еще.
Настройте слова-символы в режиме по-разному. В конце концов, перемещение в режиме CPERl отличается от, скажем, режима TeX.

Итак, в приведенном выше примере элемент 1 должен был бы перемещать курсор в "a" (и точку слева) после удара M-f. Пункт 2 позволил бы мне определить символы подчеркивания и сигилы в качестве символов слов.

Ответы

Ответ 1

Try:

(require 'misc)

Затем используйте M-x forward-to-word и посмотрите, делает ли он то, что вы хотите. Затем вы можете восстановить M-f и т.д.

Чтобы сделать _ не разделитель слов (т.е. сделать его составной частью слова) для режима C и С++, вы должны сделать это:

(modify-syntax-entry ?_ "w" c-mode-syntax-table)
(modify-syntax-entry ?_ "w" c++-mode-syntax-table)

Подробнее о синтаксических таблицах читайте эту страницу вики. Таблицы синтаксиса обычно называются как tex-mode-syntax-table и cperl-mode-syntax-table.

Ответ 2

См. также функцию forward-same-syntax. вероятно, это вам нужно, чтобы основываться на них.

Ответ 3

У меня есть второстепенный режим, который изменяет текстовые команды для работы с изменениями синтаксиса (а также CamelCaseSubwords). Это может быть немного слишком мелкозернистым для некоторых вкусов, но я считаю, что я в основном когда-либо использовал одно движение символов.

https://bitbucket.org/jpkotta/syntax-subword

Ответ 4

Я хотел скопировать поведение моего предыдущего редактора, поэтому ему нужно было немного больше контроля, поэтому здесь я беру его на себя:

(defun my-syntax-class (char)
  "Return ?s, ?w or ?p depending or whether CHAR is a white-space, word or punctuation character."
  (pcase (char-syntax char)
      (`?\s ?s)
      (`?w ?w)
      (`?_ ?w)
      (_ ?p)))

(defun my-forward-word (&optional arg)
  "Move point forward a word (simulate behavior of Far Manager editor).
With prefix argument ARG, do it ARG times if positive, or move backwards ARG times if negative."
  (interactive "^p")
  (or arg (setq arg 1))
  (let* ((backward (< arg 0))
         (count (abs arg))
         (char-next
          (if backward 'char-before 'char-after))
         (skip-syntax
          (if backward 'skip-syntax-backward 'skip-syntax-forward))
         (skip-char
          (if backward 'backward-char 'forward-char))
         prev-char next-char)
    (while (> count 0)
      (setq next-char (funcall char-next))
      (loop
       (if (or                          ; skip one char at a time for whitespace,
            (eql next-char ?\n)         ; in order to stop on newlines
            (eql (char-syntax next-char) ?\s))
           (funcall skip-char)
         (funcall skip-syntax (char-to-string (char-syntax next-char))))
       (setq prev-char next-char)
       (setq next-char (funcall char-next))
       ;; (message (format "Prev: %c %c %c Next: %c %c %c"
       ;;                   prev-char (char-syntax prev-char) (my-syntax-class prev-char)
       ;;                   next-char (char-syntax next-char) (my-syntax-class next-char)))
       (when
           (or
            (eql prev-char ?\n)         ; stop on newlines
            (eql next-char ?\n)
            (and                        ; stop on word -> punctuation
             (eql (my-syntax-class prev-char) ?w)
             (eql (my-syntax-class next-char) ?p))
            (and                        ; stop on word -> whitespace
             this-command-keys-shift-translated ; when selecting
             (eql (my-syntax-class prev-char) ?w)
             (eql (my-syntax-class next-char) ?s))
            (and                        ; stop on whitespace -> non-whitespace
             (not backward)             ; when going forward
             (not this-command-keys-shift-translated) ; and not selecting
             (eql (my-syntax-class prev-char) ?s)
             (not (eql (my-syntax-class next-char) ?s)))
            (and                        ; stop on non-whitespace -> whitespace
             backward                   ; when going backward
             (not this-command-keys-shift-translated) ; and not selecting
             (not (eql (my-syntax-class prev-char) ?s))
             (eql (my-syntax-class next-char) ?s))
            )
         (return))
       )
      (setq count (1- count)))))

(defun delete-word (&optional arg)
  "Delete characters forward until encountering the end of a word.
With argument ARG, do this that many times."
  (interactive "p")
  (delete-region (point) (progn (my-forward-word arg) (point))))

(defun backward-delete-word (arg)
  "Delete characters backward until encountering the beginning of a word.
With argument ARG, do this that many times."
  (interactive "p")
  (delete-word (- arg)))

(defun my-backward-word (&optional arg)
  (interactive "^p")
  (or arg (setq arg 1))
  (my-forward-word (- arg)))

(global-set-key (kbd "C-<left>") 'my-backward-word)
(global-set-key (kbd "C-<right>") 'my-forward-word)
(global-set-key (kbd "C-<delete>") 'delete-word)
(global-set-key (kbd "C-<backspace>") 'backward-delete-word)