Groovy критерии фильтрации на findAll в списке

Я пытаюсь создать динамические фильтры, используя findAll в списке. У меня есть переменная, которая должна быть включена в фильтр, только если не null.

 @Test
    void testSample(){
        def list = [ new Employee(age:22, isManager:false), 
                     new Employee(age:23, isManager:true), 
                     new Employee(age:22, isManager:true) ] as Set

        def var = 22;
        String query1 = "it.age == var && it.isManager == true "
        String query2 = "it.isManager == true"

        println list
        println list.findAll { var ? query1 : query2 } // Should give 1 record age = 22 and manager
        var = null;
        println list.findAll { var ? query1 : query2 } // should give 2 records-only manager

    }

Оба они дают все записи. В любом случае, я могу достичь этого одним условием без необходимости писать muiltiple-запросы?

Посмотрите немного ниже (это не работает)

println list.findAll{
                if(var) it.age == var &&
                it.isManager == true
        }

Ответы

Ответ 1

Попробуйте с закрытием, а не строками, описывающими, что вы хотите сделать:

def list = [ new Employee(age:22, isManager:false), 
             new Employee(age:23, isManager:true), 
             new Employee(age:22, isManager:true) ] as Set

def var = 22;
Closure query1 = { it.age == var && it.isManager == true }
Closure query2 = { it.isManager == true }

println list
println list.findAll( var ? query1 : query2 ) // Should give 1 record age = 22 and manager
var = null;
println list.findAll( var ? query1 : query2 ) // should give 2 records-only manager

Изменить

Вы имеете в виду:

println list.findAll{ ( var ? it.age == var : true ) && it.isManager == true }

Или лучше:

println list.findAll{ ( var != null ? it.age == var : true ) && it.isManager == true }