Создать/получить xpath из XML node java

Ответ 1

Обновление

@c0mrade обновил свой вопрос. Вот решение:

Это преобразование XSLT:

<xsl:stylesheet version="1.0"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:variable name="vApos">'</xsl:variable>

    <xsl:template match="*[@* or not(*)] ">
      <xsl:if test="not(*)">
         <xsl:apply-templates select="ancestor-or-self::*" mode="path"/>
         <xsl:value-of select="concat('=',$vApos,.,$vApos)"/>
         <xsl:text>&#xA;</xsl:text>
        </xsl:if>
        <xsl:apply-templates select="@*|*"/>
    </xsl:template>

    <xsl:template match="*" mode="path">
        <xsl:value-of select="concat('/',name())"/>
        <xsl:variable name="vnumPrecSiblings" select=
         "count(preceding-sibling::*[name()=name(current())])"/>
        <xsl:if test="$vnumPrecSiblings">
            <xsl:value-of select="concat('[', $vnumPrecSiblings +1, ']')"/>
        </xsl:if>
    </xsl:template>

    <xsl:template match="@*">
        <xsl:apply-templates select="../ancestor-or-self::*" mode="path"/>
        <xsl:value-of select="concat('[@',name(), '=',$vApos,.,$vApos,']')"/>
        <xsl:text>&#xA;</xsl:text>
    </xsl:template>
</xsl:stylesheet>

при применении к предоставленному XML-документу:

<root>
    <elemA>one</elemA>
    <elemA attribute1='first' attribute2='second'>two</elemA>
    <elemB>three</elemB>
    <elemA>four</elemA>
    <elemC>
        <elemB>five</elemB>
    </elemC>
</root>

производит точно необходимый, правильный результат:

/root/elemA='one'
/root/elemA[2]='two'
/root/elemA[2][@attribute1='first']
/root/elemA[2][@attribute2='second']
/root/elemB='three'
/root/elemA[3]='four'
/root/elemC/elemB='five'

При применении к вновь предоставленному документу с помощью @c0mrade:

<root>
    <elemX serial="kefw90234kf2esda9231">
        <id>89734</id>
    </elemX>
</root>

снова получается правильный результат:

/root/elemX='89734'
/root/elemX[@serial='kefw90234kf2esda9231']

Объяснение

• Только элементы, которые не имеют дочерних элементов или имеют атрибуты, соответствуют и обрабатываются.

• Для любого такого элемента, если у него нет дочерних элементов, все его элементы-предки или сами элементы обрабатываются в определенном режиме с именем 'path'. Затем выводится часть "='theValue'", а затем символ NL.

• Все атрибуты совпадающего элемента затем обрабатываются.

• Затем, наконец, шаблоны применяются ко всем дочерним элементам.

• Обработка элемента в режиме 'path' проста: выводится символ / и имя элемента. Затем, если есть предыдущие братья и сестры с тем же именем, выводится "[numPrecSiblings + 1]`.

• Обработка атрибутов проста: сначала все элементы ancestor-or-self:: его родителя обрабатываются в режиме 'path', затем выводится часть [attrName = attrValue], а затем NL.

Обратите внимание:

• Имена, которые находятся в пространстве имен, отображаются без каких-либо проблем и в их начальной читаемой форме.

• Чтобы облегчить читаемость, индекс [1] никогда не отображается.

Ниже мой первоначальный ответ (может быть проигнорирован)

Вот чистое решение XSLT 1.0:

Ниже представлен образец XML-документа и таблица стилей, которая принимает параметр node -set и создает одно действительное выражение XPath для каждого члена - node.

таблица стилей (buildPath.xsl):

<xsl:stylesheet version='1.0'
xmlns:xsl='http://www.w3.org/1999/XSL/Transform'
xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
>

<xsl:output method="text"/>
<xsl:variable name="theParmNodes" select="//namespace::*[local-name() =
'myNamespace']"/>
<xsl:template match="/">
  <xsl:variable name="theResult">
    <xsl:for-each select="$theParmNodes">
    <xsl:variable name="theNode" select="."/>
    <xsl:for-each select="$theNode |
