CheckException принимает только 0-параметрические методы; как я могу проверить, что другие методы бросают исключения?

Мне интересно, что лучше всего проверять на исключения в dunit. Я не очень хорошо знаком с указателями методов в Delphi. Есть ли возможность связать аргументы с указателем метода, чтобы он мог быть вызван без аргументов. В настоящий момент я всегда пишу дополнительный метод, который делает это "привязка" вручную. Это будет раздражать, если у SUT много методов метания.

// What i did before i knew abput CheckExcepion
procedure MyTest.MyMethod_BadInput_Throws;
var
    res: Boolean;
begin
    res := false;
    try
        sut.MyMethod('this is bad');
    except
        on e : MyExpectedException do:
            res := true;
    end;
    CheckTrue(res);
end;

// What i do now
procedure MyTest.MyMethodWithBadInput;
begin
    sut.MyMethod('this is bad');
end;

procedure MyTest.MyMethod_BadInput_Throws;
begin
    CheckException(MyMethodWithBadInput, MyExpectedException);
end;

// this would be nice
procedure MyTest.MyMethod_BadInput_Throws;
begin
    CheckException(
        BindArguments(sut.MyMethod, 'this is bad'),  // <-- how to do this
        MyExpectedException);
end;

Ответы

Ответ 1

Вы можете использовать StartExpectingException, чтобы окружить ваш вызов методом).

StartExpectingException(MyException);
MyMethod(MyParam);
StopExpectingException();

Ответ 2

Я не знаю, поддерживает ли DUnit еще это, но это идеальный вариант использования анонимных методов, которые были представлены в Delphi 2010. Если DUnit не поддерживает его, вы можете легко изменить исходный код самостоятельно.

Ответ 3

Как уже отмечалось, это отличное место для анонимных методов.

Вот как я это делаю. Я "заимствовал" это у Алекса Чобану:

procedure TestTMyClass.CheckException(aExceptionType: TClassOfException; aCode: TTestCode; const aMessage: String);
var
  WasException: Boolean;
begin
  WasException := False;
  try
    aCode;
  except
    on E: Exception do
    begin
      if E is aExceptionType then
      begin
        WasException := True;
      end;
    end;
  end;
  Check(WasException, aMessage);
end;

Затем назовите его чем-то вроде:

CheckException(ETestingException, 
             procedure begin FMyClass.RaiseTestingException end,      
             'The ETestingException exception didn''t get raised.  That is impossible!');

Ответ 4

Использовать StartExpectingException() не лучший способ, если вы хотите протестировать более одного случая исключения. Чтобы проверить все возможные случаи в моей тестовой процедуре, вместе с исключениями я использую этот алгоритм:

uses
  Dialogs;
procedure MyTest.MyMethod_Test;
begin
  // Test for Exceptions
  try
    MyMethod(MyParam1CreatingException1);
    ShowMessage('Error! There should have been exception: Exxx here!');
    Check(false);
  except on E: Exception do Check(E is  ExceptionType1); end; // This exception is OK
  try
    MyMethod(MyParam2CreatingException2);
    ShowMessage('Error! There should have been exception: Exxx here!');
    Check(false);
  except on E: Exception do Check(E is  ExceptionType2); end; // This exception is OK
  // ... test other exceptions ...

  // Test other parameters
  CheckEquals('result1', MyMethod(MyParam1));
  CheckEquals('result2', MyMethod(MyParam2));
  // ... other tests ...
end;

Причина использования ShowMessage('Error! There should be exception: Exxx here!'); вместо предоставленного метода Check(false, 'There should have been an EListError.'); заключается в том, что в моем случае (Delphi6) Check(boolean, 'Message') не работает - он не отображает сообщение в том случае, если Check находится внутри try...except блок (не знаю почему).

Ответ 5

Это рабочая и улучшенная версия ответа Ника Ходжеса, подклассы DUnit TestFramework.TTestCase:

uses
  TestFramework, System.SysUtils;
type
  TTestCode = reference to procedure;

  TTestCasePlus = class(TestFramework.TTestCase)
    procedure CheckException(
      ExceptionType: TClass; Code: TTestCode; const Message: String = '');
  end;

implementation

procedure TTestCasePlus.CheckException(
  ExceptionType: TClass; Code: TTestCode; const Message: String = '');
{ Check whether some code raises a specific exception type.

Adapted from http://stackoverflow.com/a/5615560/797744

Example:

  Self.CheckException(EConvertError,
                      procedure begin UnformatTimestamp('invalidstr') end);

@param ExceptionType: The exception class which we check if it was raised.
@param Code: Code in the form of an anonymous method that should raise the
  exception.
@param Message: Output message on check failure. }
var
  WasRaised: Boolean;
begin
  WasRaised := False;
  try
    Code;
  except
    on E: Exception do
      if E is ExceptionType then
        WasRaised := True;
  end;
  Check(WasRaised, Message);
end;

Хороший бонус к этому методу проверки того, что исключение было поднято над Start/StopExpectingException(), заключается в том, что вы можете запустить testrunner в сборке отладки, и он не будет беспокоить вас "Исключением было поднято. Break? Continue?" каждый раз, когда возникает исключение, даже если оно было обработано.