Есть ли лучший способ иметь необязательные аргументы в Haskell?

Я привык к тому, что в Python можно указать необязательные аргументы:

def product(a, b=2):
    return a * b

Haskell не имеет аргументов по умолчанию, но мне удалось получить что-то подобное, используя "Maybe":

product a (Just b) = a * b
product a Nothing = a * 2

Это очень громоздко, если у вас есть несколько параметров. Например, что делать, если я хочу сделать что-то вроде этого:

def multiProduct (a, b=10, c=20, d=30):
    return a * b * c * d

Мне пришлось бы иметь восемь определений multiProduct для учета всех случаев.

Вместо этого я решил пойти с этим:

multiProduct req1 opt1 opt2 opt3 = req1 * opt1' * opt2' * opt3'
    where opt1' = if isJust opt1 then (fromJust opt1) else 10
    where opt2' = if isJust opt2 then (fromJust opt2) else 20
    where opt3' = if isJust opt3 then (fromJust opt3) else 30

Это выглядит очень нелогично для меня. Есть ли идиоматический способ сделать это в Haskell, который чище?

Ответы

Ответ 1

Здесь еще один способ сделать необязательные аргументы в Haskell:

{-# LANGUAGE MultiParamTypeClasses, FlexibleInstances, FlexibleContexts #-}
module Optional where

class Optional1 a b r where 
  opt1 :: (a -> b) -> a -> r

instance Optional1 a b b where
  opt1 = id

instance Optional1 a b (a -> b) where
  opt1 = const

class Optional2 a b c r where 
  opt2 :: (a -> b -> c) -> a -> b -> r

instance Optional2 a b c c where
  opt2 = id

instance (Optional1 b c r) => Optional2 a b c (a -> r) where
  opt2 f _ b = \a -> opt1 (f a) b

{- Optional3, Optional4, etc defined similarly -}

Тогда

{-# LANGUAGE FlexibleContexts #-}
module Main where
import Optional

foo :: (Optional2 Int Char String r) => r
foo = opt2 replicate 3 'f'

_5 :: Int
_5 = 5

main = do
  putStrLn $ foo        -- prints "fff"
  putStrLn $ foo _5     -- prints "fffff"
  putStrLn $ foo _5 'y' -- prints "yyyyy"

Обновить: Упс, я получил. Я честно считаю, что ответ luqui является лучшим здесь:

  • тип понятен и легко читается даже для начинающих
  • для ошибок типа
  • GHC не нуждается в подсказках, чтобы делать с ним вывод типа (попробуйте opt2 replicate 3 'f' в ghci, чтобы понять, что я имею в виду)
  • необязательные аргументы не зависят от заказа

Ответ 2

Возможно, некоторые приятные обозначения будут проще для глаз:

(//) :: Maybe a -> a -> a
Just x  // _ = x
Nothing // y = y
-- basically fromMaybe, just want to be transparent

multiProduct req1 opt1 opt2 opt3 = req1 * (opt1 // 10) * (opt2 // 20) * (opt3 // 30)

Если вам нужно использовать параметры более одного раза, я предлагаю использовать метод @pat.

РЕДАКТИРОВАТЬ 6 лет спустя

С ViewPatterns вы можете поставить значения по умолчанию слева.

{-# LANGUAGE ViewPatterns #-}

import Data.Maybe (fromMaybe)

def :: a -> Maybe a -> a
def = fromMaybe

multiProduct :: Int -> Maybe Int -> Maybe Int -> Maybe Int -> Int
multiProduct req1 (def 10 -> opt1) (def 20 -> opt2) (def 30 -> opt3)
  = req1 * opt1 * opt2 * opt3

Ответ 3

Я не знаю, как лучше решить основную проблему, но ваш пример можно написать более кратко:

multiProduct req1 opt1 opt2 opt3 = req1 * opt1' * opt2' * opt3'
    where opt1' = fromMaybe 10 opt1
          opt2' = fromMaybe 20 opt2
          opt3' = fromMaybe 30 opt3

Ответ 5

Когда аргументы становятся слишком сложными, одним из решений является создание типа данных только для аргументов. Затем вы можете создать конструктор по умолчанию для этого типа и заполнить только то, что вы хотите заменить в своих вызовах функций.

Пример:

$ runhaskell dog.hs 
Snoopy (Beagle): Ruff!
Snoopy (Beagle): Ruff!
Wishbone (Terrier): Ruff!
Wishbone (Terrier): Ruff!
Wishbone (Terrier): Ruff!

dog.hs:

#!/usr/bin/env runhaskell

import Control.Monad (replicateM_)

data Dog = Dog {
        name :: String,
        breed :: String,
        barks :: Int
    }

defaultDog :: Dog
defaultDog = Dog {
        name = "Dog",
        breed = "Beagle",
        barks = 2
    }

bark :: Dog -> IO ()
bark dog = replicateM_ (barks dog) $ putStrLn $ (name dog) ++ " (" ++ (breed dog) ++ "): Ruff!"

main :: IO ()
main = do
    bark $ defaultDog {
            name = "Snoopy",
            barks = 2
        }

    bark $ defaultDog {
            name = "Wishbone",
            breed = "Terrier",
            barks = 3
        }

Ответ 6

Возможное улучшение/модификация подхода к записи, упомянутого mcandre и Ionuț, заключается в использовании линз:

{-# LANGUAGE -XTemplateHaskell #-}

data Dog = Dog {
  _name :: String,
  _breed :: String,
  _barks :: Int
}

makeLenses ''Dog

defaultDog :: Dog
defaultDog = Dog {
  _name = "Dog",
  _breed = "Beagle",
  _barks = 2
}

bark :: (Dog -> Dog) -> IO ()
bark modDog = do
  let dog = modDog defaultDog
  replicateM_ (barks dog) $ putStrLn $
    (name dog) ++ " (" ++ (breed dog) ++ "): Ruff!"

main :: IO ()
main = do
  bark $ (name .~ "Snoopy") . (barks .~ 2)
  bark $ (name .~ "Wishbone") . (breed .~ "Terrier") . (barks .~ 3)

Или в качестве альтернативы

bark :: Dog -> IO ()
bark dog = do
  replicateM_ (barks dog) $ putStrLn $
    (name dog) ++ " (" ++ (breed dog) ++ "): Ruff!"

main :: IO ()
main = do
  bark $ name .~ "Snoopy" $ barks .~ 2 $ defaultDog
  bark $ name .~ "Wishbone" $ breed .~ "Terrier" $ barks .~ 3 $ defaultDog

Смотрите здесь значение (.~).