$theNode/ancestor-or-self::node()[..]">
      <xsl:element name="slash">/</xsl:element>
      <xsl:choose>
        <xsl:when test="self::*">           
          <xsl:element name="nodeName">
            <xsl:value-of select="name()"/>
            <xsl:variable name="thisPosition" 
                select="count(preceding-sibling::*[name(current()) = 
                        name()])"/>
            <xsl:variable name="numFollowing" 
                select="count(following-sibling::*[name(current()) = 
                        name()])"/>
            <xsl:if test="$thisPosition + $numFollowing > 0">
              <xsl:value-of select="concat('[', $thisPosition +
                                                           1, ']')"/>
            </xsl:if>
          </xsl:element>
        </xsl:when>
        <xsl:otherwise> <!-- This node is not an element -->
          <xsl:choose>
            <xsl:when test="count(. | ../@*) = count(../@*)">   
            <!-- Attribute -->
              <xsl:element name="nodeName">
                <xsl:value-of select="concat('@',name())"/>
              </xsl:element>
            </xsl:when>     
            <xsl:when test="self::text()">  <!-- Text -->
              <xsl:element name="nodeName">
                <xsl:value-of select="'text()'"/>
                <xsl:variable name="thisPosition" 
                          select="count(preceding-sibling::text())"/>
                <xsl:variable name="numFollowing" 
                          select="count(following-sibling::text())"/>
                <xsl:if test="$thisPosition + $numFollowing > 0">
                  <xsl:value-of select="concat('[', $thisPosition + 
                                                           1, ']')"/>
                </xsl:if>
              </xsl:element>
            </xsl:when>     
            <xsl:when test="self::processing-instruction()">
            <!-- Processing Instruction -->
              <xsl:element name="nodeName">
                <xsl:value-of select="'processing-instruction()'"/>
                <xsl:variable name="thisPosition" 
                   select="count(preceding-sibling::processing-instruction())"/>
                <xsl:variable name="numFollowing" 
                    select="count(following-sibling::processing-instruction())"/>
                <xsl:if test="$thisPosition + $numFollowing > 0">
                  <xsl:value-of select="concat('[', $thisPosition + 
                                                            1, ']')"/>
                </xsl:if>
              </xsl:element>
            </xsl:when>     
            <xsl:when test="self::comment()">   <!-- Comment -->
              <xsl:element name="nodeName">
                <xsl:value-of select="'comment()'"/>
                <xsl:variable name="thisPosition" 
                         select="count(preceding-sibling::comment())"/>
                <xsl:variable name="numFollowing" 
                         select="count(following-sibling::comment())"/>
                <xsl:if test="$thisPosition + $numFollowing > 0">
                  <xsl:value-of select="concat('[', $thisPosition + 
                                                            1, ']')"/>
                </xsl:if>
              </xsl:element>
            </xsl:when>     
            <!-- Namespace: -->
            <xsl:when test="count(. | ../namespace::*) = 
                                               count(../namespace::*)">

              <xsl:variable name="apos">'</xsl:variable>
              <xsl:element name="nodeName">
                <xsl:value-of select="concat('namespace::*', 
                '[local-name() = ', $apos, local-name(), $apos, ']')"/>

              </xsl:element>
            </xsl:when>     
          </xsl:choose>
        </xsl:otherwise>            
      </xsl:choose>
    </xsl:for-each>
    <xsl:text>&#xA;</xsl:text>
  </xsl:for-each>
 </xsl:variable>
 <xsl:value-of select="msxsl:node-set($theResult)"/>
</xsl:template>
</xsl:stylesheet>

xml source (buildPath.xml):

<!-- top level Comment -->
<root>
    <nodeA>textA</nodeA>
 <nodeA id="nodeA-2">
  <?myProc ?>
        xxxxxxxx
  <nodeB/>
        <nodeB xmlns:myNamespace="myTestNamespace">
  <!-- Comment within /root/nodeA[2]/nodeB[2] -->
   <nodeC/>
  <!-- 2nd Comment within /root/nodeA[2]/nodeB[2] -->
        </nodeB>
        yyyyyyy
  <nodeB/>
  <?myProc2 ?>
    </nodeA>
</root>
<!-- top level Comment -->

Результат

/root/nodeA[2]/nodeB[2]/namespace::*[local-name() = 'myNamespace']
/root/nodeA[2]/nodeB[2]/nodeC/namespace::*[local-name() =
'myNamespace']

Ответ 2

Вот как это можно сделать с помощью SAX:

import java.util.HashMap;
import java.util.Map;

import org.xml.sax.Attributes;
import org.xml.sax.SAXException;
import org.xml.sax.XMLReader;
import org.xml.sax.helpers.DefaultHandler;

public class FragmentContentHandler extends DefaultHandler {

    private String xPath = "/";
    private XMLReader xmlReader;
    private FragmentContentHandler parent;
    private StringBuilder characters = new StringBuilder();
    private Map<String, Integer> elementNameCount = new HashMap<String, Integer>();

