Как нарисовать диаграмму классического состояния с помощью Mathematica?

Ответ 1

Вы можете сделать что-то подобное, используя VertexRenderingFunction.

GraphPlot[{{A -> C, "go"}, {C -> B, "gone"}, {C -> D, "went"}, {C -> C, "loop"}}, 
 DirectedEdges -> True, 
 VertexRenderingFunction -> ({{White, Disk[#, 0.15]}, 
     AbsoluteThickness[2], Circle[#, 0.15], 
     If[MatchQ[#2, A | B], Circle[#, 0.12], {}], Text[#2, #]} &)]

Метод Обновлено февраль 2015

Чтобы сохранить возможность интерактивного преобразования графика с помощью инструментов рисования (двойной щелчок), необходимо сохранить вершинную графику внутри GraphicsComplex, указав вместо координат. Я считаю, что это можно сделать с помощью VertexRenderingFunction с использованием переменной с добавкой, но кажется, что это возможно более надежно, чтобы сделать это с последующей обработкой. Это работает в версиях 7 и 10 Mathematica, предположительно 8 и 9:

GraphPlot[
  {{A -> C, "go"}, {C -> B, "gone"}, {C -> D, "went"}, {C -> C, "loop"}},
  DirectedEdges -> True
] /.
 Tooltip[Point[n_Integer], label_] :>
   {{White, Disk[n, 0.15]},
    Black, AbsoluteThickness[2], Circle[n, 0.15], 
    If[MatchQ[label, A | B], Circle[n, 0.12], {}], Text[label, n]}

Ответ 2

Нет необходимости в интерактивном размещении, чтобы получить ваши вершины в нужном месте, как mr.Wizard предлагает в его ответ. Вы можете использовать VertexCoordinateRules для этого:

GraphPlot[{{A -> C, "go"}, {C -> B, "gone"}, {C -> D, "went"}, {C -> C, "loop"}}, 
    DirectedEdges -> True, 
    VertexRenderingFunction -> 
          ({{White, Disk[#, 0.15]}, AbsoluteThickness[2], Circle[#, 0.15], 
           If[MatchQ[#2, A | B], Circle[#, 0.12], {}], Text[#2, #]} &),
    VertexCoordinateRules -> 
          {A -> {0, 0}, C -> {0.75, 0},B -> {1.5, 0.25}, D -> {1.5, -0.25}}
]