Скрытие приложения Excel во время выполнения

Ответ 1

Я смог воспроизвести вашу проблему. Сначала я протестировал скрытие приложения без загрузки файла PERSONAL.xlsb, и оно работало нормально. Затем я загрузил PERSONAL.xlsb и получил то же поведение, что и вы: дополнительная оболочка Excel стала видимой после Application.Visible = True.

Я не уверен, почему вы иногда получаете две дополнительные оболочки, но, возможно, у вас загружен еще один аддин (.xlam)? Вы могли бы попытаться добавить некоторый код, чтобы сначала выгрузить все надстройки, но у меня есть альтернативное решение: почему бы просто не запустить новый экземпляр Excel, загрузить в него вашу книгу макросов и запустить макрос? Например, если ваша рабочая книга называется C:\Book1.xlsb, а макрос в ней - "MyMacro", создайте вторую рабочую книгу с кодом, который запустит Book1. Как это:

Sub LaunchIt()

    Dim xlApp As Excel.Application
    Dim wb As Workbook

    Set xlApp = New Excel.Application

    With xlApp
        Set wb = .Workbooks.Open("C:\Book1.xlsb")
        .Run "'" & wb.Name & "'!MyMacro"
        wb.Close SaveChanges:=False
        .Quit
    End With

End Sub

Новый экземпляр Excel не отображается по умолчанию, поэтому нет необходимости настраивать видимость. Я проверил это, и это сработало для меня.

Ответ 2

Я также могу воспроизвести это поведение, но установка Visible-свойства окна на false решит его.

Private Sub Workbook_Open()
Dim x As Workbook
With Application
    .Visible = False
    .Wait (Now + TimeValue("0:00:05"))
    .Visible = True
        For Each x In .Workbooks
            If x.Name = "PERSONAL.XLSB" Then 'maybe also other addins(?)
                x.Windows(1).Visible = True
                x.Windows(1).Visible = False 'toggle
                x.Saved = True 'for not getting save-alerts
            End If
        Next
End With
End Sub

Редактировать:

или изменить для каждого цикла:

    For Each myAdd In AddIns
        myAdd.Installed = False
    Next myAdd

работает на моей стороне (но: при закрытии вы должны установить предыдущие установленные дополнения обратно в True)

Ответ 3

Если я правильно понял вас, вы хотите сделать невидимым для пользователя во время конкретной операции, а затем снова появиться после завершения этой операции?

Если это так, взгляните на код, который я использовал для того, чтобы мое приложение действительно начиналось с Excel невидимым только с определенной формой:

Когда пользователь закончит и хочет выйти из приложения, он нажимает кнопку команды cmdQuit. Приведенный ниже код заставит Excel снова появиться: Код, вставленный ниже. Надеюсь, это поможет вам найти решение для вашей ситуации.

Заметки:
1. В идеале мы хотели бы сделать все превосходное невидимым! Итак, если на компьютере открыт только один экземпляр Excel, используйте Application.visible = true. Однако может быть, что другие электронные таблицы открыты. Если это так, то только скрыть текущую книгу. Следовательно, ThisWorkbook.Windows(1).Visible = False используется в блоке Else.

2. Когда Excel стал невидимым, мы загрузим наши формы. Это окна, которые обеспечивают интерфейс интерфейса пользователя для взаимодействия с пользователем. Таким образом, я могу создать подходящее приложение из Excel почти без каких-либо указаний на то, что Excel работает за кулисами.

3. Как только пользователь закончит, он нажмет кнопку выхода, которую я назвал cmdExit. Вы можете увидеть, как код сгибает эту кнопку ниже. Он выгружает GUI-формы и делает Excel снова видимым для пользователя. Это похоже на то, что вы хотите достичь.

Private Sub Workbook_Open()

    Stop

    ' Hide Excel...
'    ActiveWorkbook.Windows(1).Visible = False
    If Workbooks.Count < 2 Then
        Application.Visible = False
    Else
        ThisWorkbook.Windows(1).Visible = False
    End If

    Load frmMain
    frmMain.Show vbModal

End Sub


Private Sub cmdQuit_Click()

    'ThisWorkbook.Windows(1).Visible = True
    Application.Visible = True
    Unload frmMoreOccupationLines
    Unload Me

End Sub

Я думаю, причина, по которой вы можете видеть более одной книги, может быть из-за того, что вы случайно оставили предыдущие экземпляры Excel все еще открытыми, но скрытыми (невидимыми). Они не были выгружены и все еще остаются в памяти. Имеет ли это смысл? Поэтому, когда вы выполняете Application.visible=true, вы видите все предыдущие экземпляры, которые вы не закрыли. Таким образом, решение для m может быть связано с тем, что вы реализуете правильную стратегию выгрузки и выхода в свой код.

Поэтому я думаю, вы можете найти решение, как показано ниже:

Sub Test()
    If Workbooks.Count < 2 Then
        Application.Visible = False
    Else
        ThisWorkbook.Windows(1).Visible = False
    End If

    Application.Wait (Now + TimeValue("0:00:05"))

    If Workbooks.Count < 2 Then
        Application.Visible = True
    Else
        ThisWorkbook.Windows(1).Visible = True
    End If
End Sub


Private Sub cmdQuit_Click()
    Application.Visible = True
    'Unload Me
    Application.Quit
End Sub