    public FragmentContentHandler(XMLReader xmlReader) {
        this.xmlReader = xmlReader;
    }

    private FragmentContentHandler(String xPath, XMLReader xmlReader, FragmentContentHandler parent) {
        this(xmlReader);
        this.xPath = xPath;
        this.parent = parent;
    }

    @Override
    public void startElement(String uri, String localName, String qName, Attributes atts) throws SAXException {
        Integer count = elementNameCount.get(qName);
        if(null == count) {
            count = 1;
        } else {
            count++;
        }
        elementNameCount.put(qName, count);
        String childXPath = xPath + "/" + qName + "[" + count + "]";

        int attsLength = atts.getLength();
        for(int x=0; x<attsLength; x++) {
            System.out.println(childXPath + "[@" + atts.getQName(x) + "='" + atts.getValue(x) + ']');
        }

        FragmentContentHandler child = new FragmentContentHandler(childXPath, xmlReader, this);
        xmlReader.setContentHandler(child);
    }

    @Override
    public void endElement(String uri, String localName, String qName) throws SAXException {
        String value = characters.toString().trim();
        if(value.length() > 0) {
            System.out.println(xPath + "='" + characters.toString() + "'");
        }
        xmlReader.setContentHandler(parent);
    }

    @Override
    public void characters(char[] ch, int start, int length) throws SAXException {
        characters.append(ch, start, length);
    }

}

Он может быть протестирован с помощью:

import java.io.FileInputStream;

import javax.xml.parsers.SAXParser;
import javax.xml.parsers.SAXParserFactory;

import org.xml.sax.InputSource;
import org.xml.sax.XMLReader;

public class Demo {

    public static void main(String[] args) throws Exception {
        SAXParserFactory spf = SAXParserFactory.newInstance();
        SAXParser sp = spf.newSAXParser();
        XMLReader xr = sp.getXMLReader();

        xr.setContentHandler(new FragmentContentHandler(xr));
        xr.parse(new InputSource(new FileInputStream("input.xml")));
    }
}

Это даст желаемый результат:

//root[1]/elemA[1]='one'
//root[1]/elemA[2][@attribute1='first]
//root[1]/elemA[2][@attribute2='second]
//root[1]/elemA[2]='two'
//root[1]/elemB[1]='three'
//root[1]/elemA[3]='four'
//root[1]/elemC[1]/elemB[1]='five'

Ответ 3

С jOOX (a jquery API port to Java, отказ от ответственности - я работаю в компании за библиотекой), вы можете почти добиться того, чего хотите в одном заявлении:

// I'm assuming this:
import static org.joox.JOOX.$;

// And then...
List<String> coolList = $(document).xpath("//*[not(*)]").map(
    context -> $(context).xpath() + "='" + $(context).text() + "'"
);

Если документ является вашим примером:

<root>
    <elemA>one</elemA>
    <elemA attribute1='first' attribute2='second'>two</elemA>
    <elemB>three</elemB>
    <elemA>four</elemA>
    <elemC>
        <elemB>five</elemB>
    </elemC>
</root>

Это приведет к созданию

/root[1]/elemA[1]='one'
/root[1]/elemA[2]='two'
/root[1]/elemB[1]='three'
/root[1]/elemA[3]='four'
/root[1]/elemC[1]/elemB[1]='five'

Под "почти" я подразумеваю, что jOOX еще не поддерживает атрибуты соответствия/сопоставления. Следовательно, ваши атрибуты не будут выдавать какой-либо результат. Это будет реализовано в ближайшем будущем.

Ответ 4

• использовать w3c.dom
• перейти рекурсивно вниз
• для каждого node есть простой способ получить это xpath: либо путем сохранения его как массива/списка в то время как # 2, либо через функцию, которая идет рекурсивно до тех пор, пока родитель не станет пустым, а затем изменит массив/список обнаруженных узлов.

что-то вроде этого.

UPD: и конкатенировать окончательный список, чтобы получить окончательный xpath. не думаю, что атрибуты будут проблемой.

Ответ 5

