Что такое эквивалент "доходности возврата" на языке программирования D?

Вот простой генератор в С#.

    IEnumerable<int> Foo()
    {
        int a = 1, b = 1;
        while(true)
        {
            yield return b;
            int temp = a + b;
            a = b;
            b = temp;
        }
    }

Как написать аналогичный генератор в Digital Mars D?

(Вопрос о инструкции return return)

Спасибо!

Update. Это интересно. Поскольку я просто генерирую математическую последовательность, использование recurrence может быть хорошим вариантом.

auto fib = recurrence!("a[n-1] + a[n-2]")(1, 1);

foreach (e; take(fib, 10)) // <- prints first ten numbers from the sequence
{ 
    writeln(e); 
}

Ответы

Ответ 1

Нет точного эквивалента в D. Вот некоторые приблизительные эквиваленты:

Использование внутренней итерации стиля opApply. Это не позволяет выполнять итерацию по двум итераторам в режиме блокировки:

struct Foo {
    int opApply(int delegate(ref int) dg) {
        int a = 1, b = 1;
        int result;
        while(true) {
            result = dg(b);
            if(result) break;
            int temp = a + b;
            a = b;
            b = temp;
        }

        return result;
    }
}

void main() {
    // Show usage:
    Foo foo;
    foreach(elem; foo) {
        // Do stuff.
    }
}

Использовать диапазоны. В некоторых случаях их немного сложнее записать, но они очень эффективны и позволяют выполнять итерацию блокировки. Это также можно повторить с помощью цикла foreach, точно так же, как версия opApply:

struct Foo {
    int a = 1, b = 1;

    int front() @property {
        return b;
    }

    void popFront() {
        int temp = a + b;
        a = b;
        b = temp;
    }

    // This range is infinite, i.e. never empty.
    enum bool empty = false;

    typeof(this) save() @property { return this; }
}

Если вы действительно нуждаетесь в стиле coroutine, вы можете комбинировать диапазоны и opApply вместе, используя core.thread.Fiber, но вы, вероятно, обнаружите, что либо диапазоны, либо opApply делает то, что вам нужно почти все время.

Ответ 2

Смотрите здесь; пример выдержки ниже:

module main;

import std.stdio;
import generators;

void genSquares(out int result, int from, int to)
{
    foreach (x; from .. to + 1)
        yield!result(x * x);
}

void main(string[] argv)
{
    foreach (sqr; generator(&genSquares, 10, 20))
        writeln(sqr);
}

Ответ 3

Теперь модуль std.concurrency имеет класс Generator, который делает это еще проще (и вам не нужна сторонняя библиотека).

Класс - это диапазон ввода, поэтому его можно использовать для циклов и всех стандартных функций std.range/std.algorithm.

import std.stdio;
import std.range;
import std.algorithm;
import std.concurrency : Generator, yield;

void main(string[] args) {
    auto gen = new Generator!int({
        foreach(i; 1..10)
            yield(i);
    });

    gen
        .map!(x => x*2)
        .each!writeln
    ;
}