В чем преимущество core.async в clojurescript?

Все говорят о том, насколько велика core.async и как она улучшит обработку событий в clojurescript. Я слежу за учебником ClojureScript 101, и я не вижу никакого явного преимущества из этих примеров кода. Что мне не хватает?

Почему здесь лучше использовать core.async?

(defn listen [el type]
  (let [out (chan)]
    (events/listen el type
      (fn [e] (put! out e)))
    out))

(defn dosomethingasync
  [e]
  (js/console.log "async: " e))

(let [clicks (listen (dom/getElement "search1") "click")]
  (go (while true (dosomethingasync (<! clicks)))))

против.

(defn dosomethingcallback
   [e]
   (js/console.log "callback: " e))

(events/listen (dom/getElement "search2") "click" dosomethingcallback)

Ответы

Ответ 1

Отличный вопрос!

Я думаю, что ваш первый шаг к пониманию преимущества будет Тимоти Болдридж Видео

И ниже моей попытки:

Я думаю, что различия будут устранены, если мы немного изменим ваш код.

Во-первых, пытаясь выделить предложение "Приходит время во всех хороших программах, когда компоненты или подсистемы должны перестать общаться напрямую друг с другом", извлеченные из презентации core.async, размещенной на clojure блог. Я думаю, что мы можем отделить канал входных событий от let fn:

(def clicks (listen (dom/getElement "search1") "click"))

(go
  (while true
    (dosomethingasync (<! clicks))))

(put! clicks "this channel can be written from differents parts of your code")

Во-вторых, с core.async мы можем писать асинхронные вызовы, поскольку мы будем писать синхронные вызовы (последовательный код). Пример этой ситуации требует более одного канала:

(def clicks (listen (dom/getElement "search1") "click"))

(def keys-pressed (listen (dom/getElement "search1") "keypress"))

(def to-out (chan))

(go
  (while true
    (let [click-recieved (<! clicks)]
      (dosomethingasync click-recieved)
      (>! to-out "click recieved!")
      (let [other-input-waited (<! keys-pressed)]
        (dosomethingwithkey other-input-waited)
        (>! to-out "keypressed recieved!")
        )
      )
    ))

И, наконец, я думаю, что вы неправильно используете значение функции обратного вызова. Когда мы говорим о функции обратного вызова, я думаю, что мы имеем в виду функцию, которая помимо собственных параметров получает функцию "обратный вызов". В конце выполнения функции мы вызываем функцию обратного вызова, чтобы вернуть поток выполнения в исходную точку. Изменение функции "обратного вызова" происходит следующим образом:

(defn dosomethingcallback
   [e call-back-fn]
   (js/console.log "callback: " e)
   (call-back-fn))

И если мы попытаемся выпустить что-то похожее на то же поведение, достигнутое с предыдущим примером core.async кода:

(defn do-key
   [call-back-fn e]
   (.log js/console "before  callback key" )
   (call-back-fn e))

(defn do-click
   [call-back-fn e]
   (.log js/console "before callback click")
   (call-back-fn e))

(defn key-callback-fn [e]
  (.log js/console (str "doing some work with this key: " e))
  )

(defn click-callback-fn [e]
  (.log js/console (str "doing some work with this click" e))
  (events/listen (dom/getElement "search2") "keypress" (partial do-key key-callback-fn)))


  (events/listen (dom/getElement "search2") "click" (partial do-click click-callback-fn))