Воспроизведение wav файла с помощью Haskell

Есть ли простой, прямой способ воспроизвести WAV файл из Haskell с помощью некоторой библиотеки и, возможно, так, что я воспроизвожу много звуков одновременно?

Я знаю OpenAL, но я не пишу какую-то передовую программу синтеза аудио, я просто хочу воспроизвести некоторые звуки для маленькой игры. В идеале API может быть чем-то вроде:

readWavFile :: FilePath -> IO Wave
playWave :: Wave -> IO ()
playWaveNonBlocking :: Wave -> IO ()

Я близок к тому, чтобы просто запустить mplayer или что-то в этом роде. Или пытайтесь котировать wav прямо в/dev/snd/или somesuch.

Ответы

Ответ 1

Вот как воспроизводить несколько звуков на нескольких каналах одновременно с SDL. Я думаю, что это отвечает критериям вопроса. WAV файлы, простые, Haskell, несколько каналов.

import Control.Monad
import Control.Monad.Fix
import Graphics.UI.SDL as SDL
import Graphics.UI.SDL.Mixer as Mix

main = do
  SDL.init [SDL.InitAudio]
  result <- openAudio audioRate audioFormat audioChannels audioBuffers
  classicJungle <- Mix.loadWAV "/home/chris/Samples/ClassicJungle/A4.wav"
  realTech      <- Mix.loadWAV "/home/chris/Samples/RealTech/A4.wav"
  ch1 <- Mix.playChannel anyChannel classicJungle 0
  SDL.delay 1000
  ch2 <- Mix.playChannel anyChannel realTech 0
  fix $ \loop -> do
    SDL.delay 50
    stillPlaying <- numChannelsPlaying
    when (stillPlaying /= 0) loop
  Mix.closeAudio
  SDL.quit

  where audioRate     = 22050
        audioFormat   = Mix.AudioS16LSB
        audioChannels = 2
        audioBuffers  = 4096
        anyChannel    = (-1)

Ответ 2

Я понимаю, что на самом деле это не удобный способ сделать это, но у меня был тестовый код, поэтому...

{-# LANGUAGE NoImplicitPrelude #-}
module Wav (main) where

import Fay.W3C.Events
import Fay.W3C.Html5

import Language.Fay.FFI
import Language.Fay.Prelude

main :: Fay ()
main = addWindowEventListener "load" run

run :: Event -> Fay Bool
run _ = do
    aud <- mkAudio
    setSrc aud "test.wav"
    play aud
    return False


mkAudio :: Fay HTMLAudioElement
mkAudio = ffi "new Audio()"

addWindowEventListener :: String -> (Event -> Fay Bool) -> Fay ()
addWindowEventListener = ffi "window['addEventListener'](%1,%2,false)"

Там вы идете - играя WAV файл в Haskell благодаря мощности HTML5! Все, что вам нужно сделать, это запустить веб-браузер вместо mplayer.: D

Ответ 3

используя OpenAL через ALUT:

import Control.Monad
import Sound.ALUT

playSound :: IO ()
playSound =
  withProgNameAndArgs runALUTUsingCurrentContext $ \_ _ ->
  do
    (Just device) <- openDevice Nothing
    (Just context) <- createContext device []
    currentContext $= Just context
    buffer1 <- createBuffer $ Sine 440 0 1
    buffer2 <- createBuffer HelloWorld
    [source] <- genObjectNames 1
    queueBuffers source [buffer1,buffer2]
    play [source]
    sleep 4
    closeDevice device
    return ()

main = playSound

для загрузки wav файла:

buffer3 <- createBuffer $ File "/path/to/file.wav"

кредит переходит к Chris Double: http://bluishcoder.co.nz/articles/haskell/openal.html