Получить последний день месяца в SQL

Мне нужно получить последний день месяца, указанный в качестве даты в SQL. Если у меня есть первый день месяца, я могу сделать что-то вроде этого:

Но кто-нибудь знает, как его обобщить, чтобы я мог найти последний день месяца для любой даты?

Ответы

Ответ 1

Вот моя версия. Никаких строковых манипуляций или кастинга не требуется, только один вызов каждого из функций DATEADD, YEAR и MONTH:

DECLARE @test DATETIME
SET @test = GETDATE()  -- or any other date

SELECT DATEADD(month, ((YEAR(@test) - 1900) * 12) + MONTH(@test), -1)

Ответ 2

С SQL Server 2012 вы можете использовать функцию EOMONTH.

Возвращает последний день месяца, который содержит указанную дату, с дополнительным смещением.

Синтаксис

EOMONTH ( start_date [, month_to_add ] )

Как... Я могу найти последний день месяца для любой даты?

SELECT EOMONTH(@SomeGivenDate)

Ответ 3

Вы можете получить дни в день, используя функцию DAY():

dateadd(day, -1, dateadd(month, 1, dateadd(day, 1 - day(date), date)))

Ответ 4

Я знаю, что это старый вопрос, но вот другое решение, которое работает для меня

SET @dtDate = "your date"
DATEADD(s,-1,DATEADD(mm, DATEDIFF(m,0,@dtDate)+1,0))

И если кто-то ищет разные примеры, вот ссылка http://blog.sqlauthority.com/2007/08/18/sql-server-find-last-day-of-any-month-current-previous-next/

Надеюсь, это поможет кому-то другому. Скалы утесов!!!!

Ответ 5

На основе утверждений:

SELECT DATEADD(MONTH, 1, @x)           -- Add a month to the supplied date @x

SELECT DATEADD(DAY,  0 - DAY(@x), @x)  -- Get last day of month previous to the supplied date @x

как насчет добавления месяца к дате @x, а затем получения последнего дня месяца, предшествующего этому (т.е. последний день месяца предоставленной даты)

DECLARE @x  DATE = '20-Feb-2012' 
SELECT DAY(DATEADD(DAY,  0 - DAY(DATEADD(MONTH, 1, @x)), DATEADD(MONTH, 1, @x)))

Примечание. Это был тест с использованием SQL Server 2008 R2

Ответ 6

Немного растяните свою формулу:

