Использование bootstrap-модального представления Backbone.js

Я пытаюсь создать представление Backbone.js, основанное на загрузочном модуле Twitter, в котором используется автоматическое делегирование событий Backbone с помощью атрибута events представления.

К сожалению, bootstrap-modal, кажется, прерывает делегирование событий в базовом блоке, поскольку он клонирует HTML-представление перед отображением модальности:

that.$element
      .appendTo(document.body)
      .show()

Мой взгляд:

App.Views.ProjectsNav ||= {}

class App.Views.ProjectsNav.NewProjectView extends Backbone.View
  events: {
    'click .save': 'save',
    'shown':       'shown'
  }

  save: (e) ->
    ...
    false

  shown: () ->
    App.Helpers.Forms.setFocus($(@el), true)
    false

  render: () ->
    $(@el).html(ich.nav_edit_project_template(@model.toJSON()))
    @$('.modal').modal({'show': true, 'keyboard': true, 'backdrop': true})
    @

Соответствующий (Mustache) HTML-шаблон:

<div class="modal hide" style="display: none; ">
  <div class="modal-header">
    <a href="#" class="close">×</a>
    <h3>New Project</h3>
  </div>
  <div class="modal-body form-stacked">
    <label for="name">Name</label> <input type="text" name="name" value="{{name}}"/><input type="hidden" name="lock_version" value="{{lock_version}}"/>
  </div>
  <div class="modal-footer">
    <a href="javascript:void(0)" class="save btn primary">Create</a>
    <a href="javascript:void(0)" class="cancel btn secondary">Cancel</a>
  </div>
</div>

Ни один save и shown не вызываются при срабатывании соответствующих событий.

Любые идеи?

Ответы

Ответ 1

Хорошо, поэтому решение было довольно простым:

App.Views.ProjectsNav ||= {}

class App.Views.ProjectsNav.NewProjectView extends Backbone.View
  tagName: 'div'

  events: {
    'click .save':   'save',
    'click .cancel': 'hide',
    'hidden':        'hidden',
    'shown':         'shown'
  }

  initialize: (options) ->
    super(options)
    @collection = options.collection

  hide: () ->
    @el.modal(true).hide()
    false

  save: (e) ->
    ...
    @model.save(attrs, {
      success: (project) =>
        @model = project
        @collection.add(@model)
        @hide()
      error: (project) =>
        alert('Something went wrong: ' + project)
      }
    )
    false

  render: () ->
    @el = ich.nav_edit_project_template(@model.toJSON()).modal('keyboard': true, 'backdrop': true)
    @delegateEvents()
    @el.modal('show': true)
    @

  hidden: () ->
    @remove()
    false

  shown: () ->
    App.Helpers.Forms.setFocus($(@el), true)
    false

Подводя итоги, ключ состоит в том, чтобы разделить показ модального на два шага, давая возможность назначить @el и вызвать @delegateEvents() после этого, прежде чем сделать его видимым. @el.modal(true) может использоваться для доступа к объекту, управляющему модальным, например, программным путем скрывать его.