private static void buildEntryList( List<String> entries, String parentXPath, Element parent ) {
    NamedNodeMap attrs = parent.getAttributes();
    for( int i = 0; i < attrs.getLength(); i++ ) {
        Attr attr = (Attr)attrs.item( i );
        //TODO: escape attr value
        entries.add( parentXPath+"[@"+attr.getName()+"='"+attr.getValue()+"']"); 
    }
    HashMap<String, Integer> nameMap = new HashMap<String, Integer>();
    NodeList children = parent.getChildNodes();
    for( int i = 0; i < children.getLength(); i++ ) {
        Node child = children.item( i );
        if( child instanceof Text ) {
            //TODO: escape child value
            entries.add( parentXPath+"='"+((Text)child).getData()+"'" );
        } else if( child instanceof Element ) {
            String childName = child.getNodeName();
            Integer nameCount = nameMap.get( childName );
            nameCount = nameCount == null ? 1 : nameCount + 1;
            nameMap.put( child.getNodeName(), nameCount );
            buildEntryList( entries, parentXPath+"/"+childName+"["+nameCount+"]", (Element)child);
        }
    }
}

public static List<String> getEntryList( Document doc ) {
    ArrayList<String> entries = new ArrayList<String>();
    Element root = doc.getDocumentElement();
    buildEntryList(entries, "/"+root.getNodeName()+"[1]", root );
    return entries;
}

Этот код работает с двумя предположениями: вы не используете пространства имен и нет смешанных элементов контента. Ограничение пространства имен не является серьезным, но это сделает ваше выражение XPath более трудным для чтения, поскольку каждый элемент будет чем-то вроде *:<name>[namespace-uri()='<nsuri>'][<index>], но в противном случае его легко реализовать. Смешанный контент, с другой стороны, сделает использование xpath очень утомительным, так как вам нужно будет индивидуально адресовать второй, третий и т.д. Текст node внутри элемента.

Ответ 6

Я сделал аналогичную задачу один раз. Основная идея заключалась в том, что вы можете использовать индексы элемента в xpath. Например, в следующем xml

<root>
    <el />
    <something />
    <el />
</root>

xpath для второго <el/> будет /root[1]/el[2] (индексы xpath основаны на 1). Это читается как "возьмите первый корень, затем возьмите второй из всех элементов с именем el". Таким образом, элемент something не влияет на индексирование элементов el. Таким образом, вы можете теоретически создать xpath для каждого конкретного элемента в вашем xml. На практике я выполнил это, прогуливаясь по дереву и помню информацию об элементах и ​​их индексах на этом пути.
Создание xpath, ссылающегося на определенный атрибут элемента, тогда просто добавляло '/@attrName' к элементу xpath.

Ответ 7

Я написал метод для возврата абсолютного пути элемента в библиотеке Практический XML. Чтобы дать вам представление о том, как это работает, здесь выдержка из одного из модульных тестов:

assertEquals("/root/wargle[2]/zargle",
             DomUtil.getAbsolutePath(child3a)); 

Итак, вы можете пройти через документ, применить свои тесты и использовать его для возврата XPath. Или, вероятно, лучше, что вы можете использовать утверждения на основе XPath из той же библиотеки.

Ответ 8

Я сделал то же самое на прошлой неделе для обработки моего xml файла, соответствующего совместимому формату.

Поскольку вам нужен псевдокод: Вот как я это сделал.

//Вы можете пропустить ссылку на родительский и дочерний.

1_ Инициализировать пользовательский объект node: NodeObjectVO {String nodeName, String path, List attr, родительский элемент NodeObjectVO, дочерний элемент списка}

2_ Создать пустой список

3_ Создайте dom-представление xml и переместите его в node. Для каждого node получите соответствующую информацию. Вся информация типа node, имена атрибутов и значение должны быть легко доступны из dom-объекта. (Вам нужно проверить dom NodeType, код должен игнорировать инструкцию обработки и узлы открытого текста.)

//Предупреждение о предупреждении кода. 4_ Единственная сложная часть - это получить путь. Я создал итеративный метод утилиты, чтобы получить строку xpath из NodeElement. (Хотя (node.Parent!= Null) {path + = node.parent.nodeName}.

(Вы также можете добиться этого, сохранив глобальную переменную пути, которая отслеживает родительский путь для каждой итерации.)

5_ В методе setter атрибутов (List) я добавлю путь к объекту со всеми доступными атрибутами. (один путь со всеми доступными атрибутами, а не список путей с каждой возможной комбинацией атрибутов. Возможно, вы захотите сделать другой способ.)

6_ Добавьте NodeObjectVO в список.

7_ Теперь у нас есть плоский (не иерархический) список пользовательских объектов node, которые имеют всю необходимую мне информацию.

(Примечание: Как я уже упоминал, я поддерживаю родительские отношения с родителями, вы, вероятно, должны пропустить эту часть. Существует вероятность раздувания кода, особенно в пути getparentpath. Для небольших xml это не проблема, но это вызывает озабоченность большой xml).