dateadd(day, -1,
    dateadd(month, 1,
        cast(month('5/15/2009') as varchar(2)) + 
        '/1/' + 
        cast(year('5/15/2009') as varchar(4)))

Ответ 7

Для SQL Server 2012 или выше используйте EOMONTH, чтобы получить последнюю дату месяца

SQL-запрос для отображения даты окончания текущего месяца

DECLARE @currentDate DATE = GETDATE()
SELECT EOMONTH (@currentDate) AS CurrentMonthED

SQL-запрос для отображения даты окончания следующего месяца

DECLARE @currentDate DATE = GETDATE()
SELECT EOMONTH (@currentDate, 1 ) AS NextMonthED

Ответ 8

Используя SQL Server, вот еще один способ найти последний день месяца:

SELECT DATEADD(MONTH,1,GETDATE())- day(DATEADD(MONTH,1,GETDATE()))

Ответ 9

WinSQL, чтобы получить последний день прошлого месяца (т.е. сегодня 2017-02-09, возвращает 2017-01-31: Выберите дату (день, день (сегодня()), сегодня())

Ответ 10

Попробуйте выполнить следующий запрос, он предоставит вам все, что вы хотите:)

Declare @a date =dateadd(mm, Datediff(mm,0,getdate()),0)
Print('First day of Current Month:')
Print(@a)
Print('')
set @a = dateadd(mm, Datediff(mm,0,getdate())+1,-1)
Print('Last day of Current Month:')
Print(@a)
Print('')

Print('First day of Last Month:')
set @a = dateadd(mm, Datediff(mm,0,getdate())-1,0)
Print(@a)
Print('')

Print('Last day of Last Month:') 
set @a = dateadd(mm, Datediff(mm,0,getdate()),-1)
Print(@a)
Print('')


Print('First day of Current Week:')
set @a = dateadd(ww, Datediff(ww,0,getdate()),0)
Print(@a)
Print('')

Print('Last day of Current Week:')
set @a = dateadd(ww, Datediff(ww,0,getdate())+1,-1)
Print(@a)
Print('')

Print('First day of Last Week:')
set @a =  dateadd(ww, Datediff(ww,0,getdate())-1,0)
Print(@a)
Print('')

Print('Last day of Last Week:')
set @a =  dateadd(ww, Datediff(ww,0,getdate()),-1)
Print(@a)

Ответ 11

WinSQL: я хотел вернуть все записи за последний месяц:

where DATE01 between dateadd(month,-1,dateadd(day,1,dateadd(day,-day(today()),today()))) and dateadd(day,-day(today()),today())

Это делает то же самое:

where month(DATE01) = month(dateadd(month,-1,today())) and year(DATE01) = year(dateadd(month,-1,today()))

Ответ 12

Работает на SQL-сервере

Declare @GivenDate datetime
SET @GivenDate = GETDATE()

Select DATEADD(MM,DATEDIFF(MM, 0, @GivenDate),0) --First day of the month 

Select DATEADD(MM,DATEDIFF(MM, -1, @GivenDate),-1) --Last day of the month

Ответ 13

Мои 2 цента:

select DATEADD(DAY,-1,DATEADD(MONTH,1,DATEADD(day,(0-(DATEPART(dd,'2008-02-12')-1)),'2008-02-12')))

Раджа

Ответ 14

Если вам это нужно часто, оберните его в встроенный TVF, который очень быстрый:

http://sqlblog.com/blogs/alexander_kuznetsov/archive/2009/06/21/calculating-third-wednesday-of-the-month-with-inline-udfs.aspx ,

Ответ 15

используя SQL Server 2005, это работает для меня:

select dateadd(dd,-1,dateadd(mm,datediff(mm,0,YOUR_DATE)+1,0))

В основном вы получаете количество месяцев с начала (SQL Server) для YOUR_DATE. Затем добавьте один к нему, чтобы получить порядковый номер следующего месяца. Затем вы добавляете это количество месяцев в 0, чтобы получить дату, которая является первым днем следующего месяца. Из этого вы затем вычитаете день, чтобы добраться до последнего дня YOUR_DATE.

Ответ 16

Это работает для меня, используя Microsoft SQL Server 2005:

DATEADD(d,-1,DATEADD(mm, DATEDIFF(m,0,'2009-05-01')+1,0))

Ответ 17

Возьмите некоторую базовую дату, которая составляет 31-е число месяца, например. '20011231'. Затем используйте следующая процедура (я привел 3 одинаковых примера ниже, только значение @dt отличается).

declare @dt datetime;

set @dt = '20140312'

SELECT DATEADD(month, DATEDIFF(month, '20011231', @dt), '20011231');



set @dt = '20140208'

SELECT DATEADD(month, DATEDIFF(month, '20011231', @dt), '20011231');



set @dt = '20140405'

SELECT DATEADD(month, DATEDIFF(month, '20011231', @dt), '20011231');

Ответ 18

Я написал следующую функцию, она работает.

Он возвращает тип данных datetime. Нулевой час, минута, секунда, милисекунды.

CREATE Function [dbo].[fn_GetLastDate]
(
    @date datetime
)
returns datetime
as
begin

declare @result datetime

 select @result = CHOOSE(month(@date),  
 DATEADD(DAY, 31 -day(@date), @date),
 IIF(YEAR(@date) % 4 = 0, DATEADD(DAY, 29 -day(@date), @date), DATEADD(DAY, 28 -day(@date), @date)), 
 DATEADD(DAY, 31 -day(@date), @date) ,
 DATEADD(DAY, 30 -day(@date), @date), 
 DATEADD(DAY, 31 -day(@date), @date),
 DATEADD(DAY, 30 -day(@date), @date), 
 DATEADD(DAY, 31 -day(@date), @date),
 DATEADD(DAY, 31 -day(@date), @date),
 DATEADD(DAY, 30 -day(@date), @date),
 DATEADD(DAY, 31 -day(@date), @date),
 DATEADD(DAY, 30 -day(@date), @date), 
 DATEADD(DAY, 31 -day(@date), @date))

 return convert(date, @result)

end

Он очень прост в использовании. Пример 2:

select [dbo].[fn_GetLastDate]('2016-02-03 12:34:12')

select [dbo].[fn_GetLastDate](GETDATE())

Ответ 19

Этот запрос также может быть использован.

DECLARE @SelectedDate DATE =  GETDATE()

SELECT DATEADD(DAY, - DAY(@SelectedDate), DATEADD(MONTH, 1 , @SelectedDate)) EndOfMonth

Ответ 20

---Start/End of previous Month 
Declare @StartDate datetime, @EndDate datetime

set @StartDate = DATEADD(month, DATEDIFF(month, 0, GETDATE())-1,0) 
set @EndDate = EOMONTH (DATEADD(month, DATEDIFF(month, 0, GETDATE())-1,0)) 

SELECT @StartDate,@EndDate

Ответ 21

Функция LAST_DAY прекрасно работает для этого.

Изменить: На самом деле, как упоминалось в комментариях, это, вероятно, не для всех SQL. Я оставлю сообщение в случае, если кто-то ищет ответ MySQL/Oracle, наткнувшись на него.

Из справочника mysql:

LAST_DAY(date)

Принимает значение даты или даты и времени и возвращает соответствующее значение за последний день месяца. Возвращает NULL, если аргумент недействителен.

mysql> SELECT LAST_DAY('2003-02-05');
        -> '2003-02-28'
mysql> SELECT LAST_DAY('2004-02-05');
        -> '2004-02-29'
mysql> SELECT LAST_DAY('2004-01-01 01:01:01');
        -> '2004-01-31'
mysql> SELECT LAST_DAY('2003-03-32');
        -> NULL

LAST_DAY() доступен с MySQL 4.1.1.