Как устранить зависимость подтипа?

Ответ 1

create table so1table (
    id number,
    data varchar(20)
);


create or replace type parent_type as object
(
    v_number number,
    --Prefix probably belongs with a list, not an individual value.
    --For simplicity, I'm not adding another level to the objects.
    v_prefix varchar2(10)
) not instantiable not final;
/

create or replace type parentlist as table of parent_type;
/


create or replace type foo_type under parent_type
(
    constructor function foo_type(v_number number) return self as result
);
/

--The data must be stored as a NUMBER, since ADTs don't support
--PL/SQL specific data types.  The type safety is enforced by the
--conversion in the constructor.
create or replace type body foo_type is
    constructor function foo_type(v_number number) return self as result
    as
        subtype foo_subtype is pls_integer range 0 .. 4 not null;
        new_number foo_subtype := v_number;
    begin
        self.v_number := new_number;
        self.v_prefix := 'foos:';
        return;
    end;
end;
/

create or replace type foolist as table of foo_type;
/


create or replace type bar_type under parent_type
(
    constructor function bar_type(v_number number) return self as result
);
/

create or replace type body bar_type is
    constructor function bar_type(v_number number) return self as result
    as
        subtype bar_subtype is pls_integer range 5 .. 10 not null;
        new_number bar_subtype := v_number;
    begin
        self.v_number := new_number;
        self.v_prefix := 'bars:';
        return;
    end;
end;
/

create or replace type barlist as table of bar_type;
/



create or replace package so1 as
    procedure set(id_ in number, list in parentlist);
end;
/

create or replace package body so1 as

    function to_str(list in parentlist) return varchar2 as
        v_value VARCHAR2(32767);
    begin
        for i in list.first .. list.last loop
            if i = 1 then
                v_value := list(i).v_prefix;
            end if;
            v_value := v_value || ' ' || list(i).v_number;
        end loop;

        return v_value;
    end to_str;

    procedure set(id_ in number, list in parentlist) as
        values_ constant varchar2(32767) := to_str(list);
    begin
        insert into so1table (id, data) values (id_, values_);
    end set;
end so1;
/


begin
    --You probably don't want to mix foos and bars, but it is allowed. 
    so1.set(1, parentlist(foo_type(0), foo_type(3)));
    so1.set(2, parentlist(bar_type(5), bar_type(7), bar_type(10)));

    --These would generate "ORA-06502: PL/SQL: numeric or value error"
    --so1.set(1, parentlist(foo_type(5)));
    --so1.set(1, parentlist(bar_type(4)));

end;
/

select * from so1table;

Ответ 2

Это может не ответить на ваш вопрос, но почему бы не поместить данные в обычную таблицу, а затем объединить их, как вы показываете, с помощью функции агрегации wm_concat?

то есть.,

> select * from myTable;

ID  Category  Value
--- --------- ------
1   foo       0
2   foo       3
3   bar       5
4   bar       7
5   bar       10

> select   Category||'s: '||replace(wm_concat(Value),',',' ') Data
  from     myTable
  group by Category;

Data
-------------
bars: 5 7 10
foos: 0 3

wm_concat не зависит от типа, поэтому вам не нужно перегружать ваши функции. Кроме того, существуют другие методы которые можно использовать; метод аналитической функции выглядит неплохо, но мне не нужно тестировать 11g!

( Изменить. В противном случае, я думаю, вы можете достичь того, что вы ищете, используя объектную модель Oracle, в частности полиморфизм. Однако это выходит за рамки меня... поэтому, возможно, кто-то еще может перезвонить.)

Ответ 3

Следующий ответ на самом деле заключается в том, как вы это сделаете в postgresql (и plpgsql), и я также не знаю о подтипах oracle, но я предполагаю, что они достаточно похожи, что, по крайней мере, это приведет вас к вашему ответ.

create function add (anynonarray,anynonarray) returning anynonarray
as 'begin return $1 + $2; end';

Я знаю, что я испортил синтаксис, но он должен показать, что я хочу показать с ним, в любом случае.

Идея заключается в том, что она заменит "anynonarray" или любую альтернативу с типом параметра вызова. Одно из ограничений заключается в том, что все "anynonarray" в приведенном выше примере будут иметь один и тот же тип.

Документация называлась полиморфизмом.