Условие IF EXISTS не работает с PLSQL

Я пытаюсь напечатать ТЕКСТ, когда условие TRUE. Код выбора отлично работает. Он показывает значение 403, когда я запускаю только код выбора. Но я должен напечатать некоторый текст, когда условие существует. В чем проблема со следующим кодом.

Ответы

Ответ 1

IF EXISTS() является семантически неправильным. EXISTS условие может использоваться только внутри оператора SQL. Поэтому вы можете переписать свой блок pl/sql следующим образом:

declare
  l_exst number(1);
begin
  select case 
           when exists(select ce.s_regno 
                         from courseoffering co
                         join co_enrolment ce
                           on ce.co_id = co.co_id
                        where ce.s_regno=403 
                          and ce.coe_completionstatus = 'C' 
                          and ce.c_id = 803
                          and rownum = 1
                        )
           then 1
           else 0
         end  into l_exst
  from dual;

  if l_exst = 1 
  then
    DBMS_OUTPUT.put_line('YES YOU CAN');
  else
    DBMS_OUTPUT.put_line('YOU CANNOT'); 
  end if;
end;

Или вы можете просто использовать функцию count, чтобы определить количество строк, возвращаемых запросом, и предикат rownum=1 - вам нужно только знать, существует ли запись:

declare
  l_exst number;
begin
   select count(*) 
     into l_exst
     from courseoffering co
          join co_enrolment ce
            on ce.co_id = co.co_id
    where ce.s_regno=403 
      and ce.coe_completionstatus = 'C' 
      and ce.c_id = 803
      and rownum = 1;

  if l_exst = 0
  then
    DBMS_OUTPUT.put_line('YOU CANNOT');
  else
    DBMS_OUTPUT.put_line('YES YOU CAN');
  end if;
end;

Ответ 2

К сожалению, PL/SQL не имеет оператора IF EXISTS, такого как SQL Server. Но вы можете сделать что-то вроде этого:

begin
  for x in ( select count(*) cnt
               from dual 
              where exists (
                select 1 from courseoffering co
                  join co_enrolment ce on ce.co_id = co.co_id
                 where ce.s_regno = 403 
                   and ce.coe_completionstatus = 'C' 
                   and co.c_id = 803 ) )
  loop
        if ( x.cnt = 1 ) 
        then
           dbms_output.put_line('exists');
        else 
           dbms_output.put_line('does not exist');
        end if;
  end loop;
end;
/