Пересечение с помощью Biapplicative

Я думал о распаковке операций и понял, что один из способов выразить их - это пересечение в Biapplicative.

import Data.Biapplicative

class Traversable2 t where
  traverse2 :: Biapplicative p
            => (a -> p b c) -> t a -> p (t b) (t c)

-- Note: sequence2 :: [(a,b)] -> ([a], [b])
sequence2 :: (Traversable2 t, Biapplicative p)
          => t (p b c) -> p (t b) (t c)
sequence2 = traverse2 id

instance Traversable2 [] where
  traverse2 _ [] = bipure [] []
  traverse2 f (x : xs) = bimap (:) (:) (f x) <<*>> traverse2 f xs

Мне пахнет, как будто каждый экземпляр Traversable может быть механически преобразован в экземпляр Traversable2. Но я еще не нашел способ реально реализовать traverse2 с помощью traverse, не unsafeCoerce конвертирования в списки и из списков или, возможно, играя чрезвычайно грязные трюки с помощью unsafeCoerce. Есть ли хороший способ сделать это?

Дальнейшее доказательство того, что что-либо Traversable является Traversable2:

class (Functor t, Foldable t) => Traversable2 t where
  traverse2 :: Biapplicative p
            => (a -> p b c) -> t a -> p (t b) (t c)
  default traverse2 ::
               (Biapplicative p, Generic1 t, GTraversable2 (Rep1 t))
            => (a -> p b c) -> t a -> p (t b) (t c)
  traverse2 f xs = bimap to1 to1 $ gtraverse2 f (from1 xs)

class GTraversable2 r where
  gtraverse2 :: Biapplicative p
             => (a -> p b c) -> r a -> p (r b) (r c)

instance GTraversable2 V1 where
  gtraverse2 _ x = bipure (case x of) (case x of)

instance GTraversable2 U1 where
  gtraverse2 _ _ = bipure U1 U1

instance GTraversable2 t => GTraversable2 (M1 i c t) where
  gtraverse2 f (M1 t) = bimap M1 M1 $ gtraverse2 f t

instance (GTraversable2 t, GTraversable2 u) => GTraversable2 (t :*: u) where
  gtraverse2 f (t :*: u) = bimap (:*:) (:*:) (gtraverse2 f t) <<*>> gtraverse2 f u

instance (GTraversable2 t, GTraversable2 u) => GTraversable2 (t :+: u) where
  gtraverse2 f (L1 t) = bimap L1 L1 (gtraverse2 f t)
  gtraverse2 f (R1 t) = bimap R1 R1 (gtraverse2 f t)

instance GTraversable2 (K1 i c) where
  gtraverse2 f (K1 x) = bipure (K1 x) (K1 x)

instance (Traversable2 f, GTraversable2 g) => GTraversable2 (f :.: g) where
  gtraverse2 f (Comp1 x) = bimap Comp1 Comp1 $ traverse2 (gtraverse2 f) x

instance Traversable2 t => GTraversable2 (Rec1 t) where
  gtraverse2 f (Rec1 xs) = bimap Rec1 Rec1 $ traverse2 f xs

instance GTraversable2 Par1 where
  gtraverse2 f (Par1 p) = bimap Par1 Par1 (f p)

Ответы

Ответ 1

Один лишь слегка злой способ сделать это - использовать что-то вроде Magma из lens. Это кажется значительно проще, чем решение leftaroundabout, хотя оно и не прекрасное.

data Mag a b t where
  Pure :: t -> Mag a b t
  Map :: (x -> t) -> Mag a b x -> Mag a b t
  Ap :: Mag a b (t -> u) -> Mag a b t -> Mag a b u
  One :: a -> Mag a b b

instance Functor (Mag a b) where
  fmap = Map

instance Applicative (Mag a b) where
  pure = Pure
  (<*>) = Ap

traverse2 :: forall t a b c f. (Traversable t, Biapplicative f)
          => (a -> f b c) -> t a -> f (t b) (t c)
traverse2 f0 xs0 = go m m
  where
    m :: Mag a x (t x)
    m = traverse One xs0

    go :: forall x y. Mag a b x -> Mag a c y -> f x y
    go (Pure t) (Pure u) = bipure t u
    go (Map f x) (Map g y) = bimap f g (go x y)
    go (Ap fs xs) (Ap gs ys) = go fs gs <<*>> go xs ys
    go (One x) (One y) = f0 x
    go _ _ = error "Impossible"

Ответ 2

Я думаю, что у меня может быть что-то, что соответствует вашему счету. (Изменение: это не так, см. Комментарии.) Вы можете определить newtypes над p() c и pb() и сделать их экземплярами Functor.

Реализация

Здесь ваш класс снова с определениями по умолчанию. Я пошел по пути реализации sequence2 с точки зрения sequenceA потому что это казалось более простым.

class Functor t => Traversable2 t where
  {-# MINIMAL traverse2 | sequence2 #-}
  traverse2 :: Biapplicative p => (a -> p b c) -> t a -> p (t b) (t c)
  traverse2 f = sequence2 . fmap f

  sequence2 :: Biapplicative p => t (p b c) -> p (t b) (t c)
  sequence2 = traverse2 id

Теперь "правая часть" Biapplicative

newtype R p c = R { runR :: p () c }

instance Bifunctor p => Functor (R p) where
  fmap f (R x) = R $ bimap id f x

instance Biapplicative p => Applicative (R p) where
  pure x = R (bipure () x)
  R f <*> R x =
    let f' = biliftA2 const (flip const) (bipure id ()) f
    in  R $ f' <<*>> x

mkR :: Biapplicative p => p b c -> R p c
mkR = R . biliftA2 const (flip const) (bipure () ())

sequenceR :: (Traversable t, Biapplicative p) => t (p b c) -> p () (t c)
sequenceR = runR . sequenceA . fmap mkR

с "левой частью" почти то же самое. Полный код находится в этом контексте.

Теперь мы можем сделать p (tb)() и p() (tc) и собрать их в p (tb) (tc).

instance (Functor t, Traversable t) => Traversable2 t where
  sequence2 x = biliftA2 const (flip const) (sequenceL x) (sequenceR x)

Мне нужно было включить FlexibleInstances и UndecidableInstances для объявления этого экземпляра. Кроме того, каким-то образом ghc хотел создать Functor constaint.

тестирование

Я проверил с вашим экземпляром для [] что он дает те же результаты:

main :: IO ()
main = do
  let xs = [(x, ord x - 97) | x <- ['a'..'g']]
  print xs
  print (sequence2 xs)
  print (sequence2' xs)

traverse2' :: Biapplicative p => (a -> p b c) -> [a] -> p [b] [c]
traverse2' _ [] = bipure [] []
traverse2' f (x : xs) = bimap (:) (:) (f x) <<*>> traverse2 f xs

sequence2' :: Biapplicative p => [p b c] -> p [b] [c]
sequence2' = traverse2' id

выходы

[('a',0),('b',1),('c',2),('d',3),('e',4),('f',5),('g',6)]
("abcdefg",[0,1,2,3,4,5,6])
("abcdefg",[0,1,2,3,4,5,6])

Это было весело!

Ответ 3

Следующее, похоже, делает трюк, используя "только" undefined. Возможно, проходящие законы гарантируют, что это нормально, но я не пытался это доказать.

{-# LANGUAGE GADTs, KindSignatures, TupleSections #-}

import Data.Biapplicative

import Data.Traversable

data Bimock :: (* -> * -> *) -> * -> * where
   Bimock :: p a b -> Bimock p (a,b)
   Bimfmap :: ((a,b) -> c) -> p a b -> Bimock p c
   Bimpure :: a -> Bimock p a
   Bimapp :: Bimock p ((a,b) -> c) -> p a b -> Bimock p c

instance Functor (Bimock p) where
  fmap f (Bimock p) = Bimfmap f p
  fmap f (Bimfmap g p) = Bimfmap (f . g) p
  fmap f (Bimpure x) = Bimpure (f x)
  fmap f (Bimapp gs xs) = Bimapp (fmap (f .) gs) xs
instance Biapplicative p => Applicative (Bimock p) where
  pure = Bimpure
  Bimpure f<*>xs = fmap f xs
  fs<*>Bimpure x = fmap ($x) fs
  fs<*>Bimock p = Bimapp fs p
  Bimfmap g h<*>Bimfmap i xs = Bimfmap (\(~(a₁,a₂),~(b₁,b₂)) -> g (a₁,b₁) $ i (a₂, b₂))
                              $ bimap (,) (,) h<<*>>xs
  Bimapp g h<*>xs = fmap uncurry g <*> ((,)<$>Bimock h<*>xs)

runBimock :: Biapplicative p => Bimock p (a,b) -> p a b
runBimock (Bimock p) = p
runBimock (Bimfmap f p) = bimap (fst . f . (,undefined)) (snd . f . (undefined,)) p
runBimock (Bimpure (a,b)) = bipure a b
runBimock (Bimapp (Bimpure f) xs) = runBimock . fmap f $ Bimock xs
runBimock (Bimapp (Bimfmap h g) xs)
     = runBimock . fmap (\(~(a₂,a₁),~(b₂,b₁)) -> h (a₂,b₂) (a₁,b₁))
           . Bimock $ bimap (,) (,) g<<*>>xs
runBimock (Bimapp (Bimapp h g) xs)
     = runBimock . (fmap (\θ (~(a₂,a₁),~(b₂,b₁)) -> θ (a₂,b₂) (a₁,b₁)) h<*>)
           . Bimock $ bimap (,) (,) g<<*>>xs

traverse2 :: (Biapplicative p, Traversable t) => (a -> p b c) -> t a -> p (t b) (t c)
traverse2 f s = runBimock . fmap (\bcs->(fmap fst bcs, fmap snd bcs)) $ traverse (Bimock . f) s


sequence2 :: (Traversable t, Biapplicative p)
          => t (p b c) -> p (t b) (t c)
sequence2 = traverse2 id

И даже если это безопасно, я не удивлюсь, если это даст ужасную производительность, что с неопровержимыми паттернами и квадратичным (или даже экспоненциальным?) Наращиванием кортежей.

Ответ 4

Несколько замечаний, кроме полного, оригинального ответа.

Если у вас есть Biapplicative, то вы можете с ним сделать что-то и разделить его на пару бифунторов, изоморфных двум его компонентам.

data Helper w a b = Helper {
  left :: w a (),
  right :: w () b
}

runHelper :: forall p a b. Biapplicative p => Helper p a b -> p a b
runHelper x = biliftA2 const (flip const) (left x) (right x)

makeHelper :: (Biapplicative p)
           => p a b -> Helper p a b
makeHelper w = Helper (bimap id (const ()) w)
                      (bimap (const ()) id w)

type Separated w a b = (w a (), w () b)

Можно было бы объединить подходы @nnnmmm и @leftroundabout, применив fmap (makeHelper. f) к структуре s, устраняя необходимость в undefined, но тогда вам нужно будет сделать Helper или его замену instance некоторого типа с помощью полезные операции, позволяющие решить проблему.

Если у вас есть структура Traversable, то что вы можете сделать, это sequenceA Applicative functors (в этом случае ваше решение будет выглядеть как traverse2 f = fromHelper. sequenceA. fmap (makeHelper. f), где ваш Applicative экземпляр создает пару структур t) или traverse его с помощью Functor (в этом случае ваше решение будет выглядеть как traverse2 f = fromHelper. traverse (g. makeHelper. f) where...). В любом случае вам нужно определить экземпляр Functor, так как Applicative наследует от Functor. Вы можете попытаться построить свой Functor из <<*>> и bipure id id или bimap, или вы можете работать с обеими разделенными переменными в одном и том же проходе.

К сожалению, для того, чтобы типы работали для экземпляра Functor, вам необходимо параметризовать :: pbc для типа, который мы неофициально вызываем :: w (b,c) где один параметр является декартовым произведением двух параметров p. Система типа Haskells, похоже, не допускает этого без нестандартных расширений, но @leftroundabout отлично Bimock классом Bimock. используя undefined чтобы принудить оба разделенных функтора к одному типу.

Для производительности то, что вы хотите сделать, - это не более одного обхода, который создает объект, изоморфный p (tb) (tc) который вы затем можете преобразовать (аналогично закону Naturality). Поэтому вы хотите реализовать traverse2 а не sequence2 и определить sequence2 как traverse2 id, чтобы избежать двойного перемещения. Если вы отделите переменные и произведете что-нибудь, изоморфное (p (tb)(), p() (tc)), вы можете их рекомбинировать как @mmmnnn.

В практическом использовании я подозреваю, что вы захотите наложить какую-то дополнительную структуру на проблему. Ваш вопрос сохранил компоненты b и c в Bifunctor совершенно бесплатно, но на практике они, как правило, либо ковариантные или контравариантные функторы, которые могут быть секвенированы с biliftA2 или пройденными вместе над Bitraversable, а не Traversable t, или, возможно, даже есть Semigroup, Monad Applicative или Monad.

Особенно эффективная оптимизация была бы, если ваш p изоморфен Monoid, операция <> создает структуру данных, изоморфную вашему t. (Это работает для списков и двоичных деревьев; Data.ByteString.Builder - это алгебраический тип, обладающий этим свойством.) В этом случае ассоциативность операции позволяет преобразовать структуру в строгую левую складку или ленивую правую складку.

Это был отличный вопрос, и хотя у меня нет лучшего кода, чем @leftroundabout для общего случая, я многому научился от работы